network/konversation/CMakeLists.txt

0001 cmake_minimum_required (VERSION 3.16 FATAL_ERROR)
0002
0003 # Release Service version, managed by release script
0004 set (RELEASE_SERVICE_VERSION_MAJOR "22")
0005 set (RELEASE_SERVICE_VERSION_MINOR "11")
0006 set (RELEASE_SERVICE_VERSION_MICRO "70")
0007 set (RELEASE_SERVICE_COMPACT_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}${RELEASE_SERVICE_VERSION_MINOR}${RELEASE_SERVICE_VERSION_MICRO}")
0008
0009 # Bump KONVERSATION_BASE_VERSION once new features are added
0010 set(KONVERSATION_BASE_VERSION "1.9")
0011 set(KONVERSATION_VERSION "${KONVERSATION_BASE_VERSION}.${RELEASE_SERVICE_COMPACT_VERSION}")
0012
0013 project(konversation VERSION ${KONVERSATION_VERSION})
0014
0015 set(QT_MIN_VERSION "5.15.2")
0016 set(KF5_MIN_VERSION "5.90.0")
0017 set(KDE_COMPILERSETTINGS_LEVEL "5.85")
0018
0019 find_package(ECM ${KF5_MIN_VERSION} REQUIRED NO_MODULE)
0020 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH})
0021
0022 include(CheckIncludeFile)
0023 include(KDEInstallDirs)
0024 include(KDECMakeSettings)
0025 include(KDECompilerSettings NO_POLICY_SCOPE)
0026 include(ECMInstallIcons)
0027 include(ECMSetupVersion)
0028 include(ECMGenerateDBusServiceFile)
0029 include(FeatureSummary)
0030
0031 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} CONFIG REQUIRED Core Multimedia Network Widgets)
0032
0033 find_package(KF5 ${KF5_MIN_VERSION} REQUIRED
0034     Archive
0035     Bookmarks
0036     Config
0037     ConfigWidgets
0038     CoreAddons
0039     Crash
0040     DocTools
0041     I18n
0042     IdleTime
0043     NotifyConfig
0044     KIO
0045     Parts
0046     Wallet
0047     WidgetsAddons
0048     DBusAddons
0049     NewStuff
0050     Notifications
0051     WindowSystem
0052     ItemViews
0053 )
0054
0055 if(NOT WIN32)
0056     find_package(KF5 REQUIRED GlobalAccel)
0057 endif()
0058 set(HAVE_KGLOBALACCEL ${KF5GlobalAccel_FOUND})
0059
0060 if (KF5_VERSION VERSION_LESS 5.91.0)
0061     find_package(Qt5X11Extras ${QT_MIN_VERSION} CONFIG)
0062     set_package_properties(Qt5X11Extras PROPERTIES
0063         PURPOSE "Needed for startup activation handling on X11"
0064         TYPE OPTIONAL
0065     )
0066 elseif(KF5_MIN_VERSION VERSION_GREATER 5.90)
0067     message(AUTHOR_WARNING "Please remove usage of Qt5X11Extras and HAVE_X11, no longer needed.")
0068 endif()
0069
0070 find_package(Qca-qt${QT_MAJOR_VERSION} 2.2.0)
0071 set_package_properties(Qca-qt${QT_MAJOR_VERSION} PROPERTIES DESCRIPTION "Support for encryption"
0072                        URL "https://download.kde.org/stable/qca/"
0073                        TYPE OPTIONAL)
0074 check_include_file("stropts.h" HAVE_STROPTS_H)
0075
0076 set(HAVE_QCA2 ${Qca-qt${QT_MAJOR_VERSION}_FOUND})
0077 if(TARGET Qt5::X11Extras)
0078     set(HAVE_X11 TRUE)
0079 else()
0080     set(HAVE_X11 FALSE)
0081 endif()
0082
0083 configure_file(config-konversation.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-konversation.h )
0084 include_directories(${CMAKE_CURRENT_BINARY_DIR})
0085 add_definitions(-DQT_DISABLE_DEPRECATED_BEFORE=0x050F00)
0086 #add_definitions(-DKF_DISABLE_DEPRECATED_BEFORE_AND_AT=0x060000)
0087
0088 add_subdirectory(src)
0089 add_subdirectory(data)
0090 add_subdirectory(doc)
0091
0092 if(BUILD_TESTING)
0093     add_subdirectory(tests)
0094 endif()
0095
0096 ki18n_install(po)
0097 kdoctools_install(po)
0098
0099 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)