multimedia/libkcompactdisc/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 project(KCompactDisc VERSION 5.0.0)
0004
0005 set(QT_MIN_VERSION "5.15.2")
0006 set(KF_MIN_VERSION "5.92.0")
0007
0008 # Dependencies
0009 include(FeatureSummary)
0010 find_package(ECM ${KF_MIN_VERSION} NO_MODULE)
0011 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0012
0013 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0014 set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake" ${CMAKE_MODULE_PATH})
0015
0016 include(KDEInstallDirs)
0017 include(KDECMakeSettings)
0018 include(KDECompilerSettings NO_POLICY_SCOPE)
0019
0020 include(ECMGenerateHeaders)
0021 include(ECMSetupVersion)
0022 include(ECMGeneratePriFile)
0023 include(ECMGenerateExportHeader)
0024 include(CMakePackageConfigHelpers)
0025 include(ECMDeprecationSettings)
0026 if (QT_MAJOR_VERSION STREQUAL "6")
0027     set(QT_REQUIRED_VERSION "6.5.0")
0028     set(KF_MIN_VERSION "5.240.0")
0029     set(KF_MAJOR_VERSION "6")
0030 else()
0031     set(KF_MAJOR_VERSION "5")
0032 endif()
0033
0034 # Qt5, KF5 and Phonon Packages
0035
0036 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} REQUIRED COMPONENTS Core DBus)
0037 find_package(KF${KF_MAJOR_VERSION} ${KF_MIN_VERSION} REQUIRED COMPONENTS
0038     Solid
0039     I18n
0040 )
0041 find_package(Phonon4Qt${QT_MAJOR_VERSION} 4.8.0 CONFIG REQUIRED)
0042
0043 # Sources
0044 if (QT_MAJOR_VERSION STREQUAL "6")
0045     ecm_set_disabled_deprecation_versions(
0046         QT 6.5
0047         KF 5.239
0048     )
0049 else()
0050     ecm_set_disabled_deprecation_versions(
0051         QT 5.15.2
0052         KF 5.100.0
0053     )
0054 endif()
0055
0056 add_subdirectory(src)
0057 if(BUILD_TESTING)
0058     add_subdirectory(tests)
0059 endif()
0060
0061 ki18n_install(po)
0062
0063 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)