kdeconnect-kde/core/CMakeLists.txt

0001 add_definitions(-DTRANSLATION_DOMAIN=\"kdeconnect-core\")
0002
0003 set(KDECONNECT_PRIVATE_DBUS_ADDR unix:tmpdir=/tmp)
0004 if(WIN32)
0005     set(KDECONNECT_PRIVATE_DBUS_ADDR tcp:host=localhost,port=0)
0006 endif()
0007 set(KDECONNECT_PRIVATE_DBUS_NAME DBusKDEConnectOnly)
0008 configure_file(dbushelper.h.in ${CMAKE_CURRENT_BINARY_DIR}/dbushelper.h)
0009
0010 option(MDNS_ENABLED "Use MDNS for device discovery" ON)
0011
0012 add_subdirectory(backends/lan)
0013 add_subdirectory(backends/loopback)
0014
0015 option(BLUETOOTH_ENABLED "Bluetooth support for kdeconnect" ON)
0016 if(BLUETOOTH_ENABLED)
0017     find_package(Qt6 ${QT_MIN_VERSION} REQUIRED COMPONENTS Bluetooth)
0018     add_subdirectory(backends/bluetooth)
0019 endif()
0020
0021 option(LOOPBACK_ENABLED "Loopback backend enabled" OFF)
0022
0023 add_library(kdeconnectcore)
0024 target_sources(kdeconnectcore PRIVATE
0025     ${backends_kdeconnect_SRCS}
0026
0027     backends/linkprovider.cpp
0028     backends/devicelink.cpp
0029     backends/pairinghandler.cpp
0030
0031     kdeconnectplugin.cpp
0032     kdeconnectpluginconfig.cpp
0033     pluginloader.cpp
0034
0035     kdeconnectconfig.cpp
0036     dbushelper.cpp
0037     networkpacket.cpp
0038     filetransferjob.cpp
0039     compositefiletransferjob.cpp
0040     daemon.cpp
0041     device.cpp
0042     sslhelper.cpp
0043     core_debug.cpp
0044     notificationserverinfo.cpp
0045     openconfig.cpp
0046 )
0047 ecm_qt_declare_logging_category(kdeconnectcore
0048     HEADER kdeconnect_debug.h
0049     IDENTIFIER KDECONNECT_CORE CATEGORY_NAME kdeconnect.core
0050     DEFAULT_SEVERITY Warning
0051     EXPORT kdeconnect-kde DESCRIPTION "kdeconnect (core)")
0052
0053
0054 target_include_directories(kdeconnectcore PUBLIC ${PROJECT_SOURCE_DIR})
0055
0056 find_package(OpenSSL REQUIRED COMPONENTS Crypto)
0057
0058 target_link_libraries(kdeconnectcore
0059 PUBLIC
0060     Qt::Network
0061     KF6::CoreAddons
0062     KF6::KIOCore
0063     KF6::KIOGui
0064     OpenSSL::Crypto
0065 PRIVATE
0066     Qt::DBus
0067     KF6::I18n
0068     KF6::ConfigCore
0069 )
0070
0071 if(WIN32)
0072     target_link_libraries(kdeconnectcore PRIVATE ws2_32.lib) # winsock2
0073 endif()
0074
0075 if (BLUETOOTH_ENABLED)
0076     target_compile_definitions(kdeconnectcore PRIVATE -DKDECONNECT_BLUETOOTH)
0077     target_link_libraries(kdeconnectcore PRIVATE Qt6::Bluetooth)
0078 endif()
0079
0080 if (LOOPBACK_ENABLED)
0081     target_compile_definitions(kdeconnectcore PRIVATE -DKDECONNECT_LOOPBACK)
0082 endif()
0083
0084 if (MDNS_ENABLED)
0085     target_compile_definitions(kdeconnectcore PRIVATE -DKDECONNECT_MDNS)
0086 endif()
0087
0088 set_target_properties(kdeconnectcore PROPERTIES
0089     VERSION ${KDECONNECT_VERSION}
0090     SOVERSION ${KDECONNECT_VERSION_MAJOR}
0091 )
0092
0093 generate_export_header(kdeconnectcore EXPORT_FILE_NAME kdeconnectcore_export.h BASE_NAME KDEConnectCore)
0094
0095 install(TARGETS kdeconnectcore EXPORT kdeconnectLibraryTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)