plugins/qca-gcrypt/CMakeLists.txt

0001 if(WITH_gcrypt_PLUGIN STREQUAL "yes")
0002   find_package(LibGcrypt REQUIRED)
0003 else()
0004   find_package(LibGcrypt)
0005 endif()
0006
0007 if(LIBGCRYPT_FOUND)
0008   include(CheckTypeSize)
0009
0010   set(remember_includes ${CMAKE_EXTRA_INCLUDE_FILES})
0011   set(remember_defines ${CMAKE_REQUIRED_FLAGS})
0012   set(CMAKE_EXTRA_INCLUDE_FILES gcrypt.h)
0013   set(CMAKE_REQUIRED_FLAGS ${LIBGCRYPT_CFLAGS})
0014   check_type_size(gcry_error_t GCRY_ERROR_T)
0015   set(CMAKE_REQUIRED_FLAGS ${remember_defines})
0016   set(CMAKE_EXTRA_INCLUDE_FILES ${remember_includes})
0017   if(HAVE_GCRY_ERROR_T)
0018     enable_plugin("gcrypt")
0019
0020     set(QCA_GCRYPT_SOURCES qca-gcrypt.cpp)
0021     add_definitions(${LIBGCRYPT_CFLAGS})
0022     add_library(qca-gcrypt ${PLUGIN_TYPE} ${QCA_GCRYPT_SOURCES})
0023
0024     if(APPLE AND ${PLUGIN_TYPE} STREQUAL "MODULE")
0025       set_property(TARGET qca-gcrypt PROPERTY SUFFIX ".dylib")
0026     endif()
0027
0028     target_link_libraries(qca-gcrypt Qt${QT_MAJOR_VERSION}::Core ${QCA_LIB_NAME} ${LIBGCRYPT_LIBRARIES})
0029
0030     if(NOT DEVELOPER_MODE)
0031       install(TARGETS qca-gcrypt
0032               LIBRARY DESTINATION "${QCA_CRYPTO_INSTALL_DIR}"
0033               ARCHIVE DESTINATION "${QCA_CRYPTO_INSTALL_DIR}"
0034               RUNTIME DESTINATION "${QCA_CRYPTO_INSTALL_DIR}")
0035
0036       install_pdb(qca-gcrypt ${QCA_CRYPTO_INSTALL_DIR})
0037     endif()
0038   else()
0039     message(STATUS "libgcrypt seems to be too old")
0040     disable_plugin("gcrypt")
0041   endif()
0042 else()
0043   disable_plugin("gcrypt")
0044 endif()