libraries/kirigami-addons/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2019 David Edmundson <kde@davidedmundson.co.uk>
0002 # SPDX-License-Identifier: BSD-2-Clause
0003
0004 cmake_minimum_required(VERSION 3.16)
0005
0006 project(kirigami-addons VERSION 0.11.40)
0007
0008 include(FeatureSummary)
0009
0010 set(AUTOMOC_MOC_OPTIONS -Muri=org.kde.kirigami)
0011
0012 # QT_MAJOR_VERSION is defined automatically by QtVersionOption (since ECM 5.82)
0013 # which is included by KDEInstallDirs;
0014 # This variables are updated below if Qt6 is found by ECM
0015 set(QT_REQUIRED_VERSION "5.15.2")
0016 set(KF_MIN_VERSION "5.91.0")
0017 set(KF_MAJOR_VERSION "5")
0018
0019 find_package(ECM ${KF_MIN_VERSION} NO_MODULE)
0020 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://projects.kde.org/projects/kdesupport/extra-cmake-modules")
0021
0022 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/ is checked
0023 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH})
0024
0025 include(KDEInstallDirs)
0026 include(KDECMakeSettings)
0027 include(KDECompilerSettings NO_POLICY_SCOPE)
0028
0029 include(GenerateExportHeader)
0030 include(ECMSetupVersion)
0031 include(ECMGenerateHeaders)
0032 include(CMakePackageConfigHelpers)
0033 include(ECMQtDeclareLoggingCategory)
0034 include(ECMAddQch)
0035 include(ECMQmlModule)
0036
0037 if (QT_MAJOR_VERSION STREQUAL "6")
0038     set(QT_REQUIRED_VERSION "6.4")
0039     set(KF_MIN_VERSION "5.240.0")
0040     set(KF_MAJOR_VERSION "6")
0041
0042     find_package(KSvg CONFIG)
0043     set_package_properties(KSvg PROPERTIES
0044         DESCRIPTION "Svg rendering library with theme support"
0045         PURPOSE "Required at runtime for rendering Svg items in some controls"
0046         TYPE RUNTIME
0047     )
0048
0049 endif()
0050
0051 find_package(Qt${QT_MAJOR_VERSION} ${QT_REQUIRED_VERSION} REQUIRED NO_MODULE COMPONENTS Core Quick QuickControls2)
0052
0053 find_package(KF${KF_MAJOR_VERSION} ${KF_MIN_VERSION} REQUIRED COMPONENTS Kirigami2 I18n)
0054 if (BUILD_TESTING)
0055     find_package(Qt${QT_MAJOR_VERSION}QuickTest ${QT_REQUIRED_VERSION} CONFIG QUIET)
0056 endif()
0057 if (ANDROID)
0058     find_package(Gradle REQUIRED)
0059     if (QT_MAJOR_VERSION EQUAL "5")
0060         find_package(Qt${QT_MAJOR_VERSION} ${QT_REQUIRED_VERSION} REQUIRED CONFIG COMPONENTS AndroidExtras)
0061     endif()
0062 endif()
0063
0064 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF${KF_MAJOR_VERSION}KirigamiAddons")
0065
0066 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0067 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0068
0069 configure_package_config_file(
0070     "${CMAKE_CURRENT_SOURCE_DIR}/KFKirigamiAddonsConfig.cmake.in"
0071     "${CMAKE_CURRENT_BINARY_DIR}/KF${KF_MAJOR_VERSION}KirigamiAddonsConfig.cmake"
0072     INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0073     PATH_VARS CMAKE_INSTALL_PREFIX
0074 )
0075 ecm_setup_version(${PROJECT_VERSION}
0076     VARIABLE_PREFIX KIRIGAMIADDONS
0077     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kirigamiaddons_version.h"
0078     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF${KF_MAJOR_VERSION}KirigamiAddonsConfigVersion.cmake"
0079 )
0080
0081
0082 if(QT_MAJOR_VERSION STREQUAL "6")
0083     set(QTGRAPHICALEFFECTS_MODULE "Qt5Compat.GraphicalEffects")
0084 else()
0085     set(QTGRAPHICALEFFECTS_MODULE "QtGraphicalEffects 1.0")
0086 endif()
0087
0088 add_subdirectory(src)
0089
0090 if (BUILD_TESTING AND BUILD_SHARED_LIBS)
0091     add_subdirectory(autotests)
0092 endif()
0093
0094 install(FILES
0095     "${CMAKE_CURRENT_BINARY_DIR}/KF${KF_MAJOR_VERSION}KirigamiAddonsConfig.cmake"
0096     "${CMAKE_CURRENT_BINARY_DIR}/KF${KF_MAJOR_VERSION}KirigamiAddonsConfigVersion.cmake"
0097     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0098     COMPONENT Devel
0099 )
0100
0101 ki18n_install(po)
0102
0103 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)