cmake/modules/FindMLT.cmake

0001 # Find the MLT includes and libraries
0002 #
0003 # SPDX-FileCopyrightText: 2007-2012 Jean-Baptiste Mardell <jb@kdenlive.org>
0004 # SPDX-FileCopyrightText: 2012 Alberto Villa <avilla@FreeBSD.org>
0005 #
0006 # SPDX-License-Identifier: BSD-3-Clause
0007 #
0008 # Redistribution and use is allowed according to the terms of the BSD license.
0009
0010 find_package(PkgConfig QUIET)
0011 pkg_check_modules(PC_MLT mlt++-7)
0012
0013 # Workaround cmake 3.17 issue (dropped .dll extension for library search)
0014 if(WIN32)
0015     list(INSERT CMAKE_FIND_LIBRARY_SUFFIXES 0 .dll)
0016 endif()
0017
0018 find_path(MLT_INCLUDE_DIR
0019   NAMES framework/mlt.h
0020   HINTS
0021     ${PC_MLT_INCLUDEDIR}
0022     ${PC_MLT_PREFIX}/include
0023   PATHS
0024     /usr/local/include
0025     /usr/include
0026   PATH_SUFFIXES mlt-7
0027 )
0028
0029 find_library(MLT_LIBRARIES
0030   NAMES mlt-7
0031   HINTS
0032     ${PC_MLT_LIBDIR}
0033     ${PC_MLT_PREFIX}/lib
0034   PATHS
0035     /usr/local/lib
0036     /usr/lib
0037 )
0038
0039 find_path(MLTPP_INCLUDE_DIR
0040   NAMES mlt++/Mlt.h
0041   HINTS
0042     ${PC_MLT_INCLUDEDIR}
0043     ${PC_MLT_PREFIX}/include
0044   PATHS
0045     /usr/local/include
0046     /usr/include
0047   PATH_SUFFIXES mlt-7
0048 )
0049
0050 find_library(MLTPP_LIBRARIES
0051   NAMES mlt++-7
0052   HINTS
0053     ${PC_MLT_LIBDIR}
0054     ${PC_MLT_PREFIX}/lib
0055   PATHS
0056     /usr/local/lib
0057     /usr/lib
0058 )
0059
0060 get_filename_component(MLT_ROOT_DIR ${MLTPP_INCLUDE_DIR} PATH)
0061
0062 if(PC_MLT_VERSION)
0063   set(MLT_VERSION_STRING ${PC_MLT_VERSION})
0064 endif()
0065
0066 include(FindPackageHandleStandardArgs)
0067 find_package_handle_standard_args(MLT
0068   REQUIRED_VARS MLT_LIBRARIES MLTPP_LIBRARIES MLT_INCLUDE_DIR MLTPP_INCLUDE_DIR
0069   VERSION_VAR MLT_VERSION_STRING
0070 )
0071
0072 mark_as_advanced(MLT_INCLUDE_DIR MLT_LIBRARIES MLTPP_INCLUDE_DIR MLTPP_LIBRARIES)