multimedia/kasts/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2020 Tobias Fella <tobias.fella@kde.org>
0002 # SPDX-FileCopyrightText: 2020 Nicolas Fella <nicolas.fella@gmx.de>
0003 # SPDX-FileCopyrightText: 2023 Bart De Vries <bart@mogwai.be>
0004 # SPDX-License-Identifier: BSD-2-Clause
0005
0006 cmake_minimum_required(VERSION 3.16)
0007
0008 # KDE Applications version, managed by release script.
0009 set(RELEASE_SERVICE_VERSION_MAJOR "23")
0010 set(RELEASE_SERVICE_VERSION_MINOR "08")
0011 set(RELEASE_SERVICE_VERSION_MICRO "5")
0012 set(RELEASE_SERVICE_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}.${RELEASE_SERVICE_VERSION_MICRO}")
0013
0014 project(kasts VERSION ${RELEASE_SERVICE_VERSION})
0015
0016 # be c++17 compliant
0017 set(CMAKE_CXX_STANDARD 17)
0018 set(CMAKE_CXX_STANDARD_REQUIRED ON)
0019 set(CMAKE_CXX_EXTENSIONS OFF)
0020
0021 set(KF_MIN_VERSION "5.105.0")
0022 set(QT_MIN_VERSION "5.15.2")
0023 if (ANDROID)
0024     set(QT_MIN_VERSION 5.15.10) # due to 5.15.10 changing NDK versioning
0025 endif()
0026
0027 find_package(ECM ${KF_MIN_VERSION} REQUIRED NO_MODULE)
0028
0029 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0030
0031 include(FeatureSummary)
0032 include(ECMSetupVersion)
0033 include(ECMQtDeclareLoggingCategory)
0034 include(ECMGenerateExportHeader)
0035 include(KDEInstallDirs)
0036 include(KDEGitCommitHooks)
0037 include(ECMFindQmlModule)
0038 include(KDECMakeSettings)
0039 include(KDECompilerSettings NO_POLICY_SCOPE)
0040 include(ECMAddAppIcon)
0041 include(ECMDeprecationSettings)
0042 if(NOT ANDROID)
0043     include(KDEClangFormat)
0044 endif()
0045
0046 ecm_setup_version(${PROJECT_VERSION}
0047     VARIABLE_PREFIX KASTS
0048     VERSION_HEADER ${CMAKE_CURRENT_BINARY_DIR}/kasts-version.h
0049 )
0050
0051 ecm_set_disabled_deprecation_versions(
0052     QT 5.15.2
0053     KF 5.102.0
0054 )
0055
0056 if (QT_MAJOR_VERSION EQUAL "6")
0057     set(KF_MAJOR_VERSION "6")
0058 else()
0059     set(KF_MAJOR_VERSION "5")
0060 endif()
0061
0062 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} REQUIRED NO_MODULE COMPONENTS Core Quick Test Gui QuickControls2 Sql Svg Xml)
0063 find_package(KF${KF_MAJOR_VERSION} ${KF_MIN_VERSION} REQUIRED COMPONENTS I18n CoreAddons Kirigami2 Syndication Config ThreadWeaver)
0064
0065 if (QT_MAJOR_VERSION EQUAL "6")
0066 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} REQUIRED NO_MODULE COMPONENTS Network)
0067 else()
0068 find_package(KF${KF_MAJOR_VERSION} ${KF_MIN_VERSION} OPTIONAL_COMPONENTS NetworkManagerQt)
0069 endif()
0070
0071 if (NOT KF_MAJOR_VERSION EQUAL "6") # TODO temporary workaround until kirigami-addons is switched to KF6
0072 find_package(KF5KirigamiAddons 0.7 REQUIRED)
0073 endif()
0074
0075 find_package(Taglib REQUIRED)
0076 find_package(Qt${QT_MAJOR_VERSION}Keychain)
0077 set_package_properties(Qt${QT_MAJOR_VERSION}Keychain PROPERTIES
0078     TYPE REQUIRED
0079     PURPOSE "Secure storage of account secrets"
0080 )
0081
0082 if (ANDROID)
0083     find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} REQUIRED COMPONENTS Svg)
0084     if (QT_MAJOR_VERSION EQUAL "5")
0085         find_package(Qt5 REQUIRED COMPONENTS AndroidExtras)
0086     endif()
0087     find_package(OpenSSL REQUIRED)
0088     find_package(SQLite3)
0089     find_package(ZLIB)
0090     find_package(Gradle)
0091 else()
0092     find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} REQUIRED COMPONENTS Widgets DBus)
0093 endif()
0094
0095 add_definitions(-DQT_NO_CAST_FROM_ASCII
0096                 -DQT_NO_CAST_TO_ASCII
0097                 -DQT_NO_URL_CAST_FROM_STRING
0098                 -DQT_NO_NARROWING_CONVERSIONS_IN_CONNECT
0099                 -DQT_USE_QSTRINGBUILDER
0100 )
0101
0102 ki18n_install(po)
0103
0104 install(PROGRAMS org.kde.kasts.desktop DESTINATION ${KDE_INSTALL_APPDIR})
0105 install(FILES org.kde.kasts.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
0106 install(FILES kasts.svg DESTINATION ${KDE_INSTALL_FULL_ICONDIR}/hicolor/scalable/apps)
0107 install(FILES icons/kasts-tray-dark.svg DESTINATION ${KDE_INSTALL_FULL_ICONDIR}/hicolor/scalable/apps)
0108 install(FILES icons/kasts-tray-light.svg DESTINATION ${KDE_INSTALL_FULL_ICONDIR}/hicolor/scalable/apps)
0109 install(FILES icons/media-playback-cloud.svg DESTINATION ${KDE_INSTALL_FULL_ICONDIR}/hicolor/scalable/actions)
0110
0111 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/android/version.gradle.in ${CMAKE_BINARY_DIR}/version.gradle)
0112
0113 add_subdirectory(src)
0114
0115 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)
0116
0117 if (NOT ANDROID)
0118     # inside if-statement to work around problems with gitlab Android CI
0119     file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES src/*.cpp src/*.h)
0120     kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0121     kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0122 endif()