plugins/taglibmetadata/CMakeLists.txt

0001 if(WITH_TAGLIB OR TAGLIB_LIBRARIES)
0002   set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules)
0003   # For TagLib 2.0 prefer its exported configuration
0004   set(CMAKE_FIND_PACKAGE_PREFER_CONFIG TRUE)
0005
0006   find_package(TagLib REQUIRED)
0007   if(TagLib_DIR)
0008     # The exported TagLib configuration requests a transitive ZLIB::ZLIB
0009     # imported target.
0010     find_package("ZLIB")
0011     message(STATUS "Found TagLib ${TAGLIB_VERSION}: ${TagLib_DIR}")
0012   endif()
0013
0014   set(plugin_NAME TaglibMetadata)
0015
0016   string(TOLOWER ${plugin_NAME} plugin_TARGET)
0017
0018   add_library(${plugin_TARGET}
0019     taglibmetadataplugin.cpp
0020     taglibfile.cpp
0021   )
0022   if(TAGLIB_VERSION VERSION_LESS 2.0.0)
0023     target_sources(${plugin_TARGET} PRIVATE
0024       taglibext/aac/aacfiletyperesolver.cpp
0025       taglibext/mp2/mp2filetyperesolver.cpp
0026       taglibext/dsf/dsffiletyperesolver.cpp
0027       taglibext/dsf/dsffile.cpp
0028       taglibext/dsf/dsfproperties.cpp
0029       taglibext/dsf/dsfheader.cpp
0030       taglibext/dsdiff/dsdifffiletyperesolver.cpp
0031       taglibext/dsdiff/dsdifffile.cpp
0032       taglibext/dsdiff/dsdiffproperties.cpp
0033     )
0034   endif()
0035   if(NOT ${TAGLIB_VERSION} VERSION_GREATER 1.9.1)
0036     target_sources(${plugin_TARGET} PRIVATE
0037       taglibext/synchronizedlyricsframe.cpp
0038       taglibext/eventtimingcodesframe.cpp
0039     )
0040   endif()
0041   qt_wrap_cpp(plugin_GEN_MOC_SRCS
0042     taglibmetadataplugin.h
0043     TARGET ${plugin_TARGET}
0044   )
0045   target_sources(${plugin_TARGET} PRIVATE ${plugin_GEN_MOC_SRCS})
0046   target_include_directories(${plugin_TARGET} PRIVATE ${CMAKE_CURRENT_BINARY_DIR} taglibext)
0047   target_link_libraries(${plugin_TARGET} PRIVATE kid3-core TagLib::TagLib Kid3Plugin)
0048
0049   INSTALL_KID3_PLUGIN(${plugin_TARGET} ${plugin_NAME})
0050 endif()