maui/vvave/CMakeLists.txt

0001 # Copyright 2018-2020 Camilo Higuita <milo.h@aol.com>
0002 # Copyright 2018-2020 Nitrux Latinoamericana S.C.
0003 #
0004 # SPDX-License-Identifier: GPL-3.0-or-later
0005
0006 cmake_minimum_required(VERSION 3.16)
0007
0008 set(VVAVE_VERSION 3.1.0)
0009 add_compile_definitions(APP_COPYRIGHT_NOTICE="© 2019-2024 Maui Development Team")
0010
0011 set(CMAKE_CXX_STANDARD 17)
0012 set(CMAKE_CXX_STANDARD_REQUIRED ON)
0013 set(CMAKE_INCLUDE_CURRENT_DIR ON)
0014
0015 set(CMAKE_AUTOUIC ON)
0016 set(CMAKE_AUTOMOC ON)
0017 set(CMAKE_AUTORCC ON)
0018
0019 project(vvave VERSION ${VVAVE_VERSION} LANGUAGES CXX)
0020
0021 set(REQUIRED_QT_VERSION 5.15.2)
0022 set(REQUIRED_KF5_VERSION 5.40.0)
0023
0024 find_package(ECM ${REQUIRED_KF5_VERSION} REQUIRED NO_MODULE)
0025 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0026
0027 if(UNIX AND NOT APPLE AND NOT ANDROID)
0028     include(KDEInstallDirs)
0029     include(KDECMakeSettings)
0030     include(ECMInstallIcons)
0031     include(ECMAddAppIcon)
0032 endif()
0033
0034 include(KDECompilerSettings NO_POLICY_SCOPE)
0035 include(KDEClangFormat)
0036 include(ECMSetupVersion)
0037 include(ECMSourceVersionControl)
0038 include(FeatureSummary)
0039
0040 if(ANDROID)
0041     set(ANDROID_PACKAGE_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/android_files)
0042     set(ANDROID_ABIS "armeabi-v7a")
0043     configure_file(${CMAKE_CURRENT_SOURCE_DIR}/android_files/version.gradle.in ${CMAKE_BINARY_DIR}/version.gradle)
0044 endif()
0045
0046 option(QUICK_COMPILER "Use QtQuick compiler to improve performance" TRUE)
0047
0048 find_package(Qt5 ${REQUIRED_QT_VERSION} REQUIRED NO_MODULE COMPONENTS Core Qml Quick QuickControls2 Network Sql Xml Multimedia)
0049 find_package(KF5 ${REQUIRED_KF5_VERSION} REQUIRED COMPONENTS I18n CoreAddons)
0050
0051 if(QUICK_COMPILER)
0052     find_package(Qt5QuickCompiler)
0053     set_package_properties(Qt5QuickCompiler PROPERTIES
0054         DESCRIPTION "Compile QML at build time"
0055         TYPE OPTIONAL)
0056 endif()
0057
0058 find_package(MauiKit3 REQUIRED COMPONENTS FileBrowsing Accounts)
0059 find_package(MauiKit3 REQUIRED)
0060
0061 find_package(Taglib 1.4 REQUIRED)
0062
0063 if(ANDROID)
0064     find_package(Qt5 ${REQUIRED_QT_VERSION} REQUIRED NO_MODULE COMPONENTS AndroidExtras)
0065 elseif(UNIX)
0066     find_package(Qt5 ${REQUIRED_QT_VERSION} REQUIRED NO_MODULE COMPONENTS DBus)
0067 endif()
0068
0069 if(UNIX OR WIN32 OR APPLE AND NOT ANDROID)
0070     find_package(Qt5 ${REQUIRED_QT_VERSION} REQUIRED NO_MODULE COMPONENTS Widgets)
0071 endif()
0072
0073 if(${ECM_SOURCE_UNDER_VERSION_CONTROL})
0074     execute_process(
0075         COMMAND git rev-parse --abbrev-ref HEAD
0076         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
0077         OUTPUT_VARIABLE GIT_BRANCH
0078         OUTPUT_STRIP_TRAILING_WHITESPACE)
0079
0080     # Get the latest abbreviated commit hash of the working branch
0081     execute_process(
0082         COMMAND git log -1 --format=%h
0083         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
0084         OUTPUT_VARIABLE GIT_COMMIT_HASH
0085         OUTPUT_STRIP_TRAILING_WHITESPACE)
0086
0087     add_definitions(-DGIT_COMMIT_HASH="${GIT_COMMIT_HASH}")
0088     add_definitions(-DGIT_BRANCH="${GIT_BRANCH}")
0089
0090 else()
0091     add_definitions(-DGIT_COMMIT_HASH="${VVAVE_VERSION}")
0092     add_definitions(-DGIT_BRANCH="Stable")
0093 endif()
0094
0095 ecm_setup_version(${VVAVE_VERSION}
0096     VARIABLE_PREFIX VVAVE
0097     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/vvave_version.h")
0098
0099 add_subdirectory(src)
0100
0101 ki18n_install(po)
0102
0103 if(UNIX AND NOT APPLE AND NOT ANDROID)
0104     install(FILES org.kde.vvave.desktop DESTINATION ${XDG_APPS_INSTALL_DIR})
0105     install(FILES org.kde.vvave.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
0106 endif()
0107
0108 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0109
0110 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h)
0111 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})