kio-extras/fish/CMakeLists.txt

0001 add_definitions(-DTRANSLATION_DOMAIN=\"kio6_fish\")
0002
0003 remove_definitions(-DQT_NO_CAST_FROM_ASCII)
0004
0005 include(CheckIncludeFiles)
0006 include(CheckFunctionExists)
0007
0008 check_include_files(termios.h HAVE_TERMIOS_H)
0009 check_include_files(util.h HAVE_UTIL_H)
0010 check_include_files(sys/ioctl.h HAVE_SYS_IOCTL_H)
0011 check_include_files(pty.h HAVE_PTY_H)
0012 check_include_files("sys/types.h;libutil.h" HAVE_LIBUTIL_H)
0013 check_function_exists(getpt       HAVE_GETPT)
0014 check_function_exists(grantpt     HAVE_GRANTPT)
0015 include(CheckLibraryExists)
0016 check_library_exists(util  openpty "" HAVE_OPENPTY)
0017 check_library_exists(util  isastream "" HAVE_ISASTREAM)
0018
0019 find_library(UTIL_LIBRARIES util)
0020 mark_as_advanced(UTIL_LIBRARIES)
0021
0022 configure_file(config-fish.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-fish.h)
0023
0024 ########### next target ###############
0025 # on Linux there is md5sum, on FreeBSD there is md5
0026 find_program(MD5SUM_EXECUTABLE NAMES md5sum md5 )
0027
0028 if (MD5SUM_EXECUTABLE)
0029
0030    add_library(kio_fish MODULE)
0031    set_target_properties(kio_fish PROPERTIES
0032       OUTPUT_NAME "fish"
0033    )
0034
0035    if ("${MD5SUM_EXECUTABLE}" MATCHES "md5sum")
0036       set(CUT_ARG "-f 1")                            # for md5sum the sum is in the 1st column
0037    else ()
0038       set(CUT_ARG "-f 4")                            # for md5 the sum is in the 4th column
0039    endif ()
0040
0041    if (WIN32)
0042       set(FISH_GENERATOR "generate_fishcode.bat")
0043    else ()
0044       set(FISH_GENERATOR "generate_fishcode.sh")
0045    endif ()
0046    set(fishcode_HDR "${CMAKE_CURRENT_BINARY_DIR}/fishcode.h")
0047    add_custom_command(OUTPUT ${fishcode_HDR}
0048       COMMAND ${CMAKE_CURRENT_SOURCE_DIR}/${FISH_GENERATOR} ARGS ${CMAKE_CURRENT_SOURCE_DIR}/fish.pl ${MD5SUM_EXECUTABLE} ${fishcode_HDR} "${CUT_ARG}"
0049       DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/fish.pl
0050       WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR} )
0051    set_source_files_properties(${fishcode_HDR} PROPERTIES SKIP_AUTOMOC TRUE)
0052
0053    target_sources(kio_fish PRIVATE
0054       fish.cpp
0055       ${fishcode_HDR}
0056    )
0057
0058    ecm_qt_declare_logging_category(kio_fish
0059       HEADER loggingcategory.h
0060       IDENTIFIER KIO_FISH_DEBUG
0061       CATEGORY_NAME kf.kio.workers.fish
0062       OLD_CATEGORY_NAMES kio_fish kf.kio.slaves.fish
0063       DEFAULT_SEVERITY Info
0064       DESCRIPTION "KIO fish"
0065       EXPORT KIO_EXTRAS
0066    )
0067
0068    target_link_libraries(kio_fish KF6::KIOCore KF6::WidgetsAddons KF6::I18n Qt::Network)
0069
0070    if (UTIL_LIBRARIES)
0071       target_link_libraries(kio_fish ${UTIL_LIBRARIES})
0072    endif ()
0073
0074    install(TARGETS kio_fish  DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf6/kio )
0075
0076 endif ()