libmediawiki/src/CMakeLists.txt

0001 add_library(KF5MediaWiki)
0002 add_library(KF5::MediaWiki ALIAS KF5MediaWiki)
0003 set_target_properties(KF5MediaWiki
0004     PROPERTIES VERSION ${MEDIAWIKI_VERSION}
0005     SOVERSION ${MEDIAWIKI_SOVERSION}
0006     EXPORT_NAME "MediaWiki"
0007 )
0008
0009 target_sources(KF5MediaWiki PRIVATE
0010     image.cpp
0011     imageinfo.cpp
0012     mediawiki.cpp
0013     login.cpp
0014     logout.cpp
0015     queryimageinfo.cpp
0016     queryimages.cpp
0017     querysiteinfogeneral.cpp
0018     generalinfo.cpp
0019     querysiteinfousergroups.cpp
0020     queryrevision.cpp
0021     queryinfo.cpp
0022     edit.cpp
0023     job.cpp
0024     usergroup.cpp
0025     revision.cpp
0026     page.cpp
0027     parse.cpp
0028     protection.cpp
0029     upload.cpp
0030 )
0031
0032 generate_export_header(KF5MediaWiki BASE_NAME MediaWiki)
0033
0034 target_include_directories(KF5MediaWiki INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF5}/MediaWiki>")
0035
0036 target_link_libraries(KF5MediaWiki
0037     PUBLIC
0038         Qt5::Core
0039         Qt5::Network
0040         KF5::CoreAddons
0041 )
0042
0043 ecm_generate_headers(MediaWiki_CamelCase_HEADERS
0044
0045                      HEADER_NAMES
0046                      Edit
0047                      Generalinfo
0048                      Image
0049                      Imageinfo
0050                      Job
0051                      Login
0052                      Logout
0053                      MediaWiki
0054                      Page
0055                      Parse
0056                      Protection
0057                      QueryImageinfo
0058                      QueryImages
0059                      QueryInfo
0060                      QueryRevision
0061                      QuerySiteInfoGeneral
0062                      QuerySiteinfoUsergroups
0063                      Revision
0064                      Upload
0065                      UserGroup
0066
0067                      REQUIRED_HEADERS MediaWiki_HEADERS
0068 )
0069
0070 # Install files
0071 install(TARGETS KF5MediaWiki
0072         EXPORT KF5MediaWikiTargets
0073         ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0074
0075 install(FILES
0076             ${CMAKE_CURRENT_BINARY_DIR}/mediawiki_export.h
0077             ${MediaWiki_HEADERS}
0078             ${MediaWiki_CamelCase_HEADERS}
0079         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF5}/MediaWiki
0080         COMPONENT Devel)
0081
0082 include(ECMGeneratePriFile)
0083
0084 ecm_generate_pri_file(
0085     BASE_NAME MediaWiki
0086     LIB_NAME KF5MediaWiki
0087     DEPS "core network KCoreAddons"
0088     FILENAME_VAR PRI_FILENAME
0089 )
0090
0091 install(FILES ${PRI_FILENAME}
0092         DESTINATION ${ECM_MKSPECS_INSTALL_DIR})