cmake/modules/FindGDKPixBuf.cmake

0001 # - Find GDK-PixBuf
0002 # Find the GDK-PixBuf include directories and libraries
0003 #
0004 # This module defines
0005 #   GDKPIXBUF_FOUND       - true if the following are found
0006 #   GDKPIXBUF_INCLUDE_DIR - GDK-PixBuf include directory
0007 #   GDKPIXBUF_LIBRARY     - GDK-PixBuf library location
0008
0009 find_package( PkgConfig )
0010 if( PKG_CONFIG_FOUND )
0011     # If pkg-config finds gdk-pixbuf-2.0, this will set:
0012     #   PC_GDKPIXBUF_FOUND (to TRUE)
0013     #   PC_GDKPIXBUF_INCLUDEDIR
0014     #   PC_GDKPIXBUF_INCLUDE_DIRS
0015     #   PC_GDKPIXBUF_LIBDIR
0016     #   PC_GDKPIXBUF_LIBRARY_DIRS
0017     # These variables are then used as hints to find_path()
0018     # and find_library()
0019     pkg_search_module( PC_GDKPIXBUF gdk-pixbuf-2.0 )
0020 endif()
0021
0022 find_path( GDKPIXBUF_INCLUDE_DIR gdk-pixbuf/gdk-pixbuf.h
0023     HINTS
0024         # Hints provided by pkg-config
0025         ${PC_GDKPIXBUF_INCLUDEDIR}
0026         ${PC_GDKPIXBUF_INCLUDEDIR}/*
0027         ${PC_GDKPIXBUF_INCLUDE_DIRS}
0028     PATHS
0029         # Standard include directories
0030         /usr/include/
0031         /sw/include/
0032         /usr/local/include/
0033         # Search all subdirs of the above
0034         /usr/include/*
0035         /sw/include/*
0036         /usr/local/include/*
0037     PATH_SUFFIXES
0038         # Subdirectory hints
0039         gdk-pixbuf-2.0
0040         gtk-2.0
0041 )
0042
0043 find_library( GDKPIXBUF_LIBRARY gdk_pixbuf-2.0
0044     HINTS
0045         # Hints provided by pkg-config
0046         ${PC_GDKPIXBUF_LIBDIR}
0047         ${PC_GDKPIXBUF_LIBRARY_DIRS}
0048 )
0049
0050 include( FindPackageHandleStandardArgs )
0051 # Sets GDKPIXBUF_FOUND to true if GDKPIXBUF_INCLUDE_DIR and
0052 # GDKPIXBUF_LIBRARY are both set
0053 find_package_handle_standard_args( GDKPixBuf DEFAULT_MSG
0054     GDKPIXBUF_LIBRARY
0055     GDKPIXBUF_INCLUDE_DIR
0056 )
0057 if( GDKPIXBUF_FOUND )
0058     message( STATUS "\tInclude directory: ${GDKPIXBUF_INCLUDE_DIR}" )
0059 endif()
0060
0061 mark_as_advanced( GDKPIXBUF_INCLUDE_DIR GDKPIXBUF_LIBRARY )