konqueror/libkonq/CMakeLists.txt

0001 project(LibKonq)
0002 add_definitions(-DTRANSLATION_DOMAIN="libkonq")
0003
0004 set(LIBKONQ_VERSION "5.97.0")
0005
0006 ecm_setup_version(${LIBKONQ_VERSION} VARIABLE_PREFIX KONQ
0007                   VERSION_HEADER "${LibKonq_BINARY_DIR}/konq_version.h"
0008                   PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF${KF_MAJOR_VERSION}KonqConfigVersion.cmake"
0009                   SOVERSION 7
0010 )
0011
0012 # Build dependencies
0013 find_package(Qt${KF_MAJOR_VERSION} CONFIG REQUIRED COMPONENTS Core DBus Widgets)
0014 find_package(KF${KF_MAJOR_VERSION} REQUIRED COMPONENTS Bookmarks Parts)
0015
0016 find_package(ZLIB)
0017 set_package_properties(ZLIB PROPERTIES DESCRIPTION "Support for gzip compressed files and data streams"
0018                        URL "https://www.zlib.net"
0019                        TYPE REQUIRED
0020                        PURPOSE "Required for building LibKonq"
0021                       )
0022
0023 # Targets
0024 add_subdirectory(src)
0025 if(BUILD_TESTING)
0026   add_subdirectory(autotests)
0027 endif()
0028
0029 # CMake files
0030 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF${KF_MAJOR_VERSION}Konq")
0031
0032 configure_package_config_file(
0033   "${CMAKE_CURRENT_SOURCE_DIR}/KonqConfig.cmake.in"
0034   "${CMAKE_CURRENT_BINARY_DIR}/KF${KF_MAJOR_VERSION}KonqConfig.cmake"
0035   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0036 )
0037
0038 install(FILES
0039   "${CMAKE_CURRENT_BINARY_DIR}/KF${KF_MAJOR_VERSION}KonqConfig.cmake"
0040   "${CMAKE_CURRENT_BINARY_DIR}/KF${KF_MAJOR_VERSION}KonqConfigVersion.cmake"
0041   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0042   COMPONENT Devel
0043 )
0044
0045 install(EXPORT KF${KF_MAJOR_VERSION}KonqTargets
0046     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0047     FILE KF${KF_MAJOR_VERSION}KonqTargets.cmake
0048     NAMESPACE KF${KF_MAJOR_VERSION}::
0049 )
0050
0051 install(FILES
0052     ${CMAKE_CURRENT_BINARY_DIR}/konq_version.h
0053     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}
0054     COMPONENT Devel
0055 )