Warning, /multimedia/kwave/CMakeLists.txt is written in an unsupported language. File is not indexed.
0001 #############################################################################
0002 ## Kwave - CMakeLists.txt
0003 ## -------------------
0004 ## begin : Tue May 01 2007
0005 ## copyright : (C) 2007 by Thomas Eschenbacher
0006 ## email : Thomas.Eschenbacher@gmx.de
0007 #############################################################################
0008 #
0009 #############################################################################
0010 # #
0011 # Redistribution and use in source and binary forms, with or without #
0012 # modification, are permitted provided that the following conditions #
0013 # are met: #
0014 # #
0015 # 1. Redistributions of source code must retain the above copyright #
0016 # notice, this list of conditions and the following disclaimer. #
0017 # 2. Redistributions in binary form must reproduce the above copyright #
0018 # notice, this list of conditions and the following disclaimer in the #
0019 # documentation and/or other materials provided with the distribution. #
0020 # #
0021 # For details see the accompanying cmake/COPYING-CMAKE-SCRIPTS file. #
0022 # #
0023 #############################################################################
0024
0025 # KDE Application Version, managed by release script
0026 set (RELEASE_SERVICE_VERSION_MAJOR "22")
0027 set (RELEASE_SERVICE_VERSION_MINOR "11")
0028 set (RELEASE_SERVICE_VERSION_MICRO "70")
0029
0030 #############################################################################
0031 ### build options: ###
0032
0033 # OPTION(DEBUG "build debug code [default=off]" OFF)
0034 # OPTION(WITH_ALSA "enable playback/recording via ALSA [default=on]" ON)
0035 # OPTION(WITH_DOC "build online documentation [default=on]" ON)
0036 # OPTION(WITH_FLAC "enable support for FLAC files [default=on]" ON)
0037 # OPTION(WITH_MP3 "enable support for mp3 files [default=off]" OFF)
0038 # OPTION(WITH_OGG_OPUS "enable support for ogg/opus files [default=on]" ON)
0039 # OPTION(WITH_OGG_VORBIS "enable support for ogg/vorbis files [default=on]" ON)
0040 # OPTION(WITH_OSS "enable playback/recording via OSS [default=on]" ON)
0041 # OPTION(WITH_OPTIMIZED_MEMCPY "enable optimized memcpy [default=on]" ON)
0042 # OPTION(WITH_PULSEAUDIO "enable playback/recording via PulseAudio [default=on]" ON)
0043 # OPTION(WITH_QT_AUDIO "enable playback via Qt Multimedia [default=on]" ON)
0044
0045 #############################################################################
0046 ### toplevel build targets: ###
0047
0048 # all - default target, build all files
0049 # clean - clean up the current build directory
0050 # deb - create a debian package
0051 # doc - generate docbook files for online help
0052 # distfiles - generate subdirectory with all files for distribution
0053 # html_doc - generate HTML help (for the web)
0054 # install - install the package, with support for DESTDIR
0055 # msgstats - show the progress of translations
0056 # rpm - create a RPM package + a src.rpm file
0057 # src_rpm - create the source RPM only
0058 # tarball - create a tar.bz2 archive with the sources + specfile
0059 # uninstall - uninstall the package, with support for DESTDIR
0060 # update-translations - update translation files from KDE SVN
0061 # version-labels - update all version numbers and build dates
0062 # tarball - create a tar.gz file with the sources
0063
0064 #############################################################################
0065 ### required versions ###
0066
0067 CMAKE_MINIMUM_REQUIRED(VERSION 3.16.0 FATAL_ERROR)
0068
0069 SET(QT_MIN_VERSION "5.15.0")
0070 SET(KF5_MIN_VERSION "5.90.0")
0071 SET(KDE_COMPILERSETTINGS_LEVEL "5.82")
0072
0073 #############################################################################
0074 ### Kwave version number ###
0075
0076 SET(KWAVE_VERSION_MAJOR ${RELEASE_SERVICE_VERSION_MAJOR})
0077 SET(KWAVE_VERSION_MINOR ${RELEASE_SERVICE_VERSION_MINOR})
0078 SET(KWAVE_VERSION_MICRO ${RELEASE_SERVICE_VERSION_MICRO})
0079 SET(KWAVE_VERSION "${KWAVE_VERSION_MAJOR}.${KWAVE_VERSION_MINOR}.${KWAVE_VERSION_MICRO}")
0080 MESSAGE(STATUS "Building Kwave version ${KWAVE_VERSION}")
0081
0082 #############################################################################
0083 ### project name and version ###
0084
0085 PROJECT(kwave VERSION ${KWAVE_VERSION})
0086
0087 #############################################################################
0088 ### show the compiler name and version ###
0089
0090 EXECUTE_PROCESS(
0091 COMMAND ${CMAKE_C_COMPILER} -dumpversion
0092 OUTPUT_VARIABLE COMPILER_VERSION
0093 OUTPUT_STRIP_TRAILING_WHITESPACE
0094 )
0095 GET_FILENAME_COMPONENT(COMPILER_SHORT "${CMAKE_C_COMPILER}" NAME_WE CACHE)
0096 MESSAGE(STATUS "Building with ${COMPILER_SHORT} version ${COMPILER_VERSION}")
0097
0098 #############################################################################
0099 ### check for the CPU we build for ###
0100
0101 EXECUTE_PROCESS(
0102 COMMAND ${CMAKE_C_COMPILER} -dumpmachine
0103 OUTPUT_VARIABLE MACHINE
0104 OUTPUT_STRIP_TRAILING_WHITESPACE
0105 )
0106 MESSAGE(STATUS "Building for target ${MACHINE}")
0107
0108 OPTION(WITH_OPTIMIZED_MEMCPY "enable optimized memcpy [default=on]" ON)
0109 IF (WITH_OPTIMIZED_MEMCPY)
0110
0111 STRING(REGEX MATCH "(i.86-*)|(athlon-*)|(pentium-*)" _mach_x86 ${MACHINE})
0112 IF (_mach_x86)
0113 MESSAGE(STATUS "Found target optimized memcpy() for X86 (from xine)")
0114 SET(ARCH_X86 1)
0115 ENDIF (_mach_x86)
0116
0117 STRING(REGEX MATCH "(x86_64-*)|(X86_64-*)|(AMD64-*)|(amd64-*)" _mach_x86_64 ${MACHINE})
0118 IF (_mach_x86_64)
0119 MESSAGE(STATUS "Found target optimized memcpy() for X86_64 (from xine)")
0120 SET(ARCH_X86_64 1)
0121 ENDIF (_mach_x86_64)
0122
0123 STRING(REGEX MATCH "(ppc-*)|(powerpc-*)" _mach_ppc ${MACHINE})
0124 IF (_mach_ppc)
0125 MESSAGE(STATUS "Found target optimized memcpy() for PPC (from xine)")
0126 SET(ARCH_PPC 1)
0127 ENDIF (_mach_ppc)
0128
0129 IF (NOT ARCH_X86 AND NOT ARCH_X86_64 AND NOT ARCH_PPC)
0130 MESSAGE(STATUS "No platform specific memcpy available")
0131 ENDIF (NOT ARCH_X86 AND NOT ARCH_X86_64 AND NOT ARCH_PPC)
0132
0133 ELSE (WITH_OPTIMIZED_MEMCPY)
0134 MESSAGE(STATUS "Platform specific memcpy is disabled")
0135 ENDIF (WITH_OPTIMIZED_MEMCPY)
0136
0137 #############################################################################
0138 ### path to additional cmake modules and includes ###
0139
0140 SET(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
0141
0142 #############################################################################
0143 ### cmake includes ###
0144
0145 INCLUDE(CheckIncludeFiles)
0146 INCLUDE(CheckIncludeFilesCXX)
0147 INCLUDE(CheckCCompilerFlag)
0148 INCLUDE(CheckCXXCompilerFlag)
0149 INCLUDE(CheckTypeSize)
0150 INCLUDE(CheckFunctionExists)
0151 INCLUDE(FindRequiredProgram)
0152
0153 #############################################################################
0154 ### toplevel compiler flags ###
0155
0156 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
0157 ADD_DEFINITIONS(-DQT_NO_CAST_TO_ASCII)
0158 ADD_DEFINITIONS(-DQT_NO_CAST_FROM_ASCII)
0159 ADD_DEFINITIONS(-DQT_USE_FAST_OPERATOR_PLUS)
0160 ADD_DEFINITIONS(-DQT_NO_URL_CAST_FROM_STRING)
0161 ADD_DEFINITIONS(-DQT_DEPRECATED_WARNINGS)
0162 ADD_DEFINITIONS(-DKXMLGUI_NO_DEPRECATED)
0163
0164 CHECK_C_COMPILER_FLAG(" ${CMAKE_SHARED_LIBRARY_C_FLAGS}" C_HAVE_PIC)
0165 CHECK_CXX_COMPILER_FLAG(" ${CMAKE_SHARED_LIBRARY_CXX_FLAGS}" CXX_HAVE_PIC)
0166 IF (CXX_HAVE_PIC AND C_HAVE_PIC)
0167 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${CMAKE_SHARED_LIBRARY_C_FLAGS}")
0168 SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${CMAKE_SHARED_LIBRARY_CXX_FLAGS}")
0169 ELSE (CXX_HAVE_PIC AND C_HAVE_PIC)
0170 MESSAGE(FATAL_ERROR "shared library support is missing")
0171 ENDIF (CXX_HAVE_PIC AND C_HAVE_PIC)
0172
0173 CHECK_CXX_COMPILER_FLAG("--std=c++11" CXX_HAVE_CXX11)
0174 IF (CXX_HAVE_CXX11)
0175 SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++11")
0176 ENDIF (CXX_HAVE_CXX11)
0177
0178 #############################################################################
0179
0180 LINK_DIRECTORIES(${CMAKE_CURRENT_BINARY_DIR}/libgui)
0181 LINK_DIRECTORIES(${CMAKE_CURRENT_BINARY_DIR}/libkwave)
0182
0183 #############################################################################
0184 ### Qt 5 support ###
0185
0186 SET(CMAKE_AUTOMOC TRUE)
0187 SET(CMAKE_AUTOMOC_RELAXED_MODE FALSE)
0188
0189 FIND_PACKAGE(Qt5 ${QT_MIN_VERSION} CONFIG REQUIRED COMPONENTS
0190 Concurrent
0191 Core
0192 Widgets
0193 )
0194
0195 # NOTE: this must be *after* FIND_PACKAGE(Qt5 Core ...), otherwise it would
0196 # be overwritten and produce many annoying build warnings
0197 LIST(APPEND CMAKE_AUTOMOC_MACRO_NAMES "KWAVE_PLUGIN")
0198
0199 # Qt Multimedia support
0200 OPTION(WITH_QT_AUDIO "enable playback via Qt Multimedia [default=on]" ON)
0201 IF (WITH_QT_AUDIO)
0202 SET(HAVE_QT_AUDIO_SUPPORT on)
0203 FIND_PACKAGE(Qt5 ${QT_MIN_VERSION} CONFIG REQUIRED COMPONENTS
0204 Multimedia
0205 )
0206 ENDIF (WITH_QT_AUDIO)
0207
0208
0209 #############################################################################
0210 ### KF5 support ###
0211
0212 FIND_PACKAGE(ECM ${KF5_MIN_VERSION} REQUIRED NO_MODULE)
0213 SET(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH} )
0214
0215 INCLUDE(KDEInstallDirs)
0216 INCLUDE(KDECompilerSettings NO_POLICY_SCOPE)
0217 INCLUDE(KDECMakeSettings)
0218 INCLUDE(GenerateExportHeader)
0219 INCLUDE(FeatureSummary)
0220
0221 FIND_PACKAGE(KF5 ${KF5_MIN_VERSION} REQUIRED COMPONENTS
0222 Archive
0223 Completion
0224 Config
0225 ConfigWidgets
0226 CoreAddons
0227 Crash
0228 DBusAddons
0229 DocTools
0230 I18n
0231 IconThemes
0232 KIO
0233 TextWidgets
0234 XmlGui
0235 WidgetsAddons
0236 )
0237
0238 IF (NOT WITH_DOC)
0239 SET_PACKAGE_PROPERTIES(KF5DocTools
0240 PROPERTIES DESCRIPTION "Tools to generate documentation"
0241 TYPE OPTIONAL
0242 )
0243 ENDIF (NOT WITH_DOC)
0244
0245 FEATURE_SUMMARY(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)
0246
0247 INCLUDE_DIRECTORIES(
0248 ${INTERFACE_INCLUDE_DIRECTORIES}
0249 ${CMAKE_CURRENT_SOURCE_DIR}
0250 ${CMAKE_CURRENT_BINARY_DIR}
0251 )
0252
0253 #############################################################################
0254 ### checks for needed header files ###
0255
0256 CHECK_INCLUDE_FILES(signal.h HAVE_SIGNAL_H)
0257
0258 SET(_inc_c errno.h math.h signal.h stdlib.h string.h unistd.h pthread.h)
0259 CHECK_INCLUDE_FILES("${_inc_c}" HAVE_REQUIRED_STD_C_HEADERS)
0260 IF (NOT HAVE_REQUIRED_STD_C_HEADERS)
0261 MESSAGE(FATAL_ERROR "
0262 unable to find one or more of the following C header files:
0263 ${_inc_c}")
0264 ENDIF (NOT HAVE_REQUIRED_STD_C_HEADERS)
0265
0266 SET(_inc_cpp algorithm complex limits new)
0267 CHECK_INCLUDE_FILES_CXX("${_inc_cpp}")
0268
0269 #############################################################################
0270 ### libaudiofile and libsamplerate support ###
0271
0272 INCLUDE(KwaveLibaudiofileSupport)
0273 INCLUDE(KwaveLibsamplerateSupport)
0274
0275 #############################################################################
0276 ### optionally: OSS, ALSA and PulseAudio support ###
0277 ### for playback/recording ###
0278
0279 INCLUDE(KwaveOSSSupport)
0280 INCLUDE(KwaveALSASupport)
0281 INCLUDE(KwavePulseAudioSupport)
0282
0283 #############################################################################
0284 ### cmake includes ###
0285
0286 INCLUDE(KwaveL10N)
0287
0288 #############################################################################
0289 ### flags for debugging ###
0290
0291 OPTION(DEBUG "enable the debug plugin in the menu [default=off]" OFF)
0292 IF (DEBUG)
0293 SET(HAVE_DEBUG_PLUGIN ON CACHE BOOL "enable debug plugin in the menu")
0294 ENDIF (DEBUG)
0295
0296 #############################################################################
0297 ### subdirs ###
0298
0299 ADD_SUBDIRECTORY( libgui )
0300 ADD_SUBDIRECTORY( libkwave )
0301 ADD_SUBDIRECTORY( kwave )
0302 ADD_SUBDIRECTORY( plugins )
0303
0304 OPTION(WITH_DOC "build online documentation [default=on]" ON)
0305 IF (WITH_DOC)
0306 ADD_SUBDIRECTORY( doc )
0307 ENDIF (WITH_DOC)
0308
0309 #############################################################################
0310 ### RPM support ###
0311
0312 # directory that receives the files of the "distfiles" target
0313 SET(DISTFILES_DIR ${CMAKE_BINARY_DIR}/v${KWAVE_VERSION})
0314 FILE(MAKE_DIRECTORY ${DISTFILES_DIR})
0315
0316 INCLUDE(KwaveRPMSupport)
0317
0318 #############################################################################
0319 ### DEB support ###
0320
0321 INCLUDE(KwaveDEBSupport)
0322
0323 #############################################################################
0324
0325 CONFIGURE_FILE(
0326 ${CMAKE_CURRENT_SOURCE_DIR}/config.h.cmake
0327 ${CMAKE_CURRENT_BINARY_DIR}/config.h
0328 )
0329
0330 #############################################################################
0331 ### KDE .desktop file / mime types ###
0332
0333 SET(KWAVE_DESKTOP_MIME_TYPES "${KWAVE_DESKTOP_MIME_TYPES}audio/wav;")
0334 SET(KWAVE_DESKTOP_MIME_TYPES "${KWAVE_DESKTOP_MIME_TYPES}audio/x-wav;")
0335 SET(KWAVE_DESKTOP_MIME_TYPES "${KWAVE_DESKTOP_MIME_TYPES}audio/basic;")
0336 SET(KWAVE_DESKTOP_MIME_TYPES "${KWAVE_DESKTOP_MIME_TYPES}audio/x-8svx;")
0337 SET(KWAVE_DESKTOP_MIME_TYPES "${KWAVE_DESKTOP_MIME_TYPES}audio/x-aifc;")
0338 SET(KWAVE_DESKTOP_MIME_TYPES "${KWAVE_DESKTOP_MIME_TYPES}audio/x-aiff;")
0339 SET(KWAVE_DESKTOP_MIME_TYPES "${KWAVE_DESKTOP_MIME_TYPES}audio/x-avr;")
0340 SET(KWAVE_DESKTOP_MIME_TYPES "${KWAVE_DESKTOP_MIME_TYPES}audio/x-caf;")
0341 SET(KWAVE_DESKTOP_MIME_TYPES "${KWAVE_DESKTOP_MIME_TYPES}audio/x-ircam;")
0342 SET(KWAVE_DESKTOP_MIME_TYPES "${KWAVE_DESKTOP_MIME_TYPES}audio/x-nist;")
0343 SET(KWAVE_DESKTOP_MIME_TYPES "${KWAVE_DESKTOP_MIME_TYPES}audio/x-smp;")
0344 SET(KWAVE_DESKTOP_MIME_TYPES "${KWAVE_DESKTOP_MIME_TYPES}audio/x-voc;")
0345 IF (WITH_MP3)
0346 SET(KWAVE_DESKTOP_MIME_TYPES "${KWAVE_DESKTOP_MIME_TYPES}audio/mpeg;")
0347 SET(KWAVE_DESKTOP_MIME_TYPES "${KWAVE_DESKTOP_MIME_TYPES}audio/x-mp1;")
0348 SET(KWAVE_DESKTOP_MIME_TYPES "${KWAVE_DESKTOP_MIME_TYPES}audio/x-mp2;")
0349 SET(KWAVE_DESKTOP_MIME_TYPES "${KWAVE_DESKTOP_MIME_TYPES}audio/x-mp3;")
0350 ENDIF (WITH_MP3)
0351 IF (WITH_FLAC)
0352 SET(KWAVE_DESKTOP_MIME_TYPES "${KWAVE_DESKTOP_MIME_TYPES}application/x-flac;")
0353 SET(KWAVE_DESKTOP_MIME_TYPES "${KWAVE_DESKTOP_MIME_TYPES}audio/x-flac;")
0354 ENDIF (WITH_FLAC)
0355 IF (WITH_OGG_OPUS OR WITH_OGG_VORBIS)
0356 SET(KWAVE_DESKTOP_MIME_TYPES "${KWAVE_DESKTOP_MIME_TYPES}audio/ogg;")
0357 SET(KWAVE_DESKTOP_MIME_TYPES "${KWAVE_DESKTOP_MIME_TYPES}application/ogg;")
0358 ENDIF (WITH_OGG_OPUS OR WITH_OGG_VORBIS)
0359 IF (WITH_OGG_VORBIS)
0360 SET(KWAVE_DESKTOP_MIME_TYPES "${KWAVE_DESKTOP_MIME_TYPES}audio/x-ogg;")
0361 SET(KWAVE_DESKTOP_MIME_TYPES "${KWAVE_DESKTOP_MIME_TYPES}application/x-ogg;")
0362 SET(KWAVE_DESKTOP_MIME_TYPES "${KWAVE_DESKTOP_MIME_TYPES}audio/x-vorbis+ogg;")
0363 ENDIF (WITH_OGG_VORBIS)
0364 IF (WITH_OGG_OPUS)
0365 SET(KWAVE_DESKTOP_MIME_TYPES "${KWAVE_DESKTOP_MIME_TYPES}audio/opus;")
0366 ENDIF (WITH_OGG_OPUS)
0367
0368 CONFIGURE_FILE(
0369 ${CMAKE_CURRENT_SOURCE_DIR}/kwave/org.kde.kwave.desktop.in
0370 ${CMAKE_CURRENT_BINARY_DIR}/kwave/org.kde.kwave.desktop
0371 )
0372
0373 #############################################################################
0374 ### Gentoo support ###
0375
0376 INCLUDE(KwaveEbuild)
0377
0378 #############################################################################
0379 ### collection of all files used for distribution ###
0380
0381 FIND_PROGRAM(SED_EXECUTABLE NAMES sed)
0382 SET(_distfiles_md5sum ${DISTFILES_DIR}/MD5SUMS-${KWAVE_VERSION})
0383
0384 ADD_CUSTOM_COMMAND(OUTPUT ${_distfiles_md5sum}
0385 COMMAND md5sum ${KWAVE_DISTFILES} |
0386 ${SED_EXECUTABLE} s+${DISTFILES_DIR}/++g > ${_distfiles_md5sum}
0387 DEPENDS ${KWAVE_DISTFILES}
0388 )
0389
0390 ADD_CUSTOM_TARGET(distfiles
0391 DEPENDS ${KWAVE_DISTFILES} ${_distfiles_md5sum}
0392 )
0393
0394 #############################################################################
0395 ### uninstall support ###
0396
0397 FIND_REQUIRED_PROGRAM(RMDIR_EXECUTABLE rmdir)
0398
0399 CONFIGURE_FILE(
0400 ${CMAKE_CURRENT_SOURCE_DIR}/cmake/uninstall.cmake.in
0401 ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake
0402 @ONLY
0403 )
0404
0405 #############################################################################
0406 ### "make apidoc" ###
0407
0408 FIND_PROGRAM(DOXYGEN_EXECUTABLE doxygen)
0409 FIND_REQUIRED_PROGRAM(CAT_EXECUTABLE cat)
0410
0411 IF (DOXYGEN_EXECUTABLE)
0412 SET(DOXYFILE ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile)
0413 SET(DOXYGEN_OUTPUT_DIR ${CMAKE_BINARY_DIR}/doc/api)
0414 SET(DOXYGEN_LOGFILE ${CMAKE_CURRENT_BINARY_DIR}/doxygen.log)
0415
0416 MESSAGE(STATUS "Found doxygen: ${DOXYGEN_EXECUTABLE}")
0417
0418 CONFIGURE_FILE(
0419 ${CMAKE_CURRENT_SOURCE_DIR}/doxy.cfg.in
0420 ${DOXYFILE}
0421 @ONLY
0422 )
0423
0424 ADD_CUSTOM_TARGET(apidoc
0425 DEPENDS html_doc_devel
0426 COMMAND "${CMAKE_COMMAND}" -E remove_directory "${CMAKE_BINARY_DIR}/doc/api"
0427 COMMAND "${CMAKE_COMMAND}" -E make_directory "${CMAKE_BINARY_DIR}/doc/api"
0428 COMMAND "${DOXYGEN_EXECUTABLE}" "${DOXYFILE}"
0429 COMMAND "${CAT_EXECUTABLE}" "${DOXYGEN_LOGFILE}"
0430 DEPENDS ${DOXYFILE}
0431 )
0432
0433 SET(KWAVE_ADDITIONAL_CLEAN_FILES
0434 ${KWAVE_ADDITIONAL_CLEAN_FILES}
0435 ${DOXYGEN_OUTPUT_DIR}
0436 ${DOXYGEN_LOGFILE}
0437 )
0438
0439 ENDIF (DOXYGEN_EXECUTABLE)
0440
0441 #############################################################################
0442 ### additional files for "make clean" ###
0443
0444 IF (KWAVE_ADDITIONAL_CLEAN_FILES)
0445 SET_DIRECTORY_PROPERTIES(PROPERTIES
0446 ADDITIONAL_MAKE_CLEAN_FILES
0447 "${KWAVE_ADDITIONAL_CLEAN_FILES}"
0448 )
0449 ENDIF (KWAVE_ADDITIONAL_CLEAN_FILES)
0450
0451 #############################################################################
0452 ### "make wrapper" ###
0453 ### -> creates a wrapper script named "kw" ###
0454
0455 SET(WRAPPER_SCRIPT "${CMAKE_CURRENT_BINARY_DIR}/kw")
0456
0457 CONFIGURE_FILE(
0458 "${CMAKE_CURRENT_SOURCE_DIR}/bin/kwave.wrapper.in"
0459 "${WRAPPER_SCRIPT}"
0460 @ONLY
0461 )
0462
0463 ADD_CUSTOM_TARGET(wrapper
0464 COMMAND chmod +rx "${WRAPPER_SCRIPT}"
0465 DEPENDS "${WRAPPER_SCRIPT}"
0466 )
0467
0468 #############################################################################
0469 ### install translations ###
0470
0471 ki18n_install(po)
0472 kdoctools_install(po)
0473
0474 #############################################################################
0475
0476 MESSAGE(STATUS "Using CFLAGS=${CMAKE_C_FLAGS}")
0477 MESSAGE(STATUS "Using CXXFLAGS=${CMAKE_CXX_FLAGS}")
0478 MESSAGE(STATUS "Using LDFLAGS=${LDFLAGS}")
0479
0480 #############################################################################
0481 #############################################################################