kmoretools/src/CMakeLists.txt

0001 add_library(KF6MoreTools)
0002 add_library(KF6::MoreTools ALIAS KF6MoreTools)
0003
0004 target_sources(KF6MoreTools PRIVATE
0005     kmoretools.cpp
0006     kmoretoolsconfigdialog_p.cpp
0007     kmoretoolsmenufactory.cpp
0008     kmoretoolspresets.cpp
0009 )
0010 ki18n_wrap_ui(KF6MoreTools ui/kmoretoolsconfigwidget.ui)
0011
0012 ecm_qt_declare_logging_category(KF6MoreTools
0013     HEADER kmoretools_debug.h
0014     IDENTIFIER KMORETOOLS
0015     CATEGORY_NAME kf.moretools
0016     DESCRIPTION "KMoreTools"
0017     EXPORT KMORETOOLS
0018 )
0019
0020 ecm_generate_export_header(KF6MoreTools
0021     EXPORT_FILE_NAME kmoretools_export.h
0022     BASE_NAME KMoreTools
0023     GROUP_BASE_NAME KF
0024     VERSION ${KF_VERSION}
0025     DEPRECATED_BASE_VERSION 0
0026     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0027     DEPRECATION_VERSIONS
0028 )
0029
0030 ecm_generate_headers(KMoreTools_CamelCase_HEADERS
0031     HEADER_NAMES
0032     KMoreTools
0033     KMoreToolsMenuFactory
0034     KMoreToolsPresets
0035
0036     REQUIRED_HEADERS KMoreTools_HEADERS
0037 )
0038 install(
0039     FILES
0040         ${KMoreTools_CamelCase_HEADERS}
0041         ${KMoreTools_HEADERS}
0042         ${CMAKE_CURRENT_BINARY_DIR}/kmoretools_export.h
0043     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KMoreTools
0044     COMPONENT Devel
0045 )
0046 target_include_directories(KF6MoreTools
0047     INTERFACE "$<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>"
0048     INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KMoreTools>"
0049 )
0050
0051 target_link_libraries(KF6MoreTools
0052   PUBLIC
0053     KF6::Service
0054     Qt6::Widgets
0055   PRIVATE
0056     KF6::KIOCore               # For network fetching operations
0057     KF6::KIOWidgets            # For KUrlRequester
0058     KF6::I18n                  # For translations
0059     KF6::ConfigCore            # KAuthorized
0060     Qt6::Qml
0061     Qt6::Quick
0062 )
0063
0064 set_target_properties(KF6MoreTools PROPERTIES
0065    VERSION ${KMORETOOLS_VERSION}
0066    SOVERSION ${KMORETOOLS_SOVERSION}
0067    EXPORT_NAME MoreTools
0068 )
0069
0070 install(TARGETS KF6MoreTools EXPORT KF6MoreToolsTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0071
0072 if(BUILD_QCH)
0073     ecm_add_qch(
0074         KF6MoreTools_QCH
0075         NAME KMoreTools
0076         BASE_NAME KF6MoreTools
0077         VERSION ${KF_VERSION}
0078         ORG_DOMAIN org.kde
0079         SOURCES # using only public headers, to cover only public API
0080             ${KMoreTools_HEADERS}
0081         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0082         LINK_QCHS
0083             KF6Service_QCH
0084             Qt6Widgets_QCH
0085         INCLUDE_DIRS
0086             ${CMAKE_CURRENT_BINARY_DIR}
0087             ${KMoreTools_BINARY_DIR}
0088         BLANK_MACROS
0089             KMORETOOLS_EXPORT
0090             KMORETOOLS_DEPRECATED
0091             KMORETOOLS_DEPRECATED_EXPORT
0092             "KMORETOOLS_DEPRECATED_VERSION(x, y, t)"
0093             "KMORETOOLS_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t)"
0094         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0095         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0096         COMPONENT Devel
0097     )
0098 endif()