ktextaddons/textgrammarcheck/CMakeLists.txt

0001 # SPDX-License-Identifier: BSD-3-Clause
0002 # SPDX-FileCopyrightText: none
0003
0004 add_definitions(-DTRANSLATION_DOMAIN=\"libtextgrammarcheck\")
0005
0006 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF${KF_MAJOR_VERSION}TextGrammarCheck")
0007 if (BUILD_QCH)
0008     ecm_install_qch_export(
0009         TARGETS KF${KF_MAJOR_VERSION}TextGrammarCheck_QCH
0010         FILE KF${KF_MAJOR_VERSION}TextGrammarCheckQchTargets.cmake
0011         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0012         COMPONENT Devel
0013     )
0014 set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF${KF_MAJOR_VERSION}TextGrammarCheckQchTargets.cmake\")")
0015 endif()
0016 configure_package_config_file(
0017     "${CMAKE_CURRENT_SOURCE_DIR}/KFTextGrammarCheckConfig.cmake.in"
0018     "${CMAKE_CURRENT_BINARY_DIR}/KF${KF_MAJOR_VERSION}TextGrammarCheckConfig.cmake"
0019     INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0020     )
0021
0022
0023 ecm_setup_version(PROJECT VARIABLE_PREFIX TEXTGRAMMARCHECK
0024     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/textgrammarcheck_version.h"
0025     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF${KF_MAJOR_VERSION}TextGrammarCheckConfigVersion.cmake"
0026     SOVERSION 1
0027     )
0028
0029 install(FILES
0030     "${CMAKE_CURRENT_BINARY_DIR}/KF${KF_MAJOR_VERSION}TextGrammarCheckConfig.cmake"
0031     "${CMAKE_CURRENT_BINARY_DIR}/KF${KF_MAJOR_VERSION}TextGrammarCheckConfigVersion.cmake"
0032     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0033     COMPONENT Devel
0034     )
0035
0036 install(EXPORT KF${KF_MAJOR_VERSION}TextGrammarCheckTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF${KF_MAJOR_VERSION}TextGrammarCheckTargets.cmake NAMESPACE KF${KF_MAJOR_VERSION}::)
0037
0038 install(FILES
0039     ${CMAKE_CURRENT_BINARY_DIR}/textgrammarcheck_version.h
0040     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/TextGrammarCheck/ COMPONENT Devel
0041     )
0042
0043 add_library(KF${KF_MAJOR_VERSION}TextGrammarCheck )
0044 add_library(KF${KF_MAJOR_VERSION}::TextGrammarCheck ALIAS KF${KF_MAJOR_VERSION}TextGrammarCheck)
0045 ecm_qt_declare_logging_category(KF${KF_MAJOR_VERSION}TextGrammarCheck HEADER textgrammarcheck_debug.h
0046     IDENTIFIER TEXTGRAMMARCHECK_LOG
0047     CATEGORY_NAME org.kde.kf.textgrammarcheck
0048     OLD_CATEGORY_NAMES org.kde.kf${KF_MAJOR_VERSION}.textgrammarcheck
0049         DESCRIPTION "KF${KF_MAJOR_VERSION} (Text Grammar Check)"
0050         EXPORT KTEXTADDONS
0051     )
0052
0053 target_sources(KF${KF_MAJOR_VERSION}TextGrammarCheck PRIVATE
0054     common/grammarerror.cpp
0055     common/grammarerror.h
0056     common/grammaraction.h
0057     common/grammaraction.cpp
0058     common/grammarresultwidget.cpp
0059     common/grammarresultwidget.h
0060     common/grammarresulttextedit.cpp
0061     common/grammarresulttextedit.h
0062     common/grammarresultutil.h
0063     common/grammarresultutil.cpp
0064
0065     languagetool/languageinfo.cpp
0066     languagetool/languageinfo.h
0067     languagetool/languagetoolcombobox.cpp
0068     languagetool/languagetoolcombobox.h
0069     languagetool/languagetoolconfigdialog.cpp
0070     languagetool/languagetoolconfigdialog.h
0071     languagetool/languagetoolconfigwidget.cpp
0072     languagetool/languagetoolconfigwidget.h
0073     languagetool/languagetoolgetlistoflanguagejob.cpp
0074     languagetool/languagetoolgetlistoflanguagejob.h
0075     languagetool/languagetoolgrammarerror.cpp
0076     languagetool/languagetoolgrammarerror.h
0077     languagetool/languagetoollistoflanguagesparser.cpp
0078     languagetool/languagetoollistoflanguagesparser.h
0079     languagetool/languagetoolmanager.cpp
0080     languagetool/languagetoolmanager.h
0081     languagetool/languagetoolparser.cpp
0082     languagetool/languagetoolparser.h
0083     languagetool/languagetoolresultjob.cpp
0084     languagetool/languagetoolresultjob.h
0085     languagetool/languagetoolresultwidget.cpp
0086     languagetool/languagetoolresultwidget.h
0087     languagetool/languagetoolupdatecombobox.cpp
0088     languagetool/languagetoolupdatecombobox.h
0089
0090     grammalecte/grammalecteconfigdialog.cpp
0091     grammalecte/grammalecteconfigdialog.h
0092     grammalecte/grammalecteconfigwidget.cpp
0093     grammalecte/grammalecteconfigwidget.h
0094     grammalecte/grammalectegenerateconfigoptionjob.cpp
0095     grammalecte/grammalectegenerateconfigoptionjob.h
0096     grammalecte/grammalectegrammarerror.cpp
0097     grammalecte/grammalectegrammarerror.h
0098     grammalecte/grammalectemanager.cpp
0099     grammalecte/grammalectemanager.h
0100     grammalecte/grammalecteparser.cpp
0101     grammalecte/grammalecteparser.h
0102     grammalecte/grammalecteresultjob.cpp
0103     grammalecte/grammalecteresultjob.h
0104     grammalecte/grammalecteresultwidget.cpp
0105     grammalecte/grammalecteresultwidget.h
0106     grammalecte/grammalecteurlrequesterwidget.h
0107     grammalecte/grammalecteurlrequesterwidget.cpp
0108     )
0109 if (BUILD_TESTING)
0110     add_subdirectory(grammalecte/autotests)
0111     add_subdirectory(grammalecte/tests)
0112     add_subdirectory(languagetool/autotests)
0113     add_subdirectory(languagetool/tests)
0114     add_subdirectory(common/autotests/)
0115 endif()
0116
0117 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0118     set_target_properties(KF${KF_MAJOR_VERSION}TextGrammarCheck PROPERTIES UNITY_BUILD ON)
0119 endif()
0120 generate_export_header(KF${KF_MAJOR_VERSION}TextGrammarCheck BASE_NAME textgrammarcheck)
0121
0122
0123 target_link_libraries(KF${KF_MAJOR_VERSION}TextGrammarCheck
0124     PUBLIC
0125     Qt::Gui
0126     Qt::Widgets
0127     PRIVATE
0128     Qt::Network
0129     KF${KF_MAJOR_VERSION}::I18n
0130     KF${KF_MAJOR_VERSION}::ConfigWidgets
0131     )
0132
0133 target_include_directories(KF${KF_MAJOR_VERSION}TextGrammarCheck INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/TextGrammarCheck/>")
0134
0135 set_target_properties(KF${KF_MAJOR_VERSION}TextGrammarCheck PROPERTIES
0136     VERSION ${TEXTGRAMMARCHECK_VERSION}
0137     SOVERSION ${TEXTGRAMMARCHECK_SOVERSION}
0138     EXPORT_NAME TextGrammarCheck
0139     )
0140
0141 install(TARGETS
0142     KF${KF_MAJOR_VERSION}TextGrammarCheck
0143     EXPORT KF${KF_MAJOR_VERSION}TextGrammarCheckTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS}
0144     )
0145
0146 ecm_generate_headers(TextGrammarCheck_Camelcasecommon_HEADERS
0147     HEADER_NAMES
0148     GrammarAction
0149     GrammarError
0150     GrammarResultTextEdit
0151     GrammarResultWidget
0152     REQUIRED_HEADERS TextGrammarCheck_common_HEADERS
0153     PREFIX TextGrammarCheck
0154     RELATIVE common/
0155     )
0156
0157 ecm_generate_headers(TextGrammarCheck_Camelcasegrammalecte_HEADERS
0158     HEADER_NAMES
0159     GrammalecteConfigDialog
0160     GrammalecteConfigWidget
0161     GrammalecteManager
0162     GrammalecteResultWidget
0163     GrammalecteGenerateConfigOptionJob
0164     GrammalecteResultJob
0165     REQUIRED_HEADERS TextGrammarCheck_grammalecte_HEADERS
0166     PREFIX TextGrammarCheck
0167     RELATIVE grammalecte/
0168     )
0169
0170 ecm_generate_headers(TextGrammarCheck_Camelcaselanguagetool_HEADERS
0171     HEADER_NAMES
0172     LanguageToolComboBox
0173     LanguageToolConfigDialog
0174     LanguageToolConfigWidget
0175     LanguageToolGetListOfLanguageJob
0176     LanguageToolManager
0177     LanguageToolResultWidget
0178     REQUIRED_HEADERS TextGrammarCheck_languagetool_HEADERS
0179     PREFIX TextGrammarCheck
0180     RELATIVE languagetool/
0181     )
0182
0183
0184 install(FILES
0185     ${CMAKE_CURRENT_BINARY_DIR}/textgrammarcheck_version.h
0186     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/TextGrammarCheck/ COMPONENT Devel
0187     )
0188
0189 install(FILES
0190     ${TextGrammarCheck_common_HEADERS}
0191     ${TextGrammarCheck_Camelcasecommon_HEADERS}
0192
0193     ${TextGrammarCheck_grammalecte_HEADERS}
0194     ${TextGrammarCheck_Camelcasegrammalecte_HEADERS}
0195
0196     ${TextGrammarCheck_languagetool_HEADERS}
0197     ${TextGrammarCheck_Camelcaselanguagetool_HEADERS}
0198
0199     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/TextGrammarCheck/TextGrammarCheck
0200     COMPONENT Devel
0201     )
0202
0203 install(FILES
0204     ${CMAKE_CURRENT_BINARY_DIR}/textgrammarcheck_export.h
0205     ${TextGrammarCheck_common_HEADERS}
0206     ${TextGrammarCheck_grammalecte_HEADERS}
0207     ${TextGrammarCheck_languagetool_HEADERS}
0208     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/TextGrammarCheck/textgrammarcheck
0209     COMPONENT Devel
0210     )
0211
0212
0213 if (BUILD_QCH)
0214     ecm_add_qch(
0215         KF${KF_MAJOR_VERSION}TextGrammarCheck_QCH
0216         NAME KF${KF_MAJOR_VERSION}TextGrammarCheck
0217         BASE_NAME KF${KF_MAJOR_VERSION}TextGrammarCheck
0218         VERSION ${TEXTGRAMMARCHECK_VERSION}
0219         ORG_DOMAIN org.kde
0220         SOURCES # using only public headers, to cover only public API
0221         ${TextGrammarCheck_common_HEADERS}
0222         ${TextGrammarCheck_grammalecte_HEADERS}
0223         ${TextGrammarCheck_languagetool_HEADERS}
0224         LINK_QCHS
0225             Qt${QT_MAJOR_VERSION}Core_QCH
0226             Qt${QT_MAJOR_VERSION}Gui_QCH
0227             Qt${QT_MAJOR_VERSION}Widgets_QCH
0228         INCLUDE_DIRS
0229             ${CMAKE_CURRENT_BINARY_DIR}
0230         BLANK_MACROS
0231             TEXTGRAMMARCHECK_EXPORT
0232         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0233         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0234         COMPONENT Devel
0235     )
0236 endif()