kio-extras/recentlyused/CMakeLists.txt

0001 add_definitions(-DTRANSLATION_DOMAIN=\"kio6_recentlyused\")
0002
0003 add_library(recentlyused MODULE)
0004 set_target_properties(recentlyused PROPERTIES
0005     OUTPUT_NAME "recentlyused"
0006     LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/bin/kf6/kio"
0007 )
0008 target_sources(recentlyused PRIVATE
0009     recentlyused.cpp
0010 )
0011 # recentlyused.h has examples in the comment secions which match /*,
0012 # so triggering the preprocessor to warn about nested comments.
0013 # Using a pragma to ignore that diagnostic does not work for preprocessor warnings
0014 # so for now simply that warning is completly disabled
0015 if (CMAKE_CXX_COMPILER_ID STREQUAL "GNU" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
0016     set(_flag "-Wno-comment")
0017     check_cxx_compiler_flag(${_flag} _flag_present)
0018     if(_flag_present)
0019         target_compile_options(recentlyused PRIVATE "${_flag}")
0020     endif()
0021 endif()
0022
0023 ecm_qt_declare_logging_category(recentlyused
0024     HEADER recentlyused-logsettings.h
0025     IDENTIFIER KIO_RECENTLYUSED_LOG
0026     CATEGORY_NAME kf.kio.workers.recentlyused
0027     OLD_CATEGORY_NAMES log_kio_recentlyused kf.kio.slaves.recentlyused
0028     DESCRIPTION "KIO recentlyused"
0029     EXPORT KIO_EXTRAS
0030 )
0031
0032 target_link_libraries(recentlyused
0033     KF6::KIOCore
0034     KF6::I18n
0035     Plasma::Activities
0036     Plasma::ActivitiesStats)
0037
0038 install(TARGETS recentlyused DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf6/kio)
0039
0040 # forgetfileitemaction plugin
0041 kcoreaddons_add_plugin(forgetfileitemaction
0042     SOURCES forgetfileitemaction.cpp
0043     INSTALL_NAMESPACE "kf6/kfileitemaction")
0044
0045 target_link_libraries(forgetfileitemaction
0046     KF6::I18n
0047     KF6::KIOWidgets)