network/kio-gdrive/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 # KDE Application Version, managed by release script
0004 set (RELEASE_SERVICE_VERSION_MAJOR "24")
0005 set (RELEASE_SERVICE_VERSION_MINOR "01")
0006 set (RELEASE_SERVICE_VERSION_MICRO "95")
0007 set (RELEASE_SERVICE_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}.${RELEASE_SERVICE_VERSION_MICRO}")
0008 project(kio-gdrive VERSION ${RELEASE_SERVICE_VERSION})
0009
0010 set(QT_MIN_VERSION 5.15.2)
0011 set(KF_MIN_VERSION 5.96.0)
0012 set(KGAPI_MIN_VERSION 5.11.41)
0013 set(KACCOUNTS_MIN_VERSION 20.03.80)
0014 set(QTKEYCHAIN_MIN_VERSION 0.6.0)
0015
0016 find_package(ECM ${KF_MIN_VERSION} REQUIRED NO_MODULE)
0017 set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules" ${ECM_MODULE_PATH})
0018
0019 include(FeatureSummary)
0020 include(KDEInstallDirs)
0021 include(KDECMakeSettings)
0022 include(KDECompilerSettings NO_POLICY_SCOPE)
0023 include(ECMQtDeclareLoggingCategory)
0024 include(ECMSetupVersion)
0025 include(ECMDeprecationSettings)
0026
0027 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} CONFIG REQUIRED COMPONENTS
0028     Gui
0029     Network
0030     Widgets)
0031
0032
0033 find_package(KF${QT_MAJOR_VERSION} ${KF_MIN_VERSION} REQUIRED COMPONENTS
0034     I18n
0035     DocTools
0036     KIO)
0037
0038 if(QT_MAJOR_VERSION STREQUAL "5")
0039     find_package(KPimGAPI ${KGAPI_MIN_VERSION} REQUIRED)
0040 else()
0041     find_package(KPim6GAPI ${KGAPI_MIN_VERSION} REQUIRED)
0042 endif()
0043
0044 find_package(KF${QT_MAJOR_VERSION}Purpose ${KF_MIN_VERSION}) # Optional since it depends on KAccounts
0045
0046 set_package_properties(KF${QT_MAJOR_VERSION}Purpose PROPERTIES TYPE RECOMMENDED PURPOSE "Enables the Share menu plugin.")
0047
0048 if(QT_MAJOR_VERSION STREQUAL "5")
0049   set(KACCOUNTS_SUFFIX "")
0050 else()
0051   set(KACCOUNTS_SUFFIX "6")
0052 endif()
0053
0054 find_package(KAccounts${KACCOUNTS_SUFFIX} ${KACCOUNTS_MIN_VERSION})
0055 set_package_properties(KAccounts${KACCOUNTS_SUFFIX} PROPERTIES
0056     TYPE RECOMMENDED
0057     URL "https://commits.kde.org/kaccounts-integration"
0058     PURPOSE "Enables integration with system-wide accounts.")
0059
0060 if (NOT KAccounts${KACCOUNTS_SUFFIX}_FOUND)
0061     find_package(Qt${QT_MAJOR_VERSION}Keychain ${QTKEYCHAIN_MIN_VERSION} REQUIRED)
0062     set_package_properties(Qt${QT_MAJOR_VERSION}Keychain PROPERTIES
0063         URL "https://github.com/frankosterfeld/qtkeychain"
0064         PURPOSE "Required for secure storage of accounts secrets.")
0065     message(STATUS "Building the QtKeychain backend.")
0066 endif()
0067
0068 find_package(Qt${QT_MAJOR_VERSION}Test QUIET)
0069 set_package_properties(Qt${QT_MAJOR_VERSION}Test PROPERTIES
0070     TYPE OPTIONAL
0071     PURPOSE "Required for building tests.")
0072
0073 if(NOT Qt${QT_MAJOR_VERSION}Test_FOUND)
0074    set(BUILD_TESTING OFF CACHE BOOL "Build the testing tree.")
0075 endif()
0076
0077 ecm_setup_version(${RELEASE_SERVICE_VERSION}
0078     VARIABLE_PREFIX GDRIVE
0079     VERSION_HEADER gdriveversion.h)
0080
0081 add_definitions(-DQT_NO_URL_CAST_FROM_STRING)
0082 add_definitions(-DQT_STRICT_ITERATORS)
0083 add_definitions(-DTRANSLATION_DOMAIN=\"kio5_gdrive\")
0084
0085 ecm_set_disabled_deprecation_versions(QT 5.15.2
0086      KF 5.83.0
0087     )
0088
0089 if(BUILD_TESTING)
0090     add_subdirectory(autotests)
0091 endif()
0092 add_subdirectory(desktop)
0093 add_subdirectory(doc)
0094 add_subdirectory(src)
0095
0096 if (KF${QT_MAJOR_VERSION}Purpose_FOUND)
0097     add_subdirectory(purpose)
0098 endif()
0099
0100 if (KAccounts${KACCOUNTS_SUFFIX}_FOUND)
0101     message(STATUS "Building the KAccounts backend.")
0102     add_subdirectory(kaccounts)
0103 endif()
0104
0105 ki18n_install(po)
0106 kdoctools_install(po)
0107
0108 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)