src/client/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2022 Volker Krause <vkrause@kde.org>
0002 # SPDX-License-Identifier: BSD-2-Clause
0003
0004 add_library(KUnifiedPush)
0005
0006 target_sources(KUnifiedPush PRIVATE
0007     connector.cpp
0008     connector.h
0009     ../shared/connectorutils.cpp
0010 )
0011 if (NOT ANDROID)
0012     qt_add_dbus_adaptor(dbus_srcs  ../interfaces/org.unifiedpush.Connector1.xml connector_p.h KUnifiedPush::ConnectorPrivate)
0013     qt_add_dbus_interface(dbus_srcs ../interfaces/org.unifiedpush.Distributor1.xml distributor1iface)
0014     target_sources(KUnifiedPush PRIVATE ${dbus_srcs} connector_dbus.cpp)
0015 else()
0016     add_subdirectory(android)
0017     target_sources(KUnifiedPush PRIVATE connector_android.cpp)
0018 endif()
0019
0020 set_target_properties(KUnifiedPush PROPERTIES
0021     VERSION ${KUNIFIEDPUSH_VERSION}
0022     SOVERSION ${KUNIFIEDPUSH_SOVERSION}
0023     EXPORT_NAME KUnifiedPush
0024 )
0025
0026 generate_export_header(KUnifiedPush BASE_NAME KUnifiedPush)
0027 ecm_qt_declare_logging_category(KUnifiedPush
0028     HEADER logging.h
0029     IDENTIFIER Log
0030     CATEGORY_NAME org.kde.kunifiedpush.client
0031     DESCRIPTION "KUnifiedPush Client"
0032     EXPORT KUnifiedPushLogging
0033 )
0034
0035 target_include_directories(KUnifiedPush INTERFACE "$<INSTALL_INTERFACE:${KUNIFIEDPUSH_INCLUDE_INSTALLDIR}>")
0036 target_link_libraries(KUnifiedPush PUBLIC Qt6::Core)
0037 if (NOT ANDROID)
0038     target_link_libraries(KUnifiedPush PRIVATE Qt6::DBus)
0039 endif()
0040
0041 ecm_generate_headers(KUnifiedPush_FORWARDING_HEADERS
0042     HEADER_NAMES
0043         Connector
0044     PREFIX KUnifiedPush
0045     REQUIRED_HEADERS KUnifiedPush_HEADERS
0046 )
0047
0048 install(TARGETS KUnifiedPush EXPORT KUnifiedPushTargets ${INSTALL_TARGETS_DEFAULT_ARGS})
0049 install(FILES
0050     ${KUnifiedPush_FORWARDING_HEADERS}
0051     DESTINATION ${KUNIFIEDPUSH_INCLUDE_INSTALLDIR}/KUnifiedPush
0052 )
0053 install(FILES
0054     ${KUnifiedPush_HEADERS}
0055     ${CMAKE_CURRENT_BINARY_DIR}/kunifiedpush_export.h
0056     DESTINATION ${KUNIFIEDPUSH_INCLUDE_INSTALLDIR}/kunifiedpush
0057 )