ktextaddons/texttranslator/CMakeLists.txt

0001 # SPDX-License-Identifier: BSD-3-Clause
0002 # SPDX-FileCopyrightText: 2023-2024 Laurent Montel <montel.org>
0003 add_definitions(-DTRANSLATION_DOMAIN=\"libtexttranslator\")
0004 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF${KF_MAJOR_VERSION}TextTranslator")
0005
0006 ecm_setup_version(PROJECT VARIABLE_PREFIX TEXTTRANSLATE
0007     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/texttranslator_version.h"
0008     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF${KF_MAJOR_VERSION}TextTranslatorConfigVersion.cmake"
0009     SOVERSION 1
0010     )
0011
0012 install(FILES
0013     "${CMAKE_CURRENT_BINARY_DIR}/KF${KF_MAJOR_VERSION}TextTranslatorConfig.cmake"
0014     "${CMAKE_CURRENT_BINARY_DIR}/KF${KF_MAJOR_VERSION}TextTranslatorConfigVersion.cmake"
0015     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0016     COMPONENT Devel
0017     )
0018
0019 install(EXPORT KF${KF_MAJOR_VERSION}TextTranslatorTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF${KF_MAJOR_VERSION}TextTranslatorTargets.cmake NAMESPACE KF${KF_MAJOR_VERSION}::)
0020
0021 install(FILES
0022     ${CMAKE_CURRENT_BINARY_DIR}/texttranslator_version.h
0023     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/TextTranslator/ COMPONENT Devel
0024     )
0025
0026 if(BUILD_DESIGNERPLUGIN)
0027     add_subdirectory(designer)
0028 endif()
0029
0030 add_library(KF${KF_MAJOR_VERSION}TextTranslator )
0031 add_library(KF${KF_MAJOR_VERSION}::TextTranslator ALIAS KF${KF_MAJOR_VERSION}TextTranslator)
0032 ecm_qt_declare_logging_category(KF${KF_MAJOR_VERSION}TextTranslator HEADER texttranslator_debug.h
0033     IDENTIFIER TEXTTRANSLATOR_LOG
0034     CATEGORY_NAME org.kde.kf.texttranslator
0035     OLD_CATEGORY_NAMES org.kde.kf${KF_MAJOR_VERSION}.texttranslator
0036     DESCRIPTION "KF${KF_MAJOR_VERSION} (TextTranslator)"
0037     EXPORT KTEXTADDONS
0038 )
0039
0040 target_sources(KF${KF_MAJOR_VERSION}TextTranslator PRIVATE
0041     translator/misc/translatorutil.cpp
0042     translator/misc/translatorutil.h
0043
0044     translator/widgets/translatorwidget.cpp
0045     translator/widgets/translatorwidget.h
0046     translator/widgets/translatordebugdialog.cpp
0047     translator/widgets/translatordebugdialog.h
0048     translator/widgets/translatorconfigurewidget.cpp
0049     translator/widgets/translatorconfigurewidget.h
0050     translator/widgets/translatorconfiguredialog.h
0051     translator/widgets/translatorconfiguredialog.cpp
0052
0053     translator/widgets/translatorconfigurelistswidget.cpp
0054     translator/widgets/translatorconfigurelistswidget.h
0055     translator/widgets/translatorconfigurelanguagelistwidget.cpp
0056     translator/widgets/translatorconfigurelanguagelistwidget.h
0057     translator/widgets/translatorconfigurecombowidget.h
0058     translator/widgets/translatorconfigurecombowidget.cpp
0059
0060     translator/widgets/translatormenu.cpp
0061     translator/widgets/translatormenu.h
0062
0063
0064     translator/networkmanager.cpp
0065     translator/networkmanager.h
0066     translator/translatorengineaccessmanager.h
0067     translator/translatorengineaccessmanager.cpp
0068
0069     translator/translatorengineplugin.cpp
0070     translator/translatorengineplugin.h
0071
0072     translator/translatorengineclient.h
0073     translator/translatorengineclient.cpp
0074
0075     translator/translatorengineloader.cpp
0076     translator/translatorengineloader.h
0077     )
0078 if (BUILD_TESTING)
0079     add_subdirectory(translator/autotests)
0080     add_subdirectory(translator/tests)
0081     add_subdirectory(translator/widgets/autotests)
0082 endif()
0083 add_subdirectory(translator/plugins)
0084
0085
0086 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0087     set_target_properties(KF${KF_MAJOR_VERSION}TextTranslator PROPERTIES UNITY_BUILD ON)
0088 endif()
0089 generate_export_header(KF${KF_MAJOR_VERSION}TextTranslator BASE_NAME texttranslator)
0090
0091
0092 target_link_libraries(KF${KF_MAJOR_VERSION}TextTranslator
0093     PUBLIC
0094     Qt::Gui
0095     Qt::Widgets
0096     Qt::Network
0097     PRIVATE
0098     KF${KF_MAJOR_VERSION}::I18n
0099     KF${KF_MAJOR_VERSION}::WidgetsAddons
0100     KF${KF_MAJOR_VERSION}::ConfigGui
0101     KF${KF_MAJOR_VERSION}::TextAddonsWidgets
0102     )
0103
0104 target_include_directories(KF${KF_MAJOR_VERSION}TextTranslator INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/TextTranslator/>")
0105
0106 set_target_properties(KF${KF_MAJOR_VERSION}TextTranslator PROPERTIES
0107     VERSION ${TEXTTRANSLATE_VERSION}
0108     SOVERSION ${TEXTTRANSLATE_SOVERSION}
0109     EXPORT_NAME TextTranslator
0110     )
0111
0112 install(TARGETS
0113     KF${KF_MAJOR_VERSION}TextTranslator
0114     EXPORT KF${KF_MAJOR_VERSION}TextTranslatorTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS}
0115     )
0116
0117 ecm_generate_headers(TextTranslator_Camelcasetranslatorwidgets_HEADERS
0118     HEADER_NAMES
0119     TranslatorWidget
0120     TranslatorConfigureDialog
0121     TranslatorConfigureLanguageListWidget
0122     TranslatorConfigureListsWidget
0123     TranslatorMenu
0124     REQUIRED_HEADERS TextTranslator_translatorwidgets_HEADERS
0125     PREFIX TextTranslator
0126     RELATIVE translator/widgets/
0127     )
0128
0129 ecm_generate_headers(TextTranslator_Camelcasetranslator_HEADERS
0130     HEADER_NAMES
0131     TranslatorEnginePlugin
0132     TranslatorEngineClient
0133     TranslatorEngineAccessManager
0134     TranslatorEngineLoader
0135     REQUIRED_HEADERS TextTranslator_translator_HEADERS
0136     PREFIX TextTranslator
0137     RELATIVE translator
0138     )
0139
0140 ecm_generate_headers(TextTranslator_Camelcasetranslatormisc_HEADERS
0141     HEADER_NAMES
0142     TranslatorUtil
0143     REQUIRED_HEADERS TextTranslator_translatormisc_HEADERS
0144     PREFIX TextTranslator
0145     RELATIVE translator/misc/
0146     )
0147
0148 install(FILES
0149     ${CMAKE_CURRENT_BINARY_DIR}/texttranslator_version.h
0150     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/TextTranslator/ COMPONENT Devel
0151     )
0152
0153 install(FILES
0154     ${TextTranslator_Camelcasetranslatorwidgets_HEADERS}
0155     ${TextTranslator_translatorwidgets_HEADERS}
0156
0157     ${TextTranslator_Camelcasetranslatormisc_HEADERS}
0158     ${TextTranslator_translatormisc_HEADERS}
0159
0160     ${TextTranslator_translator_HEADERS}
0161     ${TextTranslator_Camelcasetranslator_HEADERS}
0162     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/TextTranslator/TextTranslator
0163     COMPONENT Devel
0164     )
0165
0166 install(FILES
0167     ${CMAKE_CURRENT_BINARY_DIR}/texttranslator_export.h
0168     ${TextTranslator_translator_HEADERS}
0169     ${TextTranslator_translatorwidgets_HEADERS}
0170     ${TextTranslator_translatormisc_HEADERS}
0171     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/TextTranslator/texttranslator
0172     COMPONENT Devel
0173     )
0174
0175
0176 if (BUILD_QCH)
0177     ecm_add_qch(
0178         KF${KF_MAJOR_VERSION}TextTranslator_QCH
0179         NAME KF${KF_MAJOR_VERSION}TextTranslator
0180         BASE_NAME KF${KF_MAJOR_VERSION}TextTranslator
0181         VERSION ${TEXTTRANSLATE_VERSION}
0182         ORG_DOMAIN org.kde
0183         SOURCES # using only public headers, to cover only public API
0184         ${TextTranslator_translator_HEADERS}
0185         ${TextTranslator_translatorwidgets_HEADERS}
0186         ${TextTranslator_translatormisc_HEADERS}
0187         LINK_QCHS
0188             Qt${QT_MAJOR_VERSION}Core_QCH
0189             Qt${QT_MAJOR_VERSION}Gui_QCH
0190             Qt${QT_MAJOR_VERSION}Widgets_QCH
0191         INCLUDE_DIRS
0192             ${CMAKE_CURRENT_BINARY_DIR}
0193         BLANK_MACROS
0194             TEXTTRANSLATE_EXPORT
0195         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0196         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0197         COMPONENT Devel
0198     )
0199 endif()
0200 if (BUILD_QCH)
0201     ecm_install_qch_export(
0202         TARGETS KF${KF_MAJOR_VERSION}TextTranslator_QCH
0203         FILE KF${KF_MAJOR_VERSION}TextTranslatorQchTargets.cmake
0204         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0205         COMPONENT Devel
0206     )
0207     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF${KF_MAJOR_VERSION}TextTranslatorQchTargets.cmake\")")
0208 endif()
0209
0210 configure_package_config_file(
0211     "${CMAKE_CURRENT_SOURCE_DIR}/KFTextTranslatorConfig.cmake.in"
0212     "${CMAKE_CURRENT_BINARY_DIR}/KF${KF_MAJOR_VERSION}TextTranslatorConfig.cmake"
0213     INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0214     )