multimedia/kaffeine/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 project(kaffeine)
0004
0005 set(KAFFEINE_MAJOR_VERSION 2)
0006 set(KAFFEINE_MINOR_VERSION 0)
0007 set(KAFFEINE_PATCH_VERSION 18)
0008
0009 # comment/uuncomment below if either the version is a production or a development one
0010 #set(KAFFEINE_EXTRA_VERSION -git)
0011
0012 set(KAFFEINE_VERSION
0013   ${KAFFEINE_MAJOR_VERSION}.${KAFFEINE_MINOR_VERSION}.${KAFFEINE_PATCH_VERSION}${KAFFEINE_EXTRA_VERSION})
0014
0015 option(BUILD_TOOLS "Build the helper tools" OFF)
0016
0017 set(QT_MIN_VERSION "5.4.0")
0018 set(KF5_MIN_VERSION "5.11.0")
0019
0020 find_package(Qt5Core)
0021 find_package(ECM 1.0.0 REQUIRED NO_MODULE)
0022 set(CMAKE_MODULE_PATH
0023         ${ECM_MODULE_PATH}
0024         "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
0025 )
0026
0027 include(KDEInstallDirs)
0028 include(KDECMakeSettings)
0029 include(KDECompilerSettings)
0030 include(FeatureSummary)
0031 include(ECMInstallIcons)
0032 include(CheckIncludeFiles)
0033
0034 # Instruct CMake to run moc automatically when needed.
0035 set(CMAKE_AUTOMOC ON)
0036
0037 # Find Qt modules
0038 find_package(Qt5 ${QT_MIN_VERSION} CONFIG REQUIRED COMPONENTS
0039         Core    # QCommandLineParser, QStringLiteral
0040         Widgets # QApplication
0041         Network
0042         Sql
0043         X11Extras
0044 )
0045
0046 # Find KDE modules
0047 find_package(KF5 ${KF5_MIN_VERSION} REQUIRED COMPONENTS
0048         CoreAddons      # KAboutData
0049         I18n            # KLocalizedString
0050         WidgetsAddons   # KMessageBox
0051         WindowSystem    # KStartupInfo
0052         XmlGui          # KActonCollection
0053         KIO             # KFileWidget
0054         Solid
0055         DBusAddons
0056 )
0057 find_package(KF5DocTools ${KF5_MIN_VERSION} QUIET)
0058
0059 find_package(X11 REQUIRED)
0060 find_package(VLC 1.2 REQUIRED)
0061
0062 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)
0063
0064 if(CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
0065   # FreeBSD has a fully-working v4l, but needs help finding it
0066   unset(_dvb_headers)
0067   find_package(Libdvbv5)
0068   if (Libdvbv5_FOUND)
0069     find_path(_dvb_headers
0070       NAMES dmx.h
0071       PATH_SUFFIXES dvb linux/dvb
0072     )
0073     if(_dvb_headers)
0074       include_directories(${_dvb_headers})
0075     endif()
0076   endif()
0077   if(NOT _dvb_headers)
0078     include_directories(${CMAKE_CURRENT_SOURCE_DIR}/include)
0079   endif()
0080 else()
0081   # Linux (and others) have a weird copy of v4l headers to use
0082   include_directories(${CMAKE_CURRENT_SOURCE_DIR}/include)
0083 endif()
0084 include_directories(${CMAKE_BINARY_DIR} ${VLC_INCLUDE_DIRS}
0085                     ${X11_Xscreensaver_INCLUDE_PATH})
0086
0087 check_include_files(${CMAKE_CURRENT_SOURCE_DIR}/include/frontend.h HAVE_DVB)
0088
0089 if(NOT HAVE_DVB)
0090   MESSAGE(STATUS "Disabled features:\nDVB  Digital television support for Linux\n")
0091   set(HAVE_DVB 0)
0092 else()
0093   set(HAVE_DVB 1)
0094 endif(NOT HAVE_DVB)
0095
0096 if(HAVE_DVB)
0097   find_package(Libdvbv5)
0098   if(NOT Libdvbv5_FOUND)
0099     set(HAVE_LIBDVBV5 0)
0100     set(HAVE_DVB 0)
0101     message(STATUS "Disabled features:\nDVB  Digital television support for Linux, as libdvbv5 was not found.\n")
0102   endif(NOT Libdvbv5_FOUND)
0103 endif(HAVE_DVB)
0104
0105 add_subdirectory(deviceactions)
0106 add_subdirectory(icons)
0107 add_subdirectory(src)
0108
0109 ki18n_install(po)
0110
0111 if(KF5DocTools_VERSION)
0112   add_subdirectory(doc)
0113   kdoctools_install(po)
0114 endif(KF5DocTools_VERSION)
0115
0116 if(BUILD_TOOLS)
0117   add_subdirectory(tools)
0118 endif(BUILD_TOOLS)