src/app/CMakeLists.txt

0001 if(BUILD_CLI_APP)
0002   add_subdirectory(cli)
0003 endif()
0004
0005 if(BUILD_QT_APP)
0006   add_subdirectory(qt)
0007 endif()
0008
0009 if(BUILD_QML_APP)
0010   add_subdirectory(qml)
0011 endif()
0012
0013 if(BUILD_KDE_APP)
0014   set(_cmakeInstallRpath "${CMAKE_INSTALL_RPATH}")
0015   cmake_minimum_required(VERSION 3.16)
0016   find_package(ECM REQUIRED NO_MODULE)
0017   set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0018   include(ECMInstallIcons)
0019
0020   include(KDEInstallDirs)
0021   include(KDECompilerSettings)
0022   include(KDECMakeSettings)
0023   include(FeatureSummary)
0024
0025   find_package(KF${QT_MAJOR_VERSION} REQUIRED COMPONENTS Config ConfigWidgets CoreAddons WidgetsAddons XmlGui KIO)
0026
0027   if(BUILD_SHARED_LIBS)
0028     # KDECMakeSettings.cmake will overwrite our RPATH if LIB_INSTALL_DIR is
0029     # not an implicit link directory. In practice this means that most values
0030     # for CMAKE_INSTALL_PREFIX other than /usr will cause the RPATH to be
0031     # overwritten and the kid3 executable will not find its libraries.
0032     # This happens also for the default value /usr/local for
0033     # CMAKE_INSTALL_PREFIX. The RPATH is set again here to reverse this.
0034     set(_prefixLibdir "${CMAKE_INSTALL_PREFIX}/${WITH_LIBDIR}")
0035     list(FIND CMAKE_PLATFORM_IMPLICIT_LINK_DIRECTORIES "${_prefixLibdir}" _isSystemDir)
0036     if("${_isSystemDir}" STREQUAL "-1")
0037       list(APPEND _cmakeInstallRpath ${CMAKE_INSTALL_RPATH})
0038       list(REMOVE_DUPLICATES _cmakeInstallRpath)
0039       set(CMAKE_INSTALL_RPATH "${_cmakeInstallRpath}")
0040     endif()
0041   endif()
0042
0043   kde_enable_exceptions()
0044   add_subdirectory(kde)
0045   ecm_install_icons(ICONS
0046     sc-apps-kid3.svgz
0047     128-apps-kid3.png
0048     16-apps-kid3.png
0049     32-apps-kid3.png
0050     48-apps-kid3.png
0051     64-apps-kid3.png
0052     DESTINATION ${KDE_INSTALL_ICONDIR}
0053     THEME hicolor
0054   )
0055 endif()