network/kaccounts-integration/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(RELEASE_SERVICE_VERSION_MAJOR "23")
0004 set(RELEASE_SERVICE_VERSION_MINOR "07")
0005 set(RELEASE_SERVICE_VERSION_MICRO "70")
0006 set(KACCOUNTS_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}.${RELEASE_SERVICE_VERSION_MICRO}")
0007
0008 project(KAccounts LANGUAGES CXX VERSION ${KACCOUNTS_VERSION})
0009
0010 set(QT_REQUIRED_VERSION "5.15.2")
0011 set(KF_MIN_VERSION "5.97.0")
0012 set(CMAKE_CXX_STANDARD 20)
0013 set(CMAKE_CXX_STANDARD_REQUIRED ON)
0014
0015 find_package(ECM ${KF_MIN_VERSION} REQUIRED NO_MODULE)
0016 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0017
0018 include(KDEInstallDirs)
0019 include(KDECMakeSettings)
0020 include(KDECompilerSettings NO_POLICY_SCOPE)
0021
0022 include(ECMInstallIcons)
0023 include(ECMSetupVersion)
0024 include(ECMGenerateHeaders)
0025 include(KDEClangFormat)
0026 include(KDEGitCommitHooks)
0027 include(CMakePackageConfigHelpers)
0028 include(GenerateExportHeader)
0029 include(FeatureSummary)
0030 include(ECMQmlModule)
0031 include(ECMDeprecationSettings)
0032
0033 set(KACCOUNTS_SOVERSION "2")
0034 set(ACCOUNTSQT_DEP_VERSION "1.16")
0035 set(SIGNONQT_DEP_VERSION "8.55")
0036 set(ACCOUNTSGLIB_DEP_VERSION "1.21")
0037
0038 find_package(Qt${QT_MAJOR_VERSION} ${QT_REQUIRED_VERSION} CONFIG REQUIRED Core Widgets)
0039 find_package(KF${QT_MAJOR_VERSION} ${KF_MIN_VERSION} REQUIRED KCMUtils I18n CoreAddons DBusAddons Declarative Wallet KIO Package)
0040
0041 find_package(AccountsQt${QT_MAJOR_VERSION} ${ACCOUNTSQT_DEP_VERSION} CONFIG)
0042 set_package_properties(AccountsQt${QT_MAJOR_VERSION} PROPERTIES DESCRIPTION "Accounts management library for Qt applications"
0043    URL "https://gitlab.com/accounts-sso/libaccounts-qt"
0044    TYPE REQUIRED
0045    PURPOSE "Required for building this module")
0046
0047 find_package(SignOnQt${QT_MAJOR_VERSION} ${SIGNONQT_DEP_VERSION} CONFIG)
0048 set_package_properties(SignOnQt${QT_MAJOR_VERSION} PROPERTIES DESCRIPTION "D-Bus service which performs user authentication on behalf of its clients"
0049    URL "https://gitlab.com/accounts-sso/signond"
0050    TYPE REQUIRED
0051    PURPOSE "Required for building this module")
0052
0053 find_package(QCoro${QT_MAJOR_VERSION} REQUIRED COMPONENTS Core)
0054
0055 qcoro_enable_coroutines()
0056
0057 add_definitions (-DTRANSLATION_DOMAIN=\"kaccounts-integration\")
0058
0059 ecm_set_disabled_deprecation_versions(QT 5.13.0
0060      KF 5.101.0
0061     )
0062
0063
0064 add_subdirectory(src)
0065
0066 ki18n_install(po)
0067
0068 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h)
0069 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0070
0071 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0072
0073 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)