libmediawiki/tests/CMakeLists.txt

0001 #
0002 # Copyright (c) 2010-2015, Gilles Caulier, <caulier dot gilles at gmail dot com>
0003 #
0004 # Redistribution and use is allowed according to the terms of the BSD license.
0005 # For details see the accompanying COPYING-CMAKE-SCRIPTS file.
0006
0007 find_package(Qt5 ${QT_MIN_VERSION} CONFIG REQUIRED Test)
0008
0009 include(ECMMarkAsTest)
0010
0011 macro(mediawiki_executable_tests)
0012     foreach(_testname ${ARGN})
0013         add_executable(${_testname} ${_testname}.cpp libmediawikitest/fakeserver.cpp)
0014         target_link_libraries(${_testname} Qt5::Core Qt5::Test Qt5::Network KF5::MediaWiki KF5::CoreAddons)
0015         ecm_mark_as_test(${_testname})
0016         add_test(NAME libmediawiki-${_testname} COMMAND ${_testname})
0017     endforeach(_testname)
0018 endmacro()
0019
0020 mediawiki_executable_tests(
0021     edittest
0022     logintest
0023     logouttest
0024     mediawikitest
0025     parsetest
0026     queryimageinfotest
0027     queryimagestest
0028     queryinfotest
0029     queryrevisiontest
0030     querysiteinfogeneraltest
0031     querysiteinfousergroupstest
0032     uploadtest
0033 )
0034
0035 macro(MEDIAWIKI_TEST_RESOURCES)
0036
0037     foreach(resource ${ARGN})
0038
0039         add_custom_command(OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/${resource}"
0040                             COMMAND ${CMAKE_COMMAND} -E copy
0041                             "${CMAKE_CURRENT_SOURCE_DIR}/${resource}"
0042                             "${CMAKE_CURRENT_BINARY_DIR}/${resource}"
0043                             DEPENDS "${CMAKE_CURRENT_SOURCE_DIR}/${resource}")
0044         list(APPEND test_resources_dest "${resource}" )
0045
0046     endforeach()
0047
0048 endmacro()
0049
0050 MEDIAWIKI_TEST_RESOURCES(
0051     parsetest.rc
0052     queryrevisiontest.rc
0053     queryrevisiontest_content.rc
0054     queryrevisiontest_cuted.rc
0055     queryrevisiontest_onetitle.rc
0056     queryrevisiontest_parsetree.rc
0057     queryrevisiontest_rollback.rc
0058     queryrevisiontest_timestamponly.rc
0059     queryrevisiontest_useronly.rc
0060     uploadtest_image.jpg
0061 )
0062
0063 add_custom_target(TestResources ALL DEPENDS ${test_resources_dest})