src/plugins/CMakeLists.txt

0001 project(kid3_plugins)
0002 set(CMAKE_CXX_STANDARD 17)
0003
0004 # Install a library _target as a plugin with _name.
0005 macro(INSTALL_KID3_PLUGIN _target _name)
0006   if(BUILD_SHARED_LIBS)
0007     install(TARGETS ${_target}
0008       LIBRARY DESTINATION ${WITH_PLUGINSDIR}
0009       RUNTIME DESTINATION ${WITH_PLUGINSDIR})
0010     set_target_properties(
0011       ${_target} PROPERTIES
0012       RUNTIME_OUTPUT_DIRECTORY ${kid3_plugins_BINARY_DIR}
0013       LIBRARY_OUTPUT_DIRECTORY ${kid3_plugins_BINARY_DIR}
0014     )
0015   else()
0016     set_property(
0017       TARGET ${_target}
0018       APPEND PROPERTY COMPILE_DEFINITIONS QT_STATICPLUGIN
0019     )
0020     set(PLUGIN_LIBRARIES ${PLUGIN_LIBRARIES} ${_target} PARENT_SCOPE)
0021     set(PLUGIN_NAMES ${PLUGIN_NAMES} ${_name}Plugin PARENT_SCOPE)
0022   endif()
0023   if(LINUX_SELF_CONTAINED)
0024     # Just to keep CMake quiet, not needed at run time.
0025     set_target_properties(${_target} PROPERTIES INSTALL_RPATH "\$ORIGIN/..")
0026   endif()
0027 endmacro()
0028
0029 add_library(Kid3Plugin INTERFACE)
0030 target_compile_definitions(Kid3Plugin INTERFACE KID3_BUILD_PLUGIN_LIB)
0031
0032 add_subdirectory(amazonimport)
0033 add_subdirectory(discogsimport)
0034 add_subdirectory(freedbimport)
0035 add_subdirectory(musicbrainzimport)
0036 add_subdirectory(acoustidimport)
0037 add_subdirectory(id3libmetadata)
0038 add_subdirectory(taglibmetadata)
0039 add_subdirectory(oggflacmetadata)
0040 add_subdirectory(mp4v2metadata)
0041 if(WITH_QML)
0042   add_subdirectory(qmlcommand)
0043   add_subdirectory(kid3qml)
0044 endif()
0045
0046 set(PLUGIN_LIBRARIES ${PLUGIN_LIBRARIES} PARENT_SCOPE)
0047 set(CFG_IMPORT_PLUGIN_CALLS)
0048 foreach(_pluginName ${PLUGIN_NAMES})
0049   set(CFG_IMPORT_PLUGIN_CALLS "${CFG_IMPORT_PLUGIN_CALLS}Q_IMPORT_PLUGIN(${_pluginName})\n")
0050 endforeach()
0051 configure_file(importplugins.h.cmake ${kid3_BINARY_DIR}/importplugins.h)