k3b/libk3bdevice/CMakeLists.txt

0001
0002 add_library(k3bdevice SHARED
0003     k3bdevice.cpp
0004     k3bdevice_mmc.cpp
0005     k3bscsicommand.cpp
0006     k3btrack.cpp
0007     k3btoc.cpp
0008     k3bdevicemanager.cpp
0009     k3bmsf.cpp
0010     k3bdiskinfo.cpp
0011     k3bdeviceglobals.cpp
0012     k3bcrc.cpp
0013     k3bcdtext.cpp
0014 )
0015
0016 target_include_directories(k3bdevice PUBLIC .)
0017
0018 target_link_libraries(k3bdevice
0019     PUBLIC
0020         Qt${QT_MAJOR_VERSION}::Core
0021     PRIVATE
0022         KF${KF_MAJOR_VERSION}::ConfigCore
0023         KF${KF_MAJOR_VERSION}::I18n
0024         KF${KF_MAJOR_VERSION}::KIOCore
0025         KF${KF_MAJOR_VERSION}::Solid
0026 )
0027 if (QT_MAJOR_VERSION STREQUAL "6")
0028     target_link_libraries(k3bdevice PRIVATE Qt6::Core5Compat)
0029 endif()
0030
0031 if(CMAKE_SYSTEM_NAME MATCHES "k?FreeBSD")
0032     target_link_libraries(k3bdevice PRIVATE cam)
0033 endif()
0034
0035 set_target_properties(k3bdevice PROPERTIES
0036     VERSION ${K3B_LIB_VERSION_MAJOR}.${K3B_LIB_VERSION_MINOR}.${K3B_LIB_VERSION_RELEASE}
0037     SOVERSION ${K3B_LIB_VERSION_MAJOR}
0038 )
0039
0040 generate_export_header(k3bdevice
0041     EXPORT_MACRO_NAME LIBK3BDEVICE_EXPORT
0042     DEPRECATED_MACRO_NAME LIBK3BDEVICE_EXPORT_DEPRECATED
0043     EXPORT_FILE_NAME k3bdevice_export.h
0044 )
0045
0046 install(TARGETS k3bdevice ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} )
0047
0048 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/k3bdevice_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
0049
0050 install( FILES
0051     k3bdevicemanager.h
0052     k3bdevice.h
0053     k3btoc.h
0054     k3btrack.h
0055     k3bdeviceglobals.h
0056     k3bdiskinfo.h
0057     k3bcdtext.h
0058     k3bmsf.h
0059     k3bdevicetypes.h
0060     DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel
0061 )