subtitlecomposer/cmake/FindFFmpeg.cmake

0001 # Tries to find FFmpeg libraries
0002 # Once done this will define
0003 #
0004 #  FFMPEG_FOUND - System has FFmpeg
0005 #  FFMPEG_VERSION - FFmpeg version (it's actually libavformat version)
0006 #  FFMPEG_INCLUDE_DIRS - FFmpeg include directories
0007 #  FFMPEG_LIBRARIES - FFmpeg libraries
0008 #
0009 # disabled: AVDEVICE POSTPROC AVFILTER
0010 set(_avmodules AVFORMAT AVCODEC SWRESAMPLE SWSCALE AVUTIL)
0011 #  FFMPEG_(avmodule)_VERSION - module version
0012 #  FFMPEG_(avmodule)_INCLUDE_DIR - module include directory
0013 #  FFMPEG_(avmodule)_LIBRARY - module library
0014
0015 # SPDX-FileCopyrightText: 2010-2019 Mladen Milinkovic <maxrd2@smoothware.net>
0016 # SPDX-License-Identifier: BSD-3-Clause
0017
0018 find_package(PkgConfig REQUIRED)
0019
0020 foreach(MODULE ${_avmodules})
0021         string(TOLOWER ${MODULE} module)
0022
0023         pkg_check_modules(PC_FFMPEG_${MODULE} QUIET lib${module})
0024         set(FFMPEG_${MODULE}_VERSION ${PC_FFMPEG_${MODULE}_VERSION})
0025
0026         find_path(FFMPEG_${MODULE}_INCLUDE_DIR lib${module}/version.h
0027                 HINTS
0028                         ${PC_FFMPEG_${MODULE}_INCLUDEDIR} ${PC_FFMPEG_${MODULE}_INCLUDE_DIRS}
0029                 PATH_SUFFIXES ffmpeg)
0030         list(APPEND _required_vars FFMPEG_${MODULE}_INCLUDE_DIR)
0031         list(APPEND FFMPEG_INCLUDE_DIRS ${FFMPEG_${MODULE}_INCLUDE_DIR})
0032
0033         find_library(FFMPEG_${MODULE}_LIBRARY
0034                 NAMES ${module}
0035                 HINTS
0036                         ${PC_FFMPEG_${MODULE}_LIBDIR} ${PC_FFMPEG_${MODULE}_LIBRARY_DIRS})
0037         list(APPEND _required_vars FFMPEG_${MODULE}_LIBRARY)
0038         list(APPEND FFMPEG_LIBRARIES ${FFMPEG_${MODULE}_LIBRARY})
0039 endforeach()
0040 list(REMOVE_DUPLICATES FFMPEG_INCLUDE_DIRS)
0041
0042 set(_message "\n\tincludes: ${FFMPEG_INCLUDE_DIRS}\n\tlibs:")
0043 foreach(MODULE ${_avmodules})
0044         set(_message "${_message}\t${FFMPEG_${MODULE}_LIBRARY} (version ${FFMPEG_${MODULE}_VERSION})\n\t")
0045 endforeach()
0046
0047 include(FindPackageHandleStandardArgs)
0048 # handle the QUIETLY and REQUIRED arguments and set FFMPEG_FOUND to TRUE if all listed variables are TRUE
0049 find_package_handle_standard_args(FFmpeg
0050         REQUIRED_VARS _message ${_required_vars}
0051         VERSION_VAR FFMPEG_AVFORMAT_VERSION)
0052
0053 #if(FFMPEG_FOUND AND NOT FFmpeg_FIND_QUIETLY)
0054 #       message(STATUS "Found FFmpeg:\n\tinclude dir: ${FFMPEG_INCLUDE_DIRS}")
0055 #       foreach(MODULE ${_avmodules})
0056 #               message(STATUS "\t${FFMPEG_${MODULE}_LIBRARY} (version ${FFMPEG_${MODULE}_VERSION})")
0057 #       endforeach()
0058 #endif()
0059
0060 mark_as_advanced(FFMPEG_INCLUDE_DIRS FFMPEG_LIBRARIES ${_required_vars})