mpvqt/src/CMakeLists.txt

0001 #
0002 # SPDX-FileCopyrightText: 2023 George Florea Bănuș <georgefb899@gmail.com>
0003 #
0004 # SPDX-License-Identifier: BSD-2-Clause
0005 #
0006
0007 add_library(MpvQt)
0008 add_library(MpvQt::MpvQt ALIAS MpvQt)
0009
0010 set_target_properties(MpvQt PROPERTIES
0011     VERSION     ${MPVQT_VERSION}
0012     SOVERSION   ${MPVQT_SOVERSION}
0013     EXPORT_NAME MpvQt
0014 )
0015
0016 target_sources(MpvQt
0017     PRIVATE
0018         mpvabstractitem.h mpvabstractitem.cpp
0019         mpvcontroller.h mpvcontroller.cpp
0020         mpvrenderer.h mpvrenderer.cpp
0021 )
0022
0023 ecm_generate_export_header(MpvQt
0024     BASE_NAME MpvQt
0025     VERSION 1.0.0
0026     USE_VERSION_HEADER
0027 )
0028
0029 target_include_directories(MpvQt
0030     INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/MpvQt>"
0031 )
0032
0033 target_link_libraries(MpvQt
0034     PUBLIC
0035         Qt6::Quick
0036         Libmpv::Libmpv
0037 )
0038
0039 ecm_generate_headers(MpvQt_HEADERS
0040     HEADER_NAMES MpvAbstractItem
0041                  MpvController
0042     REQUIRED_HEADERS MpvQt_HEADERS
0043 )
0044
0045 install(TARGETS MpvQt EXPORT MpvQtTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0046
0047 install(FILES
0048     ${CMAKE_CURRENT_BINARY_DIR}/mpvqt_export.h
0049     ${CMAKE_CURRENT_BINARY_DIR}/mpvqt_version.h
0050     ${MpvQt_HEADERS}
0051     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/MpvQt COMPONENT Devel
0052 )
0053
0054 install(FILES
0055     "${PROJECT_BINARY_DIR}/MpvQtConfig.cmake"
0056     "${PROJECT_BINARY_DIR}/MpvQtConfigVersion.cmake"
0057     "${CMAKE_SOURCE_DIR}/cmake/FindLibmpv.cmake"
0058     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0059     COMPONENT Devel
0060 )
0061
0062 install(EXPORT MpvQtTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE MpvQtTargets.cmake NAMESPACE MpvQt:: )