network/alligator/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2020 Tobias Fella <fella@posteo.de>
0002 # SPDX-FileCopyrightText: 2020 Nicolas Fella <nicolas.fella@gmx.de>
0003 # SPDX-License-Identifier: BSD-2-Clause
0004
0005 cmake_minimum_required(VERSION 3.16)
0006
0007 # KDE Applications version, managed by release script.
0008 set(RELEASE_SERVICE_VERSION_MAJOR "23")
0009 set(RELEASE_SERVICE_VERSION_MINOR "08")
0010 set(RELEASE_SERVICE_VERSION_MICRO "5")
0011 set(RELEASE_SERVICE_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}.${RELEASE_SERVICE_VERSION_MICRO}")
0012
0013 project(alligator VERSION ${RELEASE_SERVICE_VERSION})
0014
0015 set(KF_MIN_VERSION "5.90.0")
0016 set(QT_MIN_VERSION "5.15.0")
0017 if (ANDROID)
0018     set(QT_MIN_VERSION "5.15.10")
0019 endif()
0020
0021 find_package(ECM ${KF_MIN_VERSION} REQUIRED NO_MODULE)
0022
0023 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0024
0025 include(FeatureSummary)
0026 include(ECMSetupVersion)
0027 include(KDEInstallDirs)
0028 include(KDEClangFormat)
0029 include(KDECMakeSettings)
0030 include(KDEGitCommitHooks)
0031 include(KDECompilerSettings NO_POLICY_SCOPE)
0032
0033 ecm_setup_version(${PROJECT_VERSION}
0034     VARIABLE_PREFIX ALLIGATOR
0035     VERSION_HEADER ${CMAKE_CURRENT_BINARY_DIR}/alligator-version.h
0036 )
0037
0038 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} REQUIRED NO_MODULE COMPONENTS Core Quick Test Gui QuickControls2 Sql)
0039 find_package(KF${QT_MAJOR_VERSION} ${KF_MIN_VERSION} REQUIRED COMPONENTS CoreAddons Syndication Config I18n)
0040
0041 find_package(KF${QT_MAJOR_VERSION}KirigamiAddons 0.6 REQUIRED)
0042
0043 if (ANDROID)
0044     find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} REQUIRED COMPONENTS Svg)
0045     find_package(KF${QT_MAJOR_VERSION} ${KF_MIN_VERSION} REQUIRED COMPONENTS Kirigami2)
0046     find_package(OpenSSL REQUIRED)
0047     find_package(SQLite3)
0048 else()
0049     find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} REQUIRED COMPONENTS Widgets)
0050 endif()
0051
0052 add_definitions(-DQT_NO_CAST_FROM_ASCII
0053                 -DQT_NO_CAST_TO_ASCII
0054                 -DQT_NO_URL_CAST_FROM_STRING
0055                 -DQT_NO_NARROWING_CONVERSIONS_IN_CONNECT
0056                 -DQT_USE_QSTRINGBUILDER
0057                 -DQT_DISABLE_DEPRECATED_BEFORE=0x050d00
0058 )
0059
0060 ki18n_install(po)
0061
0062 if (ANDROID)
0063     configure_file(${CMAKE_CURRENT_SOURCE_DIR}/android/version.gradle.in ${CMAKE_BINARY_DIR}/version.gradle)
0064 endif()
0065
0066 install(PROGRAMS org.kde.alligator.desktop DESTINATION ${KDE_INSTALL_APPDIR})
0067 install(FILES org.kde.alligator.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
0068 install(FILES alligator.svg DESTINATION ${KDE_INSTALL_FULL_ICONDIR}/hicolor/scalable/apps)
0069
0070 add_subdirectory(src)
0071
0072 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)
0073
0074 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0075
0076 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES src/*.cpp src/*.h)
0077 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})