Warning, /libraries/pulseaudio-qt/src/CMakeLists.txt is written in an unsupported language. File is not indexed.

0001 add_library(KF${QT_MAJOR_VERSION}PulseAudioQt SHARED)
0002 
0003 target_sources(KF${QT_MAJOR_VERSION}PulseAudioQt PRIVATE
0004     card.cpp
0005     cardport.cpp
0006     client.cpp
0007     context.cpp
0008     device.cpp
0009     maps.cpp
0010     operation.cpp
0011     port.cpp
0012     profile.cpp
0013     models.cpp
0014     pulseobject.cpp
0015     sink.cpp
0016     sinkinput.cpp
0017     source.cpp
0018     sourceoutput.cpp
0019     stream.cpp
0020     volumeobject.cpp
0021     server.cpp
0022     streamrestore.cpp
0023     module.cpp
0024     indexedpulseobject.cpp
0025 )
0026 
0027 ecm_qt_declare_logging_category(KF${QT_MAJOR_VERSION}PulseAudioQt
0028     HEADER debug.h
0029     IDENTIFIER PULSEAUDIOQT
0030     CATEGORY_NAME org.kde.pulseaudio
0031 )
0032 
0033 target_link_libraries(KF${QT_MAJOR_VERSION}PulseAudioQt
0034     PUBLIC
0035         Qt${QT_MAJOR_VERSION}::Core
0036     PRIVATE
0037         Qt${QT_MAJOR_VERSION}::Gui
0038         Qt${QT_MAJOR_VERSION}::DBus
0039         PkgConfig::LIBPULSE
0040         PkgConfig::LIBPULSE_MAINLOOP
0041 )
0042 
0043 target_include_directories(KF${QT_MAJOR_VERSION}PulseAudioQt INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KF${QT_MAJOR_VERSION}PulseAudioQt>" )
0044 
0045 set_target_properties(KF${QT_MAJOR_VERSION}PulseAudioQt PROPERTIES VERSION ${PULSEAUDIOQT_VERSION}
0046                                                    SOVERSION ${PULSEAUDIOQT_SOVERSION}
0047                                                    EXPORT_NAME PulseAudioQt
0048 )
0049 
0050 ecm_generate_headers(PulseAudioQt_HEADERS
0051     HEADER_NAMES
0052         Card
0053         CardPort
0054         Client
0055         Context
0056         Device
0057         IndexedPulseObject
0058         Module
0059         Port
0060         Profile
0061         Models
0062         PulseObject
0063         Server
0064         Sink
0065         SinkInput
0066         Source
0067         SourceOutput
0068         Stream
0069         StreamRestore
0070         VolumeObject
0071     REQUIRED_HEADERS PulseAudioQt_HEADERS
0072 )
0073 ecm_generate_export_header(KF${QT_MAJOR_VERSION}PulseAudioQt
0074     BASE_NAME PulseAudioQt
0075     GROUP_BASE_NAME KF
0076     VERSION ${PROJECT_VERSION}
0077 )
0078 
0079 ecm_generate_pkgconfig_file(BASE_NAME KF${QT_MAJOR_VERSION}PulseAudioQt
0080       INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF5}/KF${QT_MAJOR_VERSION}PulseAudioQt/
0081       DEPS "Qt${QT_MAJOR_VERSION}Core"
0082     INSTALL)
0083 
0084 install(TARGETS KF${QT_MAJOR_VERSION}PulseAudioQt EXPORT PulseAudioQtTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0085 install(FILES
0086     ${PulseAudioQt_HEADERS}
0087     ${CMAKE_CURRENT_BINARY_DIR}/pulseaudioqt_export.h
0088     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KF${QT_MAJOR_VERSION}PulseAudioQt/PulseAudioQt COMPONENT Devel
0089 )
0090 
0091 if(BUILD_QCH)
0092     ecm_add_qch(
0093         KF${QT_MAJOR_VERSION}PulseAudioQt_QCH
0094         NAME PulseAudioQt
0095         BASE_NAME KF${QT_MAJOR_VERSION}PulseAudioQt
0096         VERSION ${PULSEAUDIOQT_VERSION}
0097         ORG_DOMAIN org.kde
0098         SOURCES
0099             ${PulseAudioQt_HEADERS}
0100         LINK_QCHS
0101             Qt${QT_MAJOR_VERSION}Gui_QCH
0102         BLANK_MACROS
0103             PulseAudioQt_EXPORT
0104             PulseAudioQt_DEPRECATED
0105             PulseAudioQt_DEPRECATED_EXPORT
0106         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0107         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0108         COMPONENT Devel
0109     )
0110 endif()