mauikit-documents/src/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2022 Camilo Higuita <milo.h@aol.com>
0002 #
0003 # SPDX-License-Identifier: BSD-2-Clause
0004
0005 remove_definitions(-DQT_NO_CAST_FROM_ASCII -DQT_STRICT_ITERATORS -DQT_NO_CAST_FROM_BYTEARRAY)
0006
0007 add_subdirectory(code/poppler)
0008 #add_subdirectory(epub)
0009 add_subdirectory(code/cbz)
0010
0011 include_directories(
0012     ${CMAKE_CURRENT_SOURCE_DIR}/code)
0013
0014 ecm_add_qml_module(MauiKitDocuments${MAUI_MAJOR_VERSION} URI "org.mauikit.documents" CLASSNAME DocumentsPlugin)
0015
0016 set(sources
0017     code/plugin.cpp
0018     code/moduleinfo.cpp)
0019
0020 set(headers
0021     code/moduleinfo.h)
0022
0023 if (QT_MAJOR_VERSION STREQUAL "5")
0024     if(QUICK_COMPILER)
0025         qtquick_compiler_add_resources(documents_QML_QRC resources.qrc)
0026     else()
0027         qt5_add_resources(documents_QML_QRC resources.qrc)
0028     endif()
0029 endif()
0030
0031 ecm_target_qml_sources(MauiKitDocuments${MAUI_MAJOR_VERSION} PATH poppler SOURCES
0032     controls.${QT_MAJOR_VERSION}/poppler/PDFViewer.qml)
0033
0034 target_sources(MauiKitDocuments${MAUI_MAJOR_VERSION}
0035     PRIVATE
0036     ${sources})
0037
0038 add_library(MauiKit${MAUI_MAJOR_VERSION}::Documents ALIAS MauiKitDocuments${MAUI_MAJOR_VERSION})
0039
0040 if (QT_MAJOR_VERSION STREQUAL "5")
0041     if(QUICK_COMPILER)
0042         target_sources(MauiKitDocuments${MAUI_MAJOR_VERSION} PRIVATE ${documents_QML_QRC})
0043
0044         add_definitions(-DQUICK_COMPILER)
0045         target_compile_definitions(MauiKitDocuments${MAUI_MAJOR_VERSION} PUBLIC QUICK_COMPILER)
0046     endif()
0047 endif()
0048
0049 generate_export_header(MauiKitDocuments${MAUI_MAJOR_VERSION} BASE_NAME Documents)
0050 set_target_properties(MauiKitDocuments${MAUI_MAJOR_VERSION} PROPERTIES
0051     VERSION ${PROJECT_VERSION}
0052     SOVERSION ${PROJECT_VERSION_MAJOR}
0053     EXPORT_NAME "Documents")
0054
0055 target_include_directories(MauiKitDocuments${MAUI_MAJOR_VERSION}
0056     INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/MauiKit${MAUI_MAJOR_VERSION}/Documents>")
0057
0058 target_include_directories(MauiKitDocuments${MAUI_MAJOR_VERSION} PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR};${CMAKE_CURRENT_BINARY_DIR};>")
0059
0060 if(ANDROID)
0061     target_link_libraries(MauiKitDocuments${MAUI_MAJOR_VERSION} PRIVATE Qt${QT_MAJOR_VERSION}::AndroidExtras)
0062 endif()
0063
0064 if(UNIX AND NOT ANDROID)
0065     target_link_libraries(MauiKitDocuments${MAUI_MAJOR_VERSION} PRIVATE KF${KF_MAJOR_VERSION}::ConfigCore)
0066 endif()
0067
0068 target_link_libraries(MauiKitDocuments${MAUI_MAJOR_VERSION}
0069     PRIVATE
0070     PopplerLib
0071     CBZLib
0072     KF${KF_MAJOR_VERSION}::I18n
0073     Qt${QT_MAJOR_VERSION}::Core
0074     Qt${QT_MAJOR_VERSION}::Quick
0075     Qt${QT_MAJOR_VERSION}::Qml
0076     MauiKit${MAUI_MAJOR_VERSION})
0077
0078 ecm_finalize_qml_module(MauiKitDocuments${MAUI_MAJOR_VERSION} DESTINATION ${KDE_INSTALL_QMLDIR})
0079 ecm_generate_qmltypes(org.mauikit.documents 3.0 DESTINATION ${KDE_INSTALL_QMLDIR}/org/mauikit/documents)
0080
0081 install(TARGETS MauiKitDocuments${MAUI_MAJOR_VERSION} EXPORT MauiKitDocuments${MAUI_MAJOR_VERSION}Targets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0082
0083 install(FILES
0084     ${headers}
0085     ${CMAKE_CURRENT_BINARY_DIR}/documents_export.h
0086     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/MauiKit${MAUI_MAJOR_VERSION}/Documents
0087     COMPONENT Devel)