libraries/kopeninghours/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2020 Volker Krause <vkrause@kde.org>
0002 # SPDX-License-Identifier: BSD-3-Clause
0003
0004 cmake_minimum_required(VERSION 3.5)
0005
0006 # KDE Application Version, managed by release script
0007 set (RELEASE_SERVICE_VERSION_MAJOR "24")
0008 set (RELEASE_SERVICE_VERSION_MINOR "04")
0009 set (RELEASE_SERVICE_VERSION_MICRO "70")
0010 set (RELEASE_SERVICE_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}.${RELEASE_SERVICE_VERSION_MICRO}")
0011 project(KOpeningHours VERSION ${RELEASE_SERVICE_VERSION})
0012
0013 # Ubuntu bionic has ECM 5.44
0014 find_package(ECM 5.44 REQUIRED NO_MODULE)
0015 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${ECM_MODULE_PATH})
0016
0017 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0018 include(ECMAddTests)
0019 include(ECMGenerateHeaders)
0020 include(ECMQtDeclareLoggingCategory)
0021 if (ECM_VERSION VERSION_GREATER_EQUAL 5.91)
0022     include(ECMDeprecationSettings)
0023 else()
0024     # backward compatibility for ECM versions without QtVersionOption.cmake
0025     set(QT_MAJOR_VERSION 5)
0026 endif()
0027 include(ECMSetupVersion)
0028 include(FeatureSummary)
0029 include(KDEInstallDirs)
0030 include(KDECMakeSettings)
0031 include(GenerateExportHeader)
0032 include(ECMAddQch)
0033 include(ECMQmlModule)
0034
0035
0036 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0037 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0038
0039 set(CMAKE_CXX_STANDARD 17)
0040 set(CMAKE_CXX_STANDARD_REQUIRED ON)
0041 set(CMAKE_AUTOMOC ON)
0042 set(CMAKE_AUTORCC ON)
0043 ecm_setup_version(PROJECT VARIABLE_PREFIX KOPENINGHOURS
0044     VERSION_HEADER kopeninghours_version.h
0045     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KOpeningHoursConfigVersion.cmake"
0046     SOVERSION 1
0047 )
0048
0049 option(VALIDATOR_ONLY "Build only the validator, not the evaluator. This removes the kholidays and ki18n dependencies." OFF)
0050 if (VALIDATOR_ONLY)
0051     set(REQUIRED_QT_VERSION 5.9)
0052 else()
0053     set(REQUIRED_QT_VERSION 5.14) # 5.14 for QCalendar
0054     if (QT_MAJOR_VERSION STREQUAL "6")
0055         set(QT_REQUIRED_VERSION "6.4.0")
0056         set(KF_MIN_VERSION "5.248.0")
0057         set(KF_MAJOR_VERSION "6")
0058     else()
0059         set(KF_MAJOR_VERSION "5")
0060     endif()
0061 endif()
0062
0063 find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} REQUIRED COMPONENTS Core) # 5.14 for QCalendar
0064 find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} CONFIG QUIET OPTIONAL_COMPONENTS Qml)
0065 if (NOT VALIDATOR_ONLY)
0066     find_package(KF${KF_MAJOR_VERSION} 5.77 REQUIRED COMPONENTS Holidays I18n)
0067 endif()
0068
0069 if (BUILD_TESTING)
0070     find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} REQUIRED COMPONENTS Test)
0071 endif()
0072
0073 find_package(FLEX REQUIRED)
0074 set_package_properties(FLEX PROPERTIES PURPOSE "Lexer generator for parsing opening hours expressions")
0075 find_package(BISON REQUIRED)
0076 set_package_properties(BISON PROPERTIES PURPOSE "Grammar generator for parsing opening hours expressions")
0077
0078 find_package(PythonLibs 3.6 MODULE)
0079 if (PythonLibs_FOUND)
0080     # Extract major/minor python version
0081     string(REPLACE "." ";" VERSION_LIST ${PYTHONLIBS_VERSION_STRING})
0082     list(GET VERSION_LIST 0 PYTHONLIBS_VERSION_MAJOR)
0083     list(GET VERSION_LIST 1 PYTHONLIBS_VERSION_MINOR)
0084
0085     # boost-python requires exact version number
0086     find_package(Boost COMPONENTS python${PYTHONLIBS_VERSION_MAJOR}${PYTHONLIBS_VERSION_MINOR} MODULE)
0087 endif()
0088
0089 add_definitions(-DQT_DISABLE_DEPRECATED_BEFORE=0x050d00)
0090 add_definitions(-DKF_DISABLE_DEPRECATED_BEFORE_AND_AT=0x054400)
0091 add_definitions(-DQT_NO_FOREACH)
0092 add_subdirectory(src)
0093 if (Boost_FOUND)
0094     add_subdirectory(PyKOpeningHours)
0095 endif()
0096
0097 if (BUILD_TESTING)
0098     add_subdirectory(autotests)
0099     add_subdirectory(tests)
0100 endif()
0101
0102
0103
0104 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KOpeningHours")
0105
0106
0107 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/kopeninghours_version.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
0108 if (NOT VALIDATOR_ONLY)
0109     ki18n_install(po)
0110 endif()
0111
0112 if (BUILD_QCH)
0113     ecm_install_qch_export(
0114         TARGETS KOpeningHours_QCH
0115         FILE KOpeningHoursQchTargets.cmake
0116         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0117         COMPONENT Devel
0118     )
0119     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KOpeningHoursQchTargets.cmake\")")
0120 endif()
0121
0122 configure_package_config_file(
0123     "${CMAKE_CURRENT_SOURCE_DIR}/KOpeningHoursConfig.cmake.in"
0124     "${CMAKE_CURRENT_BINARY_DIR}/KOpeningHoursConfig.cmake"
0125     INSTALL_DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0126 )
0127
0128 install(FILES
0129         "${CMAKE_CURRENT_BINARY_DIR}/KOpeningHoursConfig.cmake"
0130         "${CMAKE_CURRENT_BINARY_DIR}/KOpeningHoursConfigVersion.cmake"
0131     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0132     COMPONENT Devel
0133 )
0134 install(EXPORT KOpeningHoursTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KOpeningHoursTargets.cmake)
0135
0136 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)