kio-gdrive/src/CMakeLists.txt

0001 include_directories(${CMAKE_SOURCE_DIR})
0002 include_directories(${CMAKE_BINARY_DIR})
0003
0004 add_subdirectory(integration)
0005
0006 set(kio_gdrive_SRCS
0007     kio_gdrive.cpp
0008     pathcache.cpp
0009     abstractaccountmanager.cpp
0010     gdrivehelper.cpp
0011     gdriveurl.cpp)
0012
0013 if (KAccounts${KACCOUNTS_SUFFIX}_FOUND)
0014     set(BACKEND_SRC kaccountsmanager.cpp)
0015     set(BACKEND_HEADER kaccountsmanager.h)
0016     set(BACKEND_CLASSNAME KAccountsManager)
0017     set(BACKEND_LIBS KAccounts${KACCOUNTS_SUFFIX})
0018 else()
0019     set(BACKEND_SRC keychainaccountmanager.cpp)
0020     set(BACKEND_HEADER keychainaccountmanager.h)
0021     set(BACKEND_CLASSNAME KeychainAccountManager)
0022     set(BACKEND_LIBS ${QTKEYCHAIN_LIBRARIES})
0023 endif()
0024
0025 set(kio_gdrive_SRCS ${kio_gdrive_SRCS} ${BACKEND_SRC})
0026 configure_file(gdrivebackend.h.in ${CMAKE_CURRENT_BINARY_DIR}/gdrivebackend.h)
0027
0028 ecm_qt_declare_logging_category(kio_gdrive_SRCS
0029     HEADER gdrivedebug.h
0030     IDENTIFIER GDRIVE
0031     CATEGORY_NAME kf.kio.workers.gdrive)
0032
0033 kcoreaddons_add_plugin(kio_gdrive
0034     SOURCES ${kio_gdrive_SRCS}
0035     INSTALL_NAMESPACE kf${QT_MAJOR_VERSION}/kio)
0036
0037 target_link_libraries(kio_gdrive
0038     Qt::Core
0039     Qt::Network
0040     KF${QT_MAJOR_VERSION}::KIOCore
0041     KF${QT_MAJOR_VERSION}::KIOWidgets
0042     KF${QT_MAJOR_VERSION}::I18n
0043     ${BACKEND_LIBS})
0044
0045 if(QT_MAJOR_VERSION STREQUAL "5")
0046     target_link_libraries(kio_gdrive KPim::GAPICore KPim::GAPIDrive)
0047 else()
0048     target_link_libraries(kio_gdrive KPim6::GAPICore KPim6::GAPIDrive)
0049 endif()
0050
0051 set_target_properties(kio_gdrive PROPERTIES OUTPUT_NAME "gdrive")