upnp-lib-qt/src/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2015 (c) Matthieu Gallien <matthieu_gallien@yahoo.fr>
0002
0003 # SPDX-License-Identifier: BSD-2-Clause
0004
0005 set(upnpLibQt_SRCS
0006     upnpssdpengine.cpp
0007     upnpcontrolabstractservice.cpp
0008     upnpcontrolabstractservicereply.cpp
0009     upnpcontrolabstractdevice.cpp
0010     upnphttpserver.cpp
0011     upnpservereventobject.cpp
0012     upnpabstractdevice.cpp
0013     upnpabstractservice.cpp
0014     upnpdevicesoapserver.cpp
0015     upnpdevicesoapserverobject.cpp
0016     upnpbasictypes.h
0017     upnpeventsubscriber.cpp
0018     upnpdevicedescriptionparser.cpp
0019     upnpservicedescriptionparser.cpp
0020     upnpdiscoveryresult.cpp
0021     upnpdevicedescription.cpp
0022     upnpactiondescription.cpp
0023     upnpservicedescription.cpp
0024     upnpstatevariabledescription.cpp
0025 )
0026
0027 ecm_qt_declare_logging_category(upnpLibQt_SRCS
0028     HEADER "ssdplogging.h"
0029     IDENTIFIER "orgKdeUpnpLibQtSsdp"
0030     CATEGORY_NAME "org.kde.upnplibqt.ssdp"
0031     DEFAULT_SEVERITY Info
0032     )
0033
0034 ecm_qt_declare_logging_category(upnpLibQt_SRCS
0035     HEADER "upnplogging.h"
0036     IDENTIFIER "orgKdeUpnpLibQtUpnp"
0037     CATEGORY_NAME "org.kde.upnplibqt.upnp"
0038     DEFAULT_SEVERITY Info
0039     )
0040
0041 add_library(UpnpLibQt ${upnpLibQt_SRCS})
0042 generate_export_header(UpnpLibQt BASE_NAME UpnpLibQt)
0043
0044
0045 target_include_directories(UpnpLibQt
0046     INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/UpnpLibQt>"
0047 )
0048
0049 set_target_properties(UpnpLibQt PROPERTIES
0050     VERSION     0.1
0051     SOVERSION   0
0052     EXPORT_NAME "UpnpLibQt"
0053 )
0054
0055 ecm_generate_headers(UpnpLibQt_HEADERS
0056     HEADER_NAMES
0057     UpnpBasicTypes
0058     UpnpAbstractDevice
0059     UpnpAbstractService
0060     UpnpControlAbstractService
0061     UpnpControlAbstractServiceReply
0062     UpnpControlAbstractDevice
0063     UpnpEventSubscriber
0064     UpnpSsdpEngine
0065     UpnpDiscoveryResult
0066     UpnpDeviceDescriptionParser
0067     UpnpHttpServer
0068     UpnpServerEventObject
0069     UpnpDeviceSoapServer
0070     UpnpDeviceSoapServerObject
0071     UpnpDeviceDescription
0072     UpnpActionDescription
0073     UpnpServiceDescription
0074     UpnpStateVariableDescription
0075
0076     REQUIRED_HEADERS UpnpLibQt_HEADERS
0077 )
0078
0079 install(TARGETS UpnpLibQt
0080         EXPORT UpnpLibQtTargets
0081         ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0082
0083 install(FILES
0084             ${CMAKE_CURRENT_BINARY_DIR}/upnplibqt_export.h
0085             ${UpnpLibQt_HEADERS}
0086         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/UpnpLibQt
0087         COMPONENT Devel)
0088
0089 if(BUILD_QCH)
0090     ecm_add_qch(
0091         UpnpLibQt_QCH
0092         NAME UpnpLibQt
0093         BASE_NAME UpnpLibQt
0094         VERSION ${KF5_VERSION}
0095         ORG_DOMAIN org.kde
0096         SOURCES # using only public headers, to cover only public API
0097             ${UpnpLibQt_HEADERS}
0098         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0099         LINK_QCHS
0100             Qt6Core_QCH
0101         BLANK_MACROS
0102             UPNPLIBQT_EXPORT
0103         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0104         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0105         COMPONENT Devel
0106     )
0107 endif()
0108
0109 include(ECMGeneratePriFile)
0110 ecm_generate_pri_file(BASE_NAME UpnpLibQt LIB_NAME UpnpLibQt DEPS "core" FILENAME_VAR PRI_FILENAME INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/UpnpLibQt)
0111 install(FILES ${PRI_FILENAME}
0112         DESTINATION ${ECM_MKSPECS_INSTALL_DIR})
0113
0114 target_link_libraries(UpnpLibQt
0115     LINK_PUBLIC
0116         Qt::Core
0117         Qt::Network
0118     LINK_PRIVATE
0119         Qt::Xml
0120         KDSoap::kdsoap
0121         KDSoap::kdsoap-server
0122 )
0123
0124 target_include_directories(UpnpLibQt PUBLIC ${KDSoap_INCLUDE_DIRS})