libraries/kirigami-addons/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2019 David Edmundson <kde@davidedmundson.co.uk>
0002 # SPDX-License-Identifier: BSD-2-Clause
0003
0004 cmake_minimum_required(VERSION 3.16)
0005
0006 project(kirigami-addons VERSION 0.4)
0007
0008 set(REQUIRED_QT_VERSION 5.15.2)
0009 set(KF5_DEP_VERSION "5.91.0")
0010
0011 include(FeatureSummary)
0012
0013 set(AUTOMOC_MOC_OPTIONS -Muri=org.kde.kirigami)
0014
0015 find_package(ECM ${KF5_DEP_VERSION} NO_MODULE)
0016 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://projects.kde.org/projects/kdesupport/extra-cmake-modules")
0017
0018 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/ is checked
0019 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH})
0020
0021 include(KDEInstallDirs)
0022 include(KDECMakeSettings)
0023 include(KDECompilerSettings NO_POLICY_SCOPE)
0024
0025 include(GenerateExportHeader)
0026 include(ECMSetupVersion)
0027 include(ECMGenerateHeaders)
0028 include(CMakePackageConfigHelpers)
0029 include(ECMQtDeclareLoggingCategory)
0030 include(ECMAddQch)
0031 include(ECMQmlModule)
0032
0033 find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} REQUIRED NO_MODULE COMPONENTS Core Quick QuickControls2)
0034
0035 find_package(KF5 ${KF5_DEP_VERSION} REQUIRED COMPONENTS Kirigami2 I18n)
0036 if (BUILD_TESTING)
0037     find_package(Qt${QT_MAJOR_VERSION}QuickTest ${REQUIRED_QT_VERSION} CONFIG QUIET)
0038 endif()
0039 if (ANDROID)
0040     find_package(Gradle REQUIRED)
0041     if (QT_MAJOR_VERSION EQUAL "5")
0042         find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} REQUIRED CONFIG COMPONENTS AndroidExtras)
0043     endif()
0044 endif()
0045
0046 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5KirigamiAddons")
0047
0048 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0049 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0050
0051 configure_package_config_file(
0052     "${CMAKE_CURRENT_SOURCE_DIR}/KF5KirigamiAddonsConfig.cmake.in"
0053     "${CMAKE_CURRENT_BINARY_DIR}/KF5KirigamiAddonsConfig.cmake"
0054     INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0055     PATH_VARS CMAKE_INSTALL_PREFIX
0056 )
0057 ecm_setup_version(${PROJECT_VERSION}
0058     VARIABLE_PREFIX KIRIGAMIADDONS
0059     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kirigamiaddons_version.h"
0060     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5KirigamiAddonsConfigVersion.cmake"
0061 )
0062
0063 add_subdirectory(src)
0064
0065 if (BUILD_TESTING AND BUILD_SHARED_LIBS)
0066     add_subdirectory(autotests)
0067 endif()
0068
0069 install(FILES
0070     "${CMAKE_CURRENT_BINARY_DIR}/KF5KirigamiAddonsConfig.cmake"
0071     "${CMAKE_CURRENT_BINARY_DIR}/KF5KirigamiAddonsConfigVersion.cmake"
0072     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0073     COMPONENT Devel
0074 )
0075
0076 ki18n_install(po)
0077
0078 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)