kio-extras/archive/CMakeLists.txt

0001 add_definitions(-DTRANSLATION_DOMAIN=\"kio6_archive\")
0002
0003 if(BUILD_TESTING)
0004     add_subdirectory(autotests)
0005 endif()
0006
0007 set(LIBKIOARCHIVE_VERSION "6.0.0")
0008 set(LIBKIOARCHIVE_SOVERSION "6")
0009 set(LIBKIOARCHIVE_INSTALL_INCLUDEDIR "${KDE_INSTALL_INCLUDEDIR}/KioArchive6")
0010
0011 include(ECMSetupVersion)
0012 ecm_setup_version(${LIBKIOARCHIVE_VERSION} VARIABLE_PREFIX "KIOARCHIVE"
0013                   VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kioarchive_version.h"
0014                   PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KioArchive6ConfigVersion.cmake"
0015                   SOVERSION ${LIBKIOARCHIVE_SOVERSION})
0016
0017 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KioArchive6")
0018
0019 configure_package_config_file(
0020   "${CMAKE_CURRENT_SOURCE_DIR}/KioArchive6Config.cmake.in"
0021   "${CMAKE_CURRENT_BINARY_DIR}/KioArchive6Config.cmake"
0022   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0023 )
0024
0025 install(FILES
0026   "${CMAKE_CURRENT_BINARY_DIR}/KioArchive6Config.cmake"
0027   "${CMAKE_CURRENT_BINARY_DIR}/KioArchive6ConfigVersion.cmake"
0028   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0029   COMPONENT Devel
0030 )
0031
0032 install(EXPORT KioArchiveTargets
0033     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0034     FILE KioArchiveTargets.cmake
0035 )
0036
0037 install(FILES
0038     kio_archivebase.h
0039     ${CMAKE_CURRENT_BINARY_DIR}/libkioarchive_export.h
0040     ${CMAKE_CURRENT_BINARY_DIR}/kioarchive_version.h
0041     DESTINATION ${LIBKIOARCHIVE_INSTALL_INCLUDEDIR}
0042     COMPONENT Devel
0043 )
0044
0045 ecm_qt_declare_logging_category(kio_archive_debug_SRCS
0046     HEADER kio_archive_debug.h
0047     IDENTIFIER KIO_ARCHIVE_LOG
0048     CATEGORY_NAME kf.kio.workers.archive
0049     OLD_CATEGORY_NAMES log_kio_archive kf.kio.slaves.archive
0050     DESCRIPTION "KIO archive"
0051     EXPORT KIO_EXTRAS
0052 )
0053
0054 ############### ArchiveProtocolBase library ###########
0055
0056 add_library(kioarchive6 kio_archivebase.cpp ${kio_archive_debug_SRCS})
0057
0058 include(GenerateExportHeader)
0059 generate_export_header(kioarchive6 BASE_NAME libkioarchive EXPORT_FILE_NAME libkioarchive_export.h)
0060
0061 target_compile_definitions(kioarchive6
0062     PRIVATE
0063         -DKIOCORE_DISABLE_DEPRECATED_BEFORE_AND_AT=0x054400 # need to support KIO::detailsToStatDetails
0064 )
0065
0066 target_link_libraries(kioarchive6
0067     PUBLIC
0068     KF6::Archive
0069     KF6::KIOCore
0070     PRIVATE
0071     KF6::I18n
0072     Qt::Network
0073     Qt::DBus
0074 )
0075
0076 set_target_properties(kioarchive6 PROPERTIES
0077     VERSION ${KIOARCHIVE_VERSION}
0078     SOVERSION ${KIOARCHIVE_SOVERSION}
0079     EXPORT_NAME KioArchive
0080 )
0081
0082 target_include_directories(kioarchive6
0083     INTERFACE "$<INSTALL_INTERFACE:${LIBKIOARCHIVE_INSTALL_INCLUDEDIR}>"
0084 )
0085
0086 install(TARGETS kioarchive6 EXPORT KioArchiveTargets LIBRARY NAMELINK_SKIP ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0087
0088 ############### Archive Worker ######################
0089
0090 add_library(kio_archive MODULE kio_archive.cpp ${kio_archive_debug_SRCS})
0091 target_link_libraries(kio_archive KF6::KIOCore KF6::Archive kioarchive6 Qt::Network)
0092 set_target_properties(kio_archive PROPERTIES OUTPUT_NAME "archive")
0093 install(TARGETS kio_archive DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf6/kio)