kio-extras/man/CMakeLists.txt

0001 add_definitions(-DTRANSLATION_DOMAIN=\"kio6_man\")
0002
0003 remove_definitions(
0004     -DQT_NO_CAST_FROM_ASCII
0005     -DQT_NO_CAST_FROM_BYTEARRAY
0006     -DQT_USE_QSTRINGBUILDER
0007 )
0008
0009 find_package(KF6 REQUIRED COMPONENTS Codecs)
0010
0011 # silence warnings for gperf generating code with 0 for null pointers
0012 set(AVOID_NULLPTR_WARNING_FLAG)
0013 if (CMAKE_CXX_COMPILER_ID STREQUAL "GNU" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
0014     set(_flag "-Wno-zero-as-null-pointer-constant")
0015     check_cxx_compiler_flag(${_flag} _flag_present)
0016     if(_flag_present)
0017         set(AVOID_NULLPTR_WARNING_FLAG ${_flag})
0018     endif()
0019 endif()
0020
0021 if(BUILD_TESTING)
0022     add_subdirectory( tests )
0023 endif()
0024
0025 # intermediate target/library, also used by the tests
0026 add_library(kio_man_debug OBJECT)
0027 target_link_libraries(kio_man_debug
0028     PRIVATE Qt::Core
0029 )
0030 ecm_qt_declare_logging_category(kio_man_debug
0031     HEADER kio_man_debug.h
0032     IDENTIFIER KIO_MAN_LOG
0033     CATEGORY_NAME kf.kio.workers.man
0034     OLD_CATEGORY_NAMES log_kio_man kf.kio.slaves.man
0035     DESCRIPTION "KIO man"
0036     EXPORT KIO_EXTRAS
0037 )
0038
0039 set_property(TARGET kio_man_debug PROPERTY POSITION_INDEPENDENT_CODE ON)
0040
0041 ########### next target ###############
0042
0043 add_library(kio_man MODULE)
0044 set_target_properties(kio_man PROPERTIES
0045     OUTPUT_NAME "man"
0046 )
0047
0048 set(kio_man_generated_SRCS)
0049 ecm_gperf_generate(requests.gperf ${CMAKE_CURRENT_BINARY_DIR}/request_gperf.h kio_man_generated_SRCS)
0050 target_sources(kio_man PRIVATE
0051     ${kio_man_generated_SRCS}
0052     man2html.cpp
0053     kio_man.cpp
0054     request_hash.cpp
0055 )
0056
0057 if (AVOID_NULLPTR_WARNING_FLAG)
0058     target_compile_options(kio_man PRIVATE ${AVOID_NULLPTR_WARNING_FLAG})
0059 endif()
0060
0061 target_link_libraries(kio_man
0062     PRIVATE KF6::KIOCore Qt::Widgets KF6::Archive KF6::I18n KF6::Codecs Qt::Network kio_man_debug
0063 )
0064
0065 if (QT_MAJOR_VERSION STREQUAL "6")
0066     target_link_libraries(kio_man PRIVATE Qt::Core5Compat)
0067 endif()
0068
0069 install(TARGETS kio_man DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf6/kio)