libraries/libtmdbqt/CMakeLists.txt

0001 project(tmdbqt)
0002 cmake_minimum_required(VERSION 3.5)
0003
0004 set(CMAKE_AUTOMOC TRUE)
0005 set(CMAKE_INCLUDE_CURRENT_DIR ON)
0006
0007 set(CMAKE_CXX_STANDARD 11)
0008 set(CMAKE_CXX_STANDARD_REQUIRED ON)
0009
0010 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules ${CMAKE_MODULE_PATH})
0011
0012 set(QT_REQUIRED_VERSION 5.1.0)
0013 find_package(QT NAMES Qt6 Qt5 CONFIG REQUIRED COMPONENTS Core Network)
0014 find_package(Qt${QT_VERSION_MAJOR} ${QT_REQUIRED_VERSION} CONFIG REQUIRED COMPONENTS Core Network)
0015
0016 # Used to create CMake config files
0017 include(CMakePackageConfigHelpers)
0018
0019 # Used to set installation paths
0020 include(GNUInstallDirs)
0021
0022 # Set the different paths
0023 set(LIB_DESTINATION         "${CMAKE_INSTALL_FULL_LIBDIR}" CACHE PATH "Library directory name")
0024 set(INCLUDE_DESTINATION     "${CMAKE_INSTALL_FULL_INCLUDEDIR}" CACHE PATH "The subdirectory to the header prefix")
0025
0026 set(CMAKE_LIBTMDBQT_VERSION_MAJOR 1)
0027 set(CMAKE_LIBTMDBQT_VERSION_MINOR 0)
0028 set(CMAKE_LIBTMDBQT_VERSION_PATCH 0)
0029 set(TMDBQT_LIB_SONAME TmdbQt${QT_VERSION_MAJOR})
0030 set(TMDBQT_LIB_SONAME_CAMEL TmdbQt${QT_VERSION_MAJOR})
0031 set(TMDBQT_LIB_NAMESPACE TmdbQt)
0032 set(CMAKE_LIBTMDBQT_VERSION_STRING "${CMAKE_LIBTMDBQT_VERSION_MAJOR}.${CMAKE_LIBTMDBQT_VERSION_MINOR}.${CMAKE_LIBTMDBQT_VERSION_PATCH}")
0033
0034 add_definitions(-DQT_NO_CAST_FROM_ASCII)
0035 add_definitions(-DQT_NO_CAST_TO_ASCII)
0036 add_definitions(-DQT_USE_FAST_CONCATENATION -DQT_USE_FAST_OPERATOR_PLUS)
0037
0038 include_directories(${QT_INCLUDES})
0039
0040 if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "GNU" OR
0041     "${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR
0042     ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Intel" AND NOT WIN32))
0043    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -Wextra -Wcast-align -Wchar-subscripts -Wformat-security -Wno-long-long -Wpointer-arith -Wundef -Werror=return-type -Wsuggest-override")
0044   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++0x")
0045 endif()
0046
0047 # Enable static build
0048 option(TMDBQT_STATIC_BUILD "Build a static library" Off)
0049
0050 add_subdirectory(src)
0051
0052 # Enable unit testing
0053 option(TMDBQT_ENABLE_TESTS "Enable tests" ON)
0054 if (TMDBQT_ENABLE_TESTS)
0055     enable_testing()
0056     find_package(Qt${QT_VERSION_MAJOR} ${QT_REQUIRED_VERSION} CONFIG REQUIRED Test)
0057     add_subdirectory(autotests)
0058 endif (TMDBQT_ENABLE_TESTS)
0059
0060 # Write LibTmdbQtConfigVersion.cmake
0061 write_basic_package_version_file(${tmdbqt_BINARY_DIR}/${TMDBQT_LIB_SONAME_CAMEL}ConfigVersion.cmake
0062                                  VERSION ${CMAKE_LIBTMDBQT_VERSION_STRING}
0063                                  COMPATIBILITY SameMajorVersion
0064                                 )
0065
0066 # Create the CMake Config files
0067 configure_package_config_file(TmdbQtConfig.cmake.in
0068                               ${tmdbqt_BINARY_DIR}/${TMDBQT_LIB_SONAME_CAMEL}Config.cmake
0069                               INSTALL_DESTINATION ${LIB_DESTINATION}/cmake/${TMDBQT_LIB_SONAME_CAMEL}
0070                               PATH_VARS LIB_DESTINATION INCLUDE_DESTINATION
0071 )
0072
0073 install(FILES ${tmdbqt_BINARY_DIR}/${TMDBQT_LIB_SONAME_CAMEL}Config.cmake
0074               ${tmdbqt_BINARY_DIR}/${TMDBQT_LIB_SONAME_CAMEL}ConfigVersion.cmake
0075         DESTINATION ${LIB_DESTINATION}/cmake/${TMDBQT_LIB_SONAME_CAMEL}
0076        )
0077
0078 install(EXPORT LibTmdbQtExport FILE ${TMDBQT_LIB_SONAME_CAMEL}Targets.cmake
0079         DESTINATION ${LIB_DESTINATION}/cmake/${TMDBQT_LIB_SONAME_CAMEL}
0080         NAMESPACE ${TMDBQT_LIB_NAMESPACE}::)