multimedia/kmplayer/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 project(kmplayer)
0004
0005 SET(KMPLAYER_MAJOR_VERSION "0")
0006 SET(KMPLAYER_MINOR_VERSION "12")
0007 SET(KMPLAYER_PATCH_VERSION "0b")
0008
0009 SET(KMPLAYER_VERSION_STRING
0010     "${KMPLAYER_MAJOR_VERSION}.${KMPLAYER_MINOR_VERSION}.${KMPLAYER_PATCH_VERSION}")
0011
0012 set(QT_MIN_VERSION "5.15.0")
0013 set(KF5_MIN_VERSION "5.80.0")
0014
0015 find_package(ECM ${KF5_MIN_VERSION} REQUIRED NO_MODULE)
0016 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH})
0017
0018 include(KDEInstallDirs)
0019 include(KDECMakeSettings)
0020 include(KDECompilerSettings NO_POLICY_SCOPE)
0021 include(ECMInstallIcons)
0022 include(ECMSetupVersion)
0023 include(ECMQtDeclareLoggingCategory)
0024 include(GenerateExportHeader)
0025 include(FeatureSummary)
0026 include(FindXCB)
0027
0028 ecm_setup_version(${KMPLAYER_VERSION_STRING} VARIABLE_PREFIX KMPLAYERPRIVATE
0029     SOVERSION ${KMPLAYER_MAJOR_VERSION}
0030 )
0031 find_package(Qt5 ${QT_MIN_VERSION} REQUIRED COMPONENTS Core DBus Widgets Svg X11Extras)
0032 find_package(KF5 ${KF5_MIN_VERSION} REQUIRED COMPONENTS
0033     Config
0034     CoreAddons
0035     DocTools
0036     IconThemes
0037     Init
0038     I18n
0039     KIO
0040     MediaPlayer
0041     Parts
0042     WidgetsAddons
0043 )
0044 find_package(X11 REQUIRED)
0045 find_package(Phonon4Qt5 REQUIRED NO_MODULE)
0046
0047 add_definitions(
0048     -DQT_USE_QSTRINGBUILDER
0049     -DQT_NO_URL_CAST_FROM_STRING
0050     -DQT_NO_NARROWING_CONVERSIONS_IN_CONNECT
0051     -DQT_NO_KEYWORDS
0052     -DQT_NO_FOREACH
0053     -DQT_DISABLE_DEPRECATED_BEFORE=0x050000
0054     -DQT_DEPRECATED_WARNINGS_SINCE=0x060000
0055     -DKF_DISABLE_DEPRECATED_BEFORE_AND_AT=0x050000
0056     -DKF_DEPRECATED_WARNINGS_SINCE=0x060000
0057 )
0058
0059 if(NOT WIN32)
0060   OPTION(KMPLAYER_BUILT_WITH_CAIRO "Enable Cairo support" ON)
0061   OPTION(KMPLAYER_BUILT_WITH_NPP "Build NPP player" ON)
0062   OPTION(KMPLAYER_BUILT_WITH_EXPAT "Use expat XML parser" OFF)
0063   include(FindPkgConfig)
0064
0065   if (KMPLAYER_BUILT_WITH_CAIRO)
0066
0067     pkg_check_modules(CAIRO cairo)
0068
0069     if(CAIRO_FOUND)
0070         set(KMPLAYER_WITH_CAIRO 1)
0071     endif()
0072   endif (KMPLAYER_BUILT_WITH_CAIRO)
0073
0074   if (KMPLAYER_BUILT_WITH_NPP)
0075     pkg_check_modules(GLibDBus dbus-glib-1)
0076     pkg_check_modules(GModule gmodule-2.0)
0077
0078     if(GLibDBus_FOUND)
0079       set(KMPLAYER_WITH_GDBUS 1)
0080       pkg_check_modules(GTK gtk+-x11-2.0)
0081       pkg_check_modules(GThread gthread-2.0)
0082       if (GTK_FOUND)
0083           set(KMPLAYER_WITH_NPP 1)
0084       endif()
0085     endif()
0086   endif (KMPLAYER_BUILT_WITH_NPP)
0087
0088   if (KMPLAYER_BUILT_WITH_EXPAT)
0089       INCLUDE(FindEXPAT)
0090       if (EXPAT_FOUND)
0091           set(KMPLAYER_WITH_EXPAT 1)
0092       else (EXPAT_FOUND)
0093           MESSAGE(Expat found)
0094       endif (EXPAT_FOUND)
0095   endif (KMPLAYER_BUILT_WITH_EXPAT)
0096
0097 endif(NOT WIN32)
0098
0099 add_subdirectory(src)
0100 add_subdirectory(icons)
0101 add_subdirectory(doc)
0102 add_subdirectory(data)
0103
0104 ki18n_install(po)
0105 kdoctools_install(po)
0106
0107 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)