audiocd-kio/plugins/CMakeLists.txt

0001 find_package(FLAC)
0002 if(FLAC_FOUND)
0003     add_subdirectory(flac)
0004 endif(FLAC_FOUND)
0005
0006 find_package(OggVorbis)
0007 if(OGGVORBIS_FOUND AND HAVE_LIBVORBISENC2)
0008     add_subdirectory(vorbis)
0009 endif(OGGVORBIS_FOUND AND HAVE_LIBVORBISENC2)
0010
0011 add_subdirectory(wav)
0012 add_subdirectory(lame)
0013 add_subdirectory(opus)
0014
0015 ########### next target ###############
0016
0017 set(AUDIOCDPLUGINS_INSTALL_INCLUDEDIR "${KDE_INSTALL_INCLUDEDIR}/audiocdplugins")
0018
0019 ecm_setup_version(PROJECT
0020     VARIABLE_PREFIX AUDIOCDPLUGINS
0021     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/audiocdplugins_version.h"
0022     SOVERSION 5
0023 )
0024
0025 add_library(audiocdplugins SHARED)
0026
0027 target_sources(audiocdplugins PRIVATE
0028     audiocdencoder.cpp audiocdencoder.h
0029 )
0030 target_include_directories(audiocdplugins
0031     PRIVATE
0032         ${CMAKE_BINARY_DIR}
0033 )
0034 target_link_libraries(audiocdplugins
0035     PUBLIC
0036         KF6::KIOCore
0037         KCddb6
0038 )
0039
0040 generate_export_header(audiocdplugins
0041     EXPORT_MACRO_NAME AUDIOCDPLUGINS_EXPORT
0042     DEPRECATED_MACRO_NAME AUDIOCDPLUGINS_EXPORT_DEPRECATED
0043     EXPORT_FILE_NAME audiocdplugins_export.h
0044 )
0045
0046 set_target_properties(audiocdplugins PROPERTIES
0047     VERSION ${AUDIOCDPLUGINS_VERSION}
0048     SOVERSION ${AUDIOCDPLUGINS_SOVERSION}
0049 )
0050
0051 install(TARGETS audiocdplugins ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0052
0053 install(FILES
0054     ${CMAKE_CURRENT_BINARY_DIR}/audiocdplugins_export.h
0055     ${CMAKE_CURRENT_BINARY_DIR}/audiocdplugins_version.h
0056     audiocdencoder.h
0057     DESTINATION ${AUDIOCDPLUGINS_INSTALL_INCLUDEDIR}
0058     COMPONENT Devel
0059 )
0060