ktextaddons/textedittexttospeech/CMakeLists.txt

0001 # SPDX-FileCopyrightText: none
0002 # SPDX-License-Identifier: BSD-3-Clause
0003 add_definitions(-DTRANSLATION_DOMAIN=\"libtextedittexttospeech\")
0004
0005 ########### CMake Config Files ###########
0006 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF${KF_MAJOR_VERSION}TextEditTextToSpeech")
0007
0008 ecm_setup_version(PROJECT VARIABLE_PREFIX TEXTEDITTEXTTOSPEECH
0009     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/textedittexttospeech_version.h"
0010     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF${KF_MAJOR_VERSION}TextEditTextToSpeechConfigVersion.cmake"
0011     SOVERSION 1
0012 )
0013
0014 add_library(KF${KF_MAJOR_VERSION}TextEditTextToSpeech)
0015 add_library(KF${KF_MAJOR_VERSION}::TextEditTextToSpeech ALIAS KF${KF_MAJOR_VERSION}TextEditTextToSpeech)
0016
0017 target_sources(KF${KF_MAJOR_VERSION}TextEditTextToSpeech PRIVATE
0018     texttospeech.cpp
0019     texttospeechwidget.cpp
0020     texttospeechconfigwidget.cpp
0021     texttospeechinterface.cpp
0022     texttospeechconfiginterface.cpp
0023     texttospeechconfigdialog.cpp
0024     texttospeechlanguagecombobox.cpp
0025     texttospeechactions.cpp
0026     texttospeech.h
0027     texttospeechwidget.h
0028     texttospeechconfigwidget.h
0029     texttospeechinterface.h
0030     texttospeechconfiginterface.h
0031     texttospeechconfigdialog.h
0032     texttospeechlanguagecombobox.h
0033     texttospeechactions.h
0034     texttospeechsliderwidget.h
0035     texttospeechsliderwidget.cpp
0036     texttospeechutil.h
0037     texttospeechutil.cpp
0038     texttospeechcontainerwidget.h
0039     texttospeechcontainerwidget.cpp
0040
0041     texttospeechvoicecombobox.h
0042     texttospeechvoicecombobox.cpp
0043 )
0044
0045 target_link_libraries(KF${KF_MAJOR_VERSION}TextEditTextToSpeech
0046     PRIVATE
0047     KF${KF_MAJOR_VERSION}::ConfigCore
0048     KF${KF_MAJOR_VERSION}::ConfigGui
0049     KF${KF_MAJOR_VERSION}::WidgetsAddons
0050     KF${KF_MAJOR_VERSION}::I18n
0051     Qt::TextToSpeech
0052 )
0053
0054 ecm_qt_declare_logging_category(KF${KF_MAJOR_VERSION}TextEditTextToSpeech HEADER textedittexttospeech_debug.h
0055     IDENTIFIER TEXTEDITTEXTTOSPEECH_LOG
0056     CATEGORY_NAME org.kde.kf.textedittexttospeech
0057     OLD_CATEGORY_NAMES org.kde.kf${KF_MAJOR_VERSION}.textedittexttospeech
0058     DESCRIPTION "KF${KF_MAJOR_VERSION} (textedit text to speech)" EXPORT KTEXTADDONS)
0059
0060 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0061     set_target_properties(KF${KF_MAJOR_VERSION}TextEditTextToSpeech PROPERTIES UNITY_BUILD ON)
0062 endif()
0063 generate_export_header(KF${KF_MAJOR_VERSION}TextEditTextToSpeech BASE_NAME textedittexttospeech)
0064
0065 target_include_directories(KF${KF_MAJOR_VERSION}TextEditTextToSpeech INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/TextEditTextToSpeech;>")
0066
0067
0068 target_link_libraries(KF${KF_MAJOR_VERSION}TextEditTextToSpeech
0069     PRIVATE
0070     KF${KF_MAJOR_VERSION}::I18n
0071     )
0072
0073 set_target_properties(KF${KF_MAJOR_VERSION}TextEditTextToSpeech PROPERTIES
0074     VERSION ${TEXTEDITTEXTTOSPEECH_VERSION}
0075     SOVERSION ${TEXTEDITTEXTTOSPEECH_SOVERSION}
0076     EXPORT_NAME TextEditTextToSpeech
0077     )
0078
0079 install(TARGETS KF${KF_MAJOR_VERSION}TextEditTextToSpeech EXPORT KF${KF_MAJOR_VERSION}TextEditTextToSpeechTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0080
0081 if(BUILD_TESTING)
0082     add_subdirectory(autotests)
0083     add_subdirectory(tests)
0084 endif()
0085
0086 ecm_generate_headers(TextEdit_CamelCasetexttospeechs_HEADERS
0087     HEADER_NAMES
0088     TextToSpeech
0089     TextToSpeechActions
0090     TextToSpeechInterface
0091     TextToSpeechWidget
0092     TextToSpeechConfigWidget
0093     TextToSpeechConfigDialog
0094     TextToSpeechContainerWidget
0095     REQUIRED_HEADERS TextEdit_texttospeechs_HEADERS
0096     PREFIX TextEditTextToSpeech
0097 )
0098
0099 install(FILES
0100     ${TextEdit_texttospeechs_HEADERS}
0101     ${CMAKE_CURRENT_BINARY_DIR}/textedittexttospeech_export.h
0102     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/TextEditTextToSpeech/textedittexttospeech
0103     COMPONENT Devel
0104 )
0105 install(FILES
0106     ${TextEdit_CamelCasetexttospeechs_HEADERS}
0107     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/TextEditTextToSpeech/TextEditTextToSpeech/
0108     COMPONENT Devel
0109 )
0110 if (BUILD_QCH)
0111     ecm_install_qch_export(
0112         TARGETS KF${KF_MAJOR_VERSION}TextEditTextToSpeech_QCH
0113         FILE KF${KF_MAJOR_VERSION}TextEditTextToSpeechQchTargets.cmake
0114         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0115         COMPONENT Devel
0116     )
0117 set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF${KF_MAJOR_VERSION}TextEditTextToSpeechQchTargets.cmake\")")
0118 endif()
0119
0120
0121
0122 install(FILES
0123     ${CMAKE_CURRENT_BINARY_DIR}/textedittexttospeech_version.h
0124     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/TextEditTextToSpeech
0125     COMPONENT Devel
0126     )
0127
0128
0129 if (BUILD_QCH)
0130     ecm_add_qch(
0131         KF${KF_MAJOR_VERSION}TextEditTextToSpeech_QCH
0132         NAME TextEditTextToSpeech
0133         BASE_NAME KF${KF_MAJOR_VERSION}TextEditTextToSpeech
0134         VERSION ${TEXTEDITTEXTTOSPEECH_VERSION}
0135         ORG_DOMAIN org.kde
0136         SOURCES # using only public headers, to cover only public API
0137             ${TextEdit_texttospeechs_HEADERS}
0138         LINK_QCHS
0139             Qt${QT_MAJOR_VERSION}Core_QCH
0140             Qt${QT_MAJOR_VERSION}Gui_QCH
0141             Qt${QT_MAJOR_VERSION}Widgets_QCH
0142         INCLUDE_DIRS
0143             ${CMAKE_CURRENT_BINARY_DIR}
0144         BLANK_MACROS
0145             TEXTEDITTEXTTOSPEECH_EXPORT
0146         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0147         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0148         COMPONENT Devel
0149     )
0150 endif()
0151
0152 configure_package_config_file(
0153     "${CMAKE_CURRENT_SOURCE_DIR}/KFTextEditTextToSpeechConfig.cmake.in"
0154     "${CMAKE_CURRENT_BINARY_DIR}/KF${KF_MAJOR_VERSION}TextEditTextToSpeechConfig.cmake"
0155     INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0156     )
0157
0158 install(FILES
0159     "${CMAKE_CURRENT_BINARY_DIR}/KF${KF_MAJOR_VERSION}TextEditTextToSpeechConfig.cmake"
0160     "${CMAKE_CURRENT_BINARY_DIR}/KF${KF_MAJOR_VERSION}TextEditTextToSpeechConfigVersion.cmake"
0161     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0162     COMPONENT Devel
0163     )
0164
0165 install(EXPORT KF${KF_MAJOR_VERSION}TextEditTextToSpeechTargets
0166     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0167     FILE KF${KF_MAJOR_VERSION}TextEditTextToSpeechTargets.cmake
0168     NAMESPACE KF${KF_MAJOR_VERSION}::
0169     )