ktextaddons/textaddonswidgets/CMakeLists.txt

0001 # SPDX-FileCopyrightText: none
0002 # SPDX-License-Identifier: BSD-3-Clause
0003 add_definitions(-DTRANSLATION_DOMAIN=\"libtextaddonswidgets\")
0004
0005 ########### CMake Config Files ###########
0006 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF${KF_MAJOR_VERSION}TextAddonsWidgets")
0007
0008 ecm_setup_version(PROJECT VARIABLE_PREFIX TEXTADDONSWIDGETS
0009     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/textaddonswidgets_version.h"
0010     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF${KF_MAJOR_VERSION}TextAddonsWidgetsConfigVersion.cmake"
0011     SOVERSION 1
0012 )
0013
0014 add_library(KF${KF_MAJOR_VERSION}TextAddonsWidgets)
0015 add_library(KF${KF_MAJOR_VERSION}::TextAddonsWidgets ALIAS KF${KF_MAJOR_VERSION}TextAddonsWidgets)
0016
0017 target_sources(KF${KF_MAJOR_VERSION}TextAddonsWidgets PRIVATE
0018     selectspecialchardialog.h
0019     selectspecialchardialog.cpp
0020     slidecontainer.cpp
0021     slidecontainer.h
0022 )
0023 if (QT_MAJOR_VERSION STREQUAL "5")
0024     target_sources(KF${KF_MAJOR_VERSION}TextAddonsWidgets PRIVATE
0025         lineeditcatchreturnkey.h
0026         lineeditcatchreturnkey.cpp
0027     )
0028 endif()
0029
0030 target_link_libraries(KF${KF_MAJOR_VERSION}TextAddonsWidgets
0031     PRIVATE
0032     Qt::Widgets
0033     KF${KF_MAJOR_VERSION}::WidgetsAddons
0034     KF${KF_MAJOR_VERSION}::ConfigGui
0035 )
0036
0037 ecm_qt_declare_logging_category(KF${KF_MAJOR_VERSION}TextAddonsWidgets HEADER TextAddonsWidgets_debug.h
0038     IDENTIFIER TEXTADDONSWIDGETS_LOG
0039     CATEGORY_NAME org.kde.kf.textaddonswidgets
0040     OLD_CATEGORY_NAMES org.kde.kf${KF_MAJOR_VERSION}.textaddonswidgets
0041     DESCRIPTION "KF${KF_MAJOR_VERSION} (textaddons widgets)" EXPORT KTEXTADDONS)
0042
0043 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0044     set_target_properties(KF${KF_MAJOR_VERSION}TextAddonsWidgets PROPERTIES UNITY_BUILD ON)
0045 endif()
0046 generate_export_header(KF${KF_MAJOR_VERSION}TextAddonsWidgets BASE_NAME TextAddonsWidgets)
0047
0048 target_include_directories(KF${KF_MAJOR_VERSION}TextAddonsWidgets INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/TextAddonsWidgets;>")
0049
0050
0051 target_link_libraries(KF${KF_MAJOR_VERSION}TextAddonsWidgets
0052     PRIVATE
0053     KF${KF_MAJOR_VERSION}::I18n
0054 )
0055
0056 set_target_properties(KF${KF_MAJOR_VERSION}TextAddonsWidgets PROPERTIES
0057     VERSION ${TEXTADDONSWIDGETS_VERSION}
0058     SOVERSION ${TEXTADDONSWIDGETS_SOVERSION}
0059     EXPORT_NAME TextAddonsWidgets
0060 )
0061
0062 install(TARGETS KF${KF_MAJOR_VERSION}TextAddonsWidgets EXPORT KF${KF_MAJOR_VERSION}TextAddonsWidgetsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0063
0064 ecm_generate_headers(TextAddonsWidgets_CamelCase_HEADERS
0065     HEADER_NAMES
0066     SelectSpecialCharDialog
0067     SlideContainer
0068     REQUIRED_HEADERS TextAddonsWidgets_HEADERS
0069     PREFIX TextAddonsWidgets
0070 )
0071 if (QT_MAJOR_VERSION STREQUAL "5")
0072     ecm_generate_headers(TextAddonsWidgets_lineedit_CamelCase_HEADERS
0073         HEADER_NAMES
0074         LineEditCatchReturnKey
0075         REQUIRED_HEADERS TextAddonsWidgets_lineedit_HEADERS
0076         PREFIX TextAddonsWidgets
0077     )
0078 endif()
0079
0080 install(FILES
0081     ${TextAddonsWidgets_HEADERS}
0082     ${TextAddonsWidgets_lineedit_HEADERS}
0083     ${CMAKE_CURRENT_BINARY_DIR}/textaddonswidgets_export.h
0084     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/TextAddonsWidgets/textaddonswidgets
0085     COMPONENT Devel
0086 )
0087 install(FILES
0088     ${TextAddonsWidgets_CamelCase_HEADERS}
0089     ${TextAddonsWidgets_lineedit_CamelCase_HEADERS}
0090     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/TextAddonsWidgets/TextAddonsWidgets/
0091     COMPONENT Devel
0092 )
0093
0094
0095 install(FILES
0096     "${CMAKE_CURRENT_BINARY_DIR}/KF${KF_MAJOR_VERSION}TextAddonsWidgetsConfig.cmake"
0097     "${CMAKE_CURRENT_BINARY_DIR}/KF${KF_MAJOR_VERSION}TextAddonsWidgetsConfigVersion.cmake"
0098     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0099     COMPONENT Devel
0100 )
0101
0102 install(EXPORT KF${KF_MAJOR_VERSION}TextAddonsWidgetsTargets
0103     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0104     FILE KF${KF_MAJOR_VERSION}TextAddonsWidgetsTargets.cmake
0105     NAMESPACE KF${KF_MAJOR_VERSION}::
0106 )
0107
0108 install(FILES
0109     ${CMAKE_CURRENT_BINARY_DIR}/textaddonswidgets_version.h
0110     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/TextAddonsWidgets
0111     COMPONENT Devel
0112 )
0113
0114
0115 if (BUILD_QCH)
0116     ecm_add_qch(
0117         KF${KF_MAJOR_VERSION}TextAddonsWidgets_QCH
0118         NAME KF${KF_MAJOR_VERSION}TextAddonsWidgets
0119         BASE_NAME KF${KF_MAJOR_VERSION}TextAddonsWidgets
0120         VERSION ${TEXTADDONSWIDGETS_VERSION}
0121         ORG_DOMAIN org.kde
0122         SOURCES # using only public headers, to cover only public API
0123         ${TextAddonsWidgets_HEADERS}
0124         LINK_QCHS
0125         Qt${QT_MAJOR_VERSION}Core_QCH
0126         Qt${QT_MAJOR_VERSION}Gui_QCH
0127         Qt${QT_MAJOR_VERSION}Widgets_QCH
0128         INCLUDE_DIRS
0129         ${CMAKE_CURRENT_BINARY_DIR}
0130         BLANK_MACROS
0131         TEXTADDONSWIDGETS_EXPORT
0132         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0133         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0134         COMPONENT Devel
0135     )
0136 endif()
0137
0138 if (BUILD_QCH)
0139     ecm_install_qch_export(
0140         TARGETS KF${KF_MAJOR_VERSION}TextAddonsWidgets_QCH
0141         FILE KF${KF_MAJOR_VERSION}TextAddonsWidgetsQchTargets.cmake
0142         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0143         COMPONENT Devel
0144     )
0145 set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF${KF_MAJOR_VERSION}TextAddonsWidgetsQchTargets.cmake\")")
0146 endif()
0147
0148 configure_package_config_file(
0149     "${CMAKE_CURRENT_SOURCE_DIR}/KFTextAddonsWidgetsConfig.cmake.in"
0150     "${CMAKE_CURRENT_BINARY_DIR}/KF${KF_MAJOR_VERSION}TextAddonsWidgetsConfig.cmake"
0151     INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0152 )
0153
0154 if (BUILD_TESTING)
0155     add_subdirectory(autotests)
0156     add_subdirectory(tests)
0157 endif()