subtitlecomposer/cmake/FindICU.cmake

0001 # Tries to find ICU library
0002 # Once done this will define
0003 #
0004 #  ICU_FOUND - System has ICU library
0005 #  ICU_VERSION - ICU library version
0006 #  ICU_LIBRARIES - Link these to use ICU library
0007 #  ICU_INCLUDE_DIRS - ICU library include dirs
0008 #  ICU_DEFINITIONS - compiler switches required for using ICU library
0009
0010 # SPDX-FileCopyrightText: 2010-2019 Mladen Milinkovic <maxrd2@smoothware.net>
0011 # SPDX-License-Identifier: BSD-3-Clause
0012
0013 find_package(PkgConfig REQUIRED)
0014
0015 pkg_check_modules(PC_ICU QUIET icu-i18n)
0016
0017 find_path(ICU_INCLUDE_DIRS
0018         unicode/utypes.h
0019         HINTS ${PC_ICU_INCLUDEDIR} ${PC_ICU_INCLUDE_DIRS}
0020         DOC "Include directory for the ICU library")
0021 set(_required_vars ICU_INCLUDE_DIRS)
0022
0023 foreach(_lib ${PC_ICU_LIBRARIES})
0024         find_library(_lib_${_lib}
0025                 NAMES ${_lib}
0026                 HINTS ${PC_ICU_LIBDIR} ${PC_ICU_LIBRARY_DIRS})
0027         list(APPEND ICU_LIBRARIES ${_lib_${_lib}})
0028         list(APPEND _required_vars _lib_${_lib})
0029 endforeach()
0030
0031 set(_message "\n\tincludes: ${ICU_INCLUDE_DIRS}\n\tlibs: ${ICU_LIBRARIES}\n\t")
0032
0033 include(FindPackageHandleStandardArgs)
0034 # handle the QUIETLY and REQUIRED arguments and set FFMPEG_FOUND to TRUE if all listed variables are TRUE
0035 find_package_handle_standard_args(ICU
0036         REQUIRED_VARS _message ${_required_vars}
0037         VERSION_VAR PC_ICU_VERSION)
0038
0039 if(ICU_FOUND)
0040         set(ICU_DEFINITIONS -D_REENTRANT)
0041 endif()
0042
0043 mark_as_advanced(ICU_INCLUDE_DIRS ICU_LIBRARIES ICU_DEFINITIONS)