src/lib/CMakeLists.txt

0001 add_library(kmplayercommon SHARED)
0002
0003 target_compile_definitions(kmplayercommon PRIVATE -DTRANSLATION_DOMAIN=\"kmplayer\")
0004
0005 target_sources(kmplayercommon PRIVATE
0006     kmplayerview.cpp
0007     playmodel.cpp
0008     playlistview.cpp
0009     kmplayercontrolpanel.cpp
0010     kmplayerconfig.cpp
0011     pref.cpp
0012     kmplayerprocess.cpp
0013     kmplayerpartbase.cpp
0014     kmplayerplaylist.cpp
0015     kmplayer_asx.cpp
0016     kmplayer_smil.cpp
0017     kmplayer_rp.cpp
0018     kmplayer_rss.cpp
0019     kmplayer_atom.cpp
0020     kmplayer_opml.cpp
0021     kmplayer_xspf.cpp
0022     expression.cpp
0023     mediaobject.cpp
0024     triestring.cpp
0025     surface.cpp
0026     viewarea.cpp
0027 )
0028
0029 ecm_qt_declare_logging_category(kmplayercommon
0030     HEADER kmplayercommon_log.h
0031     IDENTIFIER LOG_KMPLAYER_COMMON
0032     CATEGORY_NAME kmplayer.common
0033     DESCRIPTION "KMPlayer Common lib"
0034     EXPORT KMPLAYER
0035 )
0036
0037 set(libkmplayercommon_dbus_SRCS)
0038 qt5_add_dbus_adaptor(libkmplayercommon_dbus_SRCS
0039     org.kde.kmplayer.master.xml
0040     kmplayerprocess.h KMPlayer::MasterProcessInfo
0041 )
0042 qt5_add_dbus_adaptor(libkmplayercommon_dbus_SRCS
0043     org.kde.kmplayer.streammaster.xml
0044     kmplayerprocess.h KMPlayer::MasterProcess
0045 )
0046 qt5_add_dbus_adaptor(libkmplayercommon_dbus_SRCS
0047     org.kde.kmplayer.part.xml
0048     kmplayerpartbase.h KMPlayer::PartBase
0049 )
0050
0051 if (KMPLAYER_WITH_NPP)
0052     qt5_add_dbus_adaptor(libkmplayercommon_dbus_SRCS
0053         org.kde.kmplayer.callback.xml
0054         kmplayerprocess.h KMPlayer::NpPlayer
0055     )
0056     qt5_add_dbus_adaptor(libkmplayercommon_dbus_SRCS
0057         org.kde.kmplayer.stream.xml
0058         kmplayerprocess.h KMPlayer::NpStream
0059     )
0060 endif ()
0061
0062 set_source_files_properties(org.freedesktop.PowerManagement.Inhibit.xml
0063     PROPERTIES NO_NAMESPACE TRUE
0064 )
0065 qt5_add_dbus_interfaces(libkmplayercommon_dbus_SRCS org.freedesktop.PowerManagement.Inhibit.xml)
0066
0067 target_sources(kmplayercommon PRIVATE
0068     ${libkmplayercommon_dbus_SRCS}
0069 )
0070
0071 generate_export_header(kmplayercommon)
0072
0073 target_include_directories(kmplayercommon
0074     PUBLIC
0075         "$<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}/..>" # config file
0076     PRIVATE
0077         ${CAIRO_INCLUDE_DIRS}
0078         ${EXPAT_INCLUDE_DIRS}
0079 )
0080 target_link_libraries(kmplayercommon
0081     PUBLIC
0082         KF5::MediaPlayer
0083     PRIVATE
0084         KF5::IconThemes
0085         KF5::Bookmarks
0086         Qt5::Svg
0087         Qt5::X11Extras
0088         ${CAIRO_LIBRARIES}
0089         ${XCB_LIBRARIES}
0090         ${EXPAT_LIBRARIES}
0091 )
0092
0093 install(TARGETS kmplayercommon ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0094
0095 install(FILES bookmarks.xml DESTINATION ${KDE_INSTALL_DATADIR}/kmplayer)