mauikit-filebrowsing/src/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2020 Camilo Higuita <milo.h@aol.com>
0002 #
0003 # SPDX-License-Identifier: GPL-3.0-or-later
0004
0005 include_directories(
0006     ${CMAKE_CURRENT_SOURCE_DIR}/code/libwebdavclient/lib
0007     ${CMAKE_CURRENT_SOURCE_DIR}/code/libwebdavclient/lib/utils
0008     ${CMAKE_CURRENT_SOURCE_DIR}/code/libwebdavclient/lib/dto)
0009
0010 ecm_add_qml_module(MauiKitFileBrowsing${MAUI_MAJOR_VERSION}
0011 URI "org.mauikit.filebrowsing"
0012 CLASS_NAME FileBrowsingPlugin)
0013
0014 set(sources
0015     code/filebrowsing_plugin.cpp
0016     code/fm.cpp
0017     code/fmstatic.cpp
0018     code/fmlist.cpp
0019     code/placeslist.cpp
0020     code/downloader.cpp
0021     code/fileloader.cpp
0022     code/thumbnailer.cpp
0023     code/tagging.cpp
0024     code/tagdb.cpp
0025     code/tagslist.cpp
0026     code/tagging.qrc
0027     code/openwithmodel.cpp
0028     code/moduleinfo.cpp
0029     assets.qrc)
0030
0031 set(headers
0032     code/fm.h
0033     code/fmstatic.h
0034     code/fmlist.h
0035     code/placeslist.h
0036     code/downloader.h
0037     code/fileloader.h
0038     code/thumbnailer.h
0039     code/tagging.h
0040     code/tagdb.h
0041     code/tagslist.h
0042     code/moduleinfo.h
0043     code/openwithmodel.h)
0044
0045 set(syncing_SRCS
0046     code/syncing.cpp
0047     #code/syncinglist.cpp
0048     code/libwebdavclient/lib/WebDAVClient.cpp
0049     code/libwebdavclient/lib/dto/WebDAVItem.cpp
0050     code/libwebdavclient/lib/utils/Environment.cpp
0051     code/libwebdavclient/lib/utils/NetworkHelper.cpp
0052     code/libwebdavclient/lib/utils/WebDAVReply.cpp
0053     code/libwebdavclient/lib/utils/XMLHelper.cpp)
0054
0055 set(syncing_HDRS
0056     code/syncing.h
0057     #code/syncinglist.h
0058     code/libwebdavclient/lib/WebDAVClient.hpp
0059     code/libwebdavclient/lib/dto/WebDAVItem.hpp
0060     code/libwebdavclient/lib/utils/Environment.hpp
0061     code/libwebdavclient/lib/utils/NetworkHelper.hpp
0062     code/libwebdavclient/lib/utils/WebDAVReply.hpp
0063     code/libwebdavclient/lib/utils/XMLHelper.hpp)
0064
0065 if (QT_MAJOR_VERSION STREQUAL "5")
0066     if(QUICK_COMPILER)
0067         qtquick_compiler_add_resources(filebrowsing_QML_QRC resources.qrc)
0068     else()
0069         qt5_add_resources(filebrowsing_QML_QRC resources.qrc)
0070     endif()
0071 endif()
0072
0073 ecm_target_qml_sources(MauiKitFileBrowsing${MAUI_MAJOR_VERSION} SOURCES
0074
0075     controls.${QT_MAJOR_VERSION}/FileBrowser.qml
0076     controls.${QT_MAJOR_VERSION}/OpenWithDialog.qml
0077     controls.${QT_MAJOR_VERSION}/FileDialog.qml
0078     controls.${QT_MAJOR_VERSION}/NewTagDialog.qml
0079     controls.${QT_MAJOR_VERSION}/PlacesListBrowser.qml
0080     controls.${QT_MAJOR_VERSION}/TagsDialog.qml
0081     controls.${QT_MAJOR_VERSION}/TagsBar.qml)
0082
0083 ecm_target_qml_sources(MauiKitFileBrowsing${MAUI_MAJOR_VERSION} PATH private SOURCES
0084
0085     controls.${QT_MAJOR_VERSION}/private/BrowserHolder.qml
0086     controls.${QT_MAJOR_VERSION}/private/BrowserSettings.qml
0087
0088     controls.${QT_MAJOR_VERSION}/private/BrowserView.qml
0089
0090     controls.${QT_MAJOR_VERSION}/private/TagDelegate.qml
0091     controls.${QT_MAJOR_VERSION}/private/TagList.qml)
0092
0093 target_sources(MauiKitFileBrowsing${MAUI_MAJOR_VERSION}
0094     PRIVATE
0095     ${sources}
0096     ${syncing_SRCS})
0097
0098 add_library(MauiKit${MAUI_MAJOR_VERSION}::FileBrowsing ALIAS MauiKitFileBrowsing${MAUI_MAJOR_VERSION})
0099
0100 if (QT_MAJOR_VERSION STREQUAL "5")
0101     if(QUICK_COMPILER)
0102         target_sources(MauiKitFileBrowsing${MAUI_MAJOR_VERSION} PRIVATE ${filebrowsing_QML_QRC})
0103
0104         add_definitions(-DQUICK_COMPILER)
0105         target_compile_definitions(MauiKitFileBrowsing${MAUI_MAJOR_VERSION} PUBLIC QUICK_COMPILER)
0106     endif()
0107 endif()
0108
0109 generate_export_header(MauiKitFileBrowsing${MAUI_MAJOR_VERSION} BASE_NAME FileBrowsing)
0110 set_target_properties(MauiKitFileBrowsing${MAUI_MAJOR_VERSION} PROPERTIES
0111     VERSION ${PROJECT_VERSION}
0112     SOVERSION ${PROJECT_VERSION_MAJOR}
0113     EXPORT_NAME "FileBrowsing")
0114
0115 target_include_directories(MauiKitFileBrowsing${MAUI_MAJOR_VERSION}
0116     INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/MauiKit${MAUI_MAJOR_VERSION}/FileBrowsing>")
0117
0118 target_include_directories(MauiKitFileBrowsing${MAUI_MAJOR_VERSION} PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR};${CMAKE_CURRENT_BINARY_DIR};>")
0119
0120 if(ANDROID)
0121     target_link_libraries(MauiKitFileBrowsing${MAUI_MAJOR_VERSION} PRIVATE Qt${QT_MAJOR_VERSION}::AndroidExtras)
0122 endif()
0123
0124 if(${KIO_AVAILABLE})
0125     target_link_libraries(MauiKitFileBrowsing${MAUI_MAJOR_VERSION}
0126
0127         PRIVATE
0128         KF${KF_MAJOR_VERSION}::KIOCore
0129         KF${KF_MAJOR_VERSION}::KIOFileWidgets)
0130
0131     add_definitions(-DKIO_AVAILABLE)
0132     target_compile_definitions(MauiKitFileBrowsing${MAUI_MAJOR_VERSION} PUBLIC KIO_AVAILABLE)
0133 endif()
0134
0135 target_link_libraries( MauiKitFileBrowsing${MAUI_MAJOR_VERSION}
0136     PRIVATE
0137     KF${KF_MAJOR_VERSION}::I18n
0138     Qt${QT_MAJOR_VERSION}::Core
0139     Qt${QT_MAJOR_VERSION}::Quick
0140     Qt${QT_MAJOR_VERSION}::Qml
0141     Qt${QT_MAJOR_VERSION}::Sql
0142     Qt${QT_MAJOR_VERSION}::Xml
0143     Qt${QT_MAJOR_VERSION}::Concurrent
0144     Qt${QT_MAJOR_VERSION}::Network
0145     MauiKit${MAUI_MAJOR_VERSION})
0146
0147 ecm_finalize_qml_module(MauiKitFileBrowsing${MAUI_MAJOR_VERSION} DESTINATION ${KDE_INSTALL_QMLDIR})
0148 # ecm_generate_qmltypes(org.mauikit.filebrowsing 3.0 DESTINATION ${KDE_INSTALL_QMLDIR}/org/mauikit/filebrowsing)
0149
0150 install(TARGETS MauiKitFileBrowsing${MAUI_MAJOR_VERSION} EXPORT MauiKitFileBrowsing${MAUI_MAJOR_VERSION}Targets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0151
0152 install(FILES
0153     ${headers}
0154     ${syncing_HDRS}
0155     ${CMAKE_CURRENT_BINARY_DIR}/filebrowsing_export.h
0156     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/MauiKit${MAUI_MAJOR_VERSION}/FileBrowsing
0157     COMPONENT Devel)
0158
0159