src/app/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2021 Volker Krause <vkrause@kde.org>
0002 # SPDX-License-Identifier: BSD-3-Clause
0003
0004 add_executable(kosmindoormap-app
0005     main.cpp
0006     qml.qrc
0007 )
0008
0009 target_include_directories(kosmindoormap-app PRIVATE ${CMAKE_BINARY_DIR})
0010 target_link_libraries(kosmindoormap-app PRIVATE
0011     KOSMIndoorMap
0012     KOSM_xmlioplugin
0013     KF6::I18n
0014     Qt::Quick
0015 )
0016
0017 if (TARGET KOSM_pbfioplugin)
0018     target_compile_definitions(kosmindoormap-app PRIVATE -DHAVE_OSM_PBF_SUPPORT=1)
0019     target_link_libraries(kosmindoormap-app PRIVATE KOSM_pbfioplugin)
0020 else()
0021     target_compile_definitions(kosmindoormap-app PRIVATE -DHAVE_OSM_PBF_SUPPORT=0)
0022 endif()
0023
0024 if (ANDROID)
0025     # explicitly add runtime dependencies and transitive link dependencies,
0026     # so androiddeployqt picks them up
0027     target_link_libraries(kosmindoormap-app PRIVATE
0028         KF6::Kirigami2
0029         Qt::Svg
0030         OpenSSL::SSL
0031         Qt::QuickControls2
0032     )
0033
0034     kirigami_package_breeze_icons(ICONS
0035         arrow-right
0036         document-open-symbolic
0037         edit-clear-symbolic
0038         edit-paste-symbolic
0039         go-down-symbolic
0040         go-home
0041         go-up-symbolic
0042         help-about-symbolic
0043         license
0044         search
0045         view-refresh-symbolic
0046     )
0047
0048     ecm_add_android_apk(kosmindoormap-app ANDROID_DIR ${CMAKE_CURRENT_SOURCE_DIR}/android)
0049 else ()
0050     target_link_libraries(kosmindoormap-app PRIVATE
0051         Qt::Widgets
0052     )
0053     set_target_properties(kosmindoormap-app PROPERTIES OUTPUT_NAME "kosmindoormap")
0054 endif()
0055
0056 if (BUILD_STANDALONE_APP)
0057     install(TARGETS kosmindoormap-app ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0058     if (NOT ANDROID)
0059         install(PROGRAMS org.kde.kosmindoormap.desktop DESTINATION ${KDE_INSTALL_APPDIR})
0060         #install(FILES org.kde.kosmindoormap.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
0061     endif()
0062 endif()