src/main/CMakeLists.txt

0001 include_directories(
0002   ../lib/3rdparty
0003   ../lib/app
0004   ../lib/session
0005   ../lib/webengine
0006   ../lib/webtab
0007 )
0008 set(SRCS main.cpp)
0009 if (WIN32)
0010     set(SRCS ${SRCS} version.rc)
0011     configure_file(falkonversion.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/falkonversion.h)
0012 endif()
0013 ecm_create_qm_loader(SRCS falkon_qt)
0014 add_executable(falkon ${SRCS})
0015
0016 target_link_libraries(falkon FalkonPrivate)
0017
0018 if (APPLE)
0019     set_target_properties(falkon PROPERTIES MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/Info.plist)
0020     set_target_properties(falkon PROPERTIES MACOSX_BUNDLE_GUI_IDENTIFIER "org.kde.falkon")
0021     set_target_properties(falkon PROPERTIES MACOSX_BUNDLE_BUNDLE_NAME "Falkon")
0022     install(FILES lib/data/icons/exeicons/falkon.icns DESTINATION ${BUNDLE_INSTALL_DIR}/falkon.app/Contents/Resources)
0023     #install(DIRECTORY ${CMAKE_BINARY_DIR}/bin/locale DESTINATION ${BUNDLE_INSTALL_DIR}/falkon.app/Contents/Resources)
0024     install(DIRECTORY ${CMAKE_SOURCE_DIR}/themes DESTINATION ${BUNDLE_INSTALL_DIR}/falkon.app/Contents/Resources)
0025     install(DIRECTORY ${CMAKE_BINARY_DIR}/bin/plugins DESTINATION ${BUNDLE_INSTALL_DIR}/falkon.app/Contents/Resources)
0026 endif ()
0027
0028 if (CMAKE_SYSTEM_NAME MATCHES FreeBSD OR CMAKE_SYSTEM_NAME MATCHES OpenBSD)
0029     target_link_libraries(falkon execinfo)
0030 endif()
0031
0032 if (UNIX AND NOT APPLE)
0033     install(TARGETS falkon ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0034     install(DIRECTORY ${CMAKE_SOURCE_DIR}/themes DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/falkon)
0035     if (KF6I18n_FOUND)
0036         ki18n_install(${CMAKE_SOURCE_DIR}/po)
0037     endif()
0038     ecm_install_po_files_as_qm(${CMAKE_SOURCE_DIR}/poqm)
0039
0040     install(PROGRAMS ../../linux/applications/org.kde.falkon.desktop DESTINATION ${KDE_INSTALL_APPDIR})
0041
0042     ecm_install_icons(ICONS
0043         ../../linux/hicolor/16-apps-falkon.png
0044         ../../linux/hicolor/32-apps-falkon.png
0045         ../../linux/hicolor/48-apps-falkon.png
0046         ../../linux/hicolor/64-apps-falkon.png
0047         ../../linux/hicolor/128-apps-falkon.png
0048         ../../linux/hicolor/256-apps-falkon.png
0049         ../../linux/hicolor/sc-apps-falkon.svg
0050         DESTINATION ${KDE_INSTALL_ICONDIR} THEME hicolor)
0051
0052     install(FILES ../../linux/completion/falkon DESTINATION ${KDE_INSTALL_DATADIR}/bash-completion/completions)
0053     install(FILES ../../linux/appdata/org.kde.falkon.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
0054 endif()
0055