subtitlecomposer/cmake/FindPocketSphinx.cmake

0001 # - Try to find PocketSphinx
0002 # Once done this will define
0003 #  POCKETSPHINX_FOUND - System has PocketSphinx
0004 #  POCKETSPHINX_VERSION - PocketSphinx version
0005 #  POCKETSPHINX_INCLUDE_DIRS - The PocketSphinx include directories
0006 #  POCKETSPHINX_LIBRARIES - The libraries needed to use PocketSphinx
0007 #  POCKETSPHINX_DEFINITIONS - Compiler switches required for using PocketSphinx
0008 #  POCKETSPHINX_MODELDIR - Directory that contains PocketSphinx models
0009
0010 # SPDX-FileCopyrightText: 2010-2019 Mladen Milinkovic <maxrd2@smoothware.net>
0011 # SPDX-License-Identifier: BSD-3-Clause
0012
0013 find_package(PkgConfig REQUIRED)
0014 pkg_check_modules(PC_POCKETSPHINX QUIET pocketsphinx)
0015 set(POCKETSPHINX_DEFINITIONS ${PC_POCKETSPHINX_CFLAGS_OTHER})
0016 set(POCKETSPHINX_VERSION ${PC_POCKETSPHINX_VERSION})
0017
0018 find_path(POCKETSPHINX_INCDIR pocketsphinx.h HINTS ${PC_POCKETSPHINX_INCLUDEDIR} ${PC_POCKETSPHINX_INCLUDE_DIRS})
0019 find_path(SPHINXBASE_INCDIR sphinx_config.h HINTS ${PC_POCKETSPHINX_INCLUDEDIR} ${PC_POCKETSPHINX_INCLUDE_DIRS})
0020 set(POCKETSPHINX_INCLUDE_DIR ${POCKETSPHINX_INCDIR} ${SPHINXBASE_INCDIR})
0021 unset(POCKETSPHINX_INCDIR)
0022 unset(SPHINXBASE_INCDIR)
0023
0024 foreach(_LIB ${PC_POCKETSPHINX_LIBRARIES})
0025         set(_LIB_PATH "_LIB_PATH-NOTFOUND")
0026         find_library(_LIB_PATH
0027                 NAMES ${_LIB}
0028                 HINTS ${PC_POCKETSPHINX_LIBDIR} ${PC_POCKETSPHINX_LIBRARY_DIRS})
0029         set(POCKETSPHINX_LIBRARIES ${POCKETSPHINX_LIBRARIES} ${_LIB_PATH})
0030 endforeach(_LIB)
0031
0032 set(POCKETSPHINX_INCLUDE_DIRS ${POCKETSPHINX_INCLUDE_DIR})
0033
0034 include(FindPackageHandleStandardArgs)
0035 # handle the QUIETLY and REQUIRED arguments and set POCKETSPHINX_FOUND to TRUE if all listed variables are TRUE
0036 find_package_handle_standard_args(PocketSphinx
0037         REQUIRED_VARS POCKETSPHINX_LIBRARIES POCKETSPHINX_INCLUDE_DIR
0038         VERSION_VAR POCKETSPHINX_VERSION)
0039
0040 execute_process(COMMAND pkg-config --variable=modeldir pocketsphinx
0041                                 OUTPUT_VARIABLE POCKETSPHINX_MODELDIR_OUTPUT
0042                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
0043 set(POCKETSPHINX_MODELDIR ${POCKETSPHINX_MODELDIR_OUTPUT})
0044
0045 mark_as_advanced(POCKETSPHINX_INCLUDE_DIR POCKETSPHINX_LIBRARY)