src/lib/CMakeLists.txt

0001 if(QT_MAJOR_VERSION STREQUAL "5")
0002   set(KACCOUNTS_SUFFIX "")
0003 else()
0004   set(KACCOUNTS_SUFFIX "6")
0005 endif()
0006
0007 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KAccounts${KACCOUNTS_SUFFIX}")
0008
0009 ecm_setup_version(${KACCOUNTS_VERSION}
0010   VARIABLE_PREFIX KACCOUNTS
0011   VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kaccounts_version.h"
0012   PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KAccounts${KACCOUNTS_SUFFIX}ConfigVersion.cmake"
0013   SOVERSION ${KACCOUNTS_SOVERSION})
0014
0015 set (kaccountslib_SRCS
0016      accountsmodel.cpp
0017      core.cpp
0018      kaccountsdplugin.cpp
0019      kaccountsuiplugin.cpp
0020      providersmodel.cpp
0021      servicesmodel.cpp
0022      uipluginsmanager.cpp
0023
0024      accountservicetogglejob.cpp
0025      changeaccountdisplaynamejob.cpp
0026      createaccountjob.cpp
0027      getcredentialsjob.cpp
0028      removeaccountjob.cpp
0029
0030      accountsmodel.h
0031      core.h
0032      kaccountsdplugin.h
0033      kaccountsuiplugin.h
0034      providersmodel.h
0035      servicesmodel.h
0036      uipluginsmanager.h
0037
0038      accountservicetogglejob.h
0039      changeaccountdisplaynamejob.h
0040      createaccountjob.h
0041      getcredentialsjob.h
0042      removeaccountjob.h
0043 )
0044
0045 # For the Qt5 build keep the old header layout for compatibility
0046 if(QT_MAJOR_VERSION STREQUAL "5")
0047   ecm_generate_headers(kaccountslib_HEADERS
0048     HEADER_NAMES
0049     AccountsModel
0050     Core
0051     KAccountsUiPlugin
0052     KAccountsDPlugin
0053     ProvidersModel
0054     ServicesModel
0055
0056     AccountServiceToggleJob
0057     ChangeAccountDisplayNameJob
0058     CreateAccountJob
0059     GetCredentialsJob
0060     RemoveAccountJob
0061     REQUIRED_HEADERS kaccountslib_HEADERS
0062   )
0063 else()
0064   ecm_generate_headers(kaccountslib_CamelCase_HEADERS
0065     HEADER_NAMES
0066     AccountsModel
0067     Core
0068     KAccountsUiPlugin
0069     KAccountsDPlugin
0070     ProvidersModel
0071     ServicesModel
0072
0073     AccountServiceToggleJob
0074     ChangeAccountDisplayNameJob
0075     CreateAccountJob
0076     GetCredentialsJob
0077     RemoveAccountJob
0078     PREFIX KAccounts
0079     REQUIRED_HEADERS kaccountslib_HEADERS
0080   )
0081 endif()
0082
0083 add_library(kaccounts ${kaccountslib_SRCS})
0084
0085 target_compile_definitions(kaccounts
0086     PRIVATE
0087     ACCOUNTSQT5_VERSION_MAJOR=${AccountsQt5_VERSION_MAJOR}
0088     ACCOUNTSQT5_VERSION_MINOR=${AccountsQt5_VERSION_MINOR}
0089 )
0090
0091 generate_export_header(kaccounts BASE_NAME kaccounts)
0092 target_link_libraries (kaccounts
0093     PUBLIC
0094         KF${QT_MAJOR_VERSION}::CoreAddons
0095         KF${QT_MAJOR_VERSION}::I18n
0096         ${ACCOUNTSQT_LIBRARIES}
0097         Qt::Xml
0098         Qt::Gui
0099     PRIVATE
0100         ${SIGNONQT_LIBRARIES}
0101 )
0102
0103 target_include_directories(kaccounts
0104     INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/KAccounts${KACCOUNTS_SUFFIX}>"
0105 )
0106
0107 target_include_directories(kaccounts SYSTEM
0108     PUBLIC "${ACCOUNTSQT_INCLUDE_DIRS}"
0109     PRIVATE "${SIGNONQT_INCLUDE_DIRS}"
0110 )
0111 set_target_properties(kaccounts PROPERTIES VERSION   ${KACCOUNTS_VERSION}
0112                                            SOVERSION ${KACCOUNTS_SOVERSION}
0113                                            EXPORT_NAME KAccounts${KACCOUNTS_SUFFIX}
0114                                            LIBRARY_OUTPUT_NAME kaccounts${KACCOUNTS_SUFFIX}
0115 )
0116
0117 configure_package_config_file(
0118   "${CMAKE_CURRENT_SOURCE_DIR}/KAccountsConfig.cmake.in"
0119   "${CMAKE_CURRENT_BINARY_DIR}/KAccounts${KACCOUNTS_SUFFIX}Config.cmake"
0120   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0121 )
0122
0123 install(FILES
0124   "KAccountsMacros.cmake"
0125   "${CMAKE_CURRENT_BINARY_DIR}/KAccounts${KACCOUNTS_SUFFIX}Config.cmake"
0126   "${CMAKE_CURRENT_BINARY_DIR}/KAccounts${KACCOUNTS_SUFFIX}ConfigVersion.cmake"
0127   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0128   COMPONENT Devel
0129 )
0130
0131 install(TARGETS kaccounts EXPORT KAccounts${KACCOUNTS_SUFFIX}Targets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0132
0133 install(EXPORT KAccounts${KACCOUNTS_SUFFIX}Targets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KAccounts${KACCOUNTS_SUFFIX}Targets.cmake ) #NAMESPACE KF${QT_MAJOR_VERSION}::
0134
0135 if(QT_MAJOR_VERSION STREQUAL "5")
0136   install (FILES
0137         ${CMAKE_CURRENT_BINARY_DIR}/kaccounts_export.h
0138         ${kaccountslib_HEADERS}
0139         ${CMAKE_CURRENT_BINARY_DIR}/kaccounts_version.h
0140         DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KAccounts COMPONENT Devel
0141   )
0142
0143 else()
0144   install (FILES
0145           ${CMAKE_CURRENT_BINARY_DIR}/kaccounts_export.h
0146           ${CMAKE_CURRENT_BINARY_DIR}/kaccounts_version.h
0147           DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KAccounts${KACCOUNTS_SUFFIX} COMPONENT Devel
0148   )
0149
0150   install (FILES
0151           ${kaccountslib_HEADERS}
0152           DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KAccounts${KACCOUNTS_SUFFIX}/kaccounts COMPONENT Devel
0153   )
0154
0155   install (FILES
0156           ${kaccountslib_CamelCase_HEADERS}
0157           DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KAccounts${KACCOUNTS_SUFFIX}/KAccounts COMPONENT Devel
0158   )
0159 endif()