audiocd-kio/cmake/FindCdparanoia.cmake

0001 # - Try to find the CD Paranoia libraries
0002 # Once done this will define
0003 #
0004 #  CDPARANOIA_FOUND       - system has cdparanoia
0005 #  CDPARANOIA_INCLUDE_DIR - the cdparanoia include directory
0006 #  CDPARANOIA_LIBRARIES   - Link these to use cdparanoia
0007 #
0008
0009 # Copyright (c) 2006, Richard Laerkaeng, <richard@goteborg.utfors.se>
0010 # Copyright (c) 2007, Allen Winter, <winter@kde.org>
0011 #
0012 # Redistribution and use is allowed according to the terms of the BSD license.
0013 # For details see the accompanying COPYING-CMAKE-SCRIPTS file.
0014
0015 find_path(CDPARANOIA_INCLUDE_DIR cdda_interface.h PATH_SUFFIXES cdda cdparanoia)
0016
0017 find_library(CDPARANOIA_LIBRARY NAMES cdda_paranoia)
0018 find_library(CDPARANOIA_IF_LIBRARY NAMES cdda_interface)
0019
0020 if (CDPARANOIA_LIBRARY AND CDPARANOIA_IF_LIBRARY)
0021     SET(CDPARANOIA_LIBRARIES ${CDPARANOIA_LIBRARY} ${CDPARANOIA_IF_LIBRARY} "-lm")
0022 endif ()
0023
0024 include(FindPackageHandleStandardArgs)
0025 find_package_handle_standard_args(Cdparanoia
0026     DEFAULT_MSG
0027     CDPARANOIA_LIBRARIES CDPARANOIA_INCLUDE_DIR
0028 )
0029
0030 mark_as_advanced(
0031     CDPARANOIA_INCLUDE_DIR
0032     CDPARANOIA_LIBRARY
0033     CDPARANOIA_IF_LIBRARY
0034 )
0035
0036 if(CDPARANOIA_FOUND AND NOT TARGET Cdparanoia::Cdparanoia)
0037     add_library(Cdparanoia::Cdparanoia UNKNOWN IMPORTED)
0038     set_target_properties(Cdparanoia::Cdparanoia PROPERTIES
0039         IMPORTED_LOCATION "${CDPARANOIA_LIBRARY}"
0040         INTERFACE_LINK_LIBRARIES  "${CDPARANOIA_IF_LIBRARY};-lm"
0041         INTERFACE_INCLUDE_DIRECTORIES "${CDPARANOIA_INCLUDE_DIR}"
0042     )
0043 endif()